How can I get contacts into Numbers spreadsheet

Question

How can I get my contacts into a Numbers spreadsheet, please help since the OS X mavericks upgrade I cant drag them and I dont know how to get them into the spreadsheet now can anyone help

Answer 1

And here's a way to get some actual information from Contacts into Numbers 3.0.
1. Copy/paste the script below into AppleScript Editor.
2. Select the cards in Contacts that you want.
3. Click the green run button in AppleScript Editor.
4. Click a cell in Numbers and command-v to paste the data in.
That should result in something like this:
Here is the script:
--Places tab-separated Contacts data on the system clipboard for pasting into a table
--usage: select one or more contacts in Contacts, run, select a cell in a table and paste
tell application "Contacts"
          set {tsvData, contacts} to {"", selection}
          if selection is not {} then
                    set tsvData to "Name" & tab & "Phones" & tab & "Street" & tab & "City" & tab & "Zip" & tab & "Emails" & return --header row
                    repeat with thisPerson in contacts
                              set {thisPhone, thisEmail} to {"", ""}
                              set {thisName, thisID} to {name, id} of thisPerson
                              set {thisStreet, thisCity, thisZip} to {street, city, zip} of the first address of thisPerson
                              set phoneProperties to properties of phones of thisPerson
                              repeat with j from 1 to (count of phoneProperties)
                                        set thisPhone to thisPhone & value of item j of phoneProperties & "  "
                              end repeat
                              set emailProperties to properties of emails of thisPerson
                              repeat with j from 1 to (count of emailProperties)
                                        set thisEmail to thisEmail & value of item j of emailProperties & "   "
                              end repeat
                              set tsvData to tsvData & thisName & tab & thisPhone & tab & thisStreet & tab & thisCity & tab & thisZip & tab & thisEmail & return
                    end repeat
  set the clipboard to text 1 thru -2 of tsvData -- remove trailing return
                    tell application "System Events" to display dialog "Click in cell and <command-v>" buttons {"OK"} default button 1
          else
                    tell application "System Events" to display dialog "Select at least one card in Contacts and run again" buttons {"OK"} default button 1
          end if
end tell
This is not as nice as the old vcard drag and drop import. It's a simple example and probably needs some customizing because there are so many different ways people store information in Contacts.  But this approach can meet most needs, if it's not convenient to leave the data in Contacts and link to it.
SG