How can we let the program run in backgroud automatically?

Question

normally,we need to find peak off time run big program
that read pooled table and slowly.
How can we let the program run in backgroud automatically?
BTW:before that pop a window just give runner a notice.

Answer 1

Here is an example, try this one.
REPORT ztest.
PARAMETERS: p_vbeln LIKE vbak-vbeln,
            p_bkrun NO-DISPLAY.
DATA: ls_vbak LIKE vbak.
DATA: v_answer,
      v_jobcount LIKE tbtcjob-jobcount.
  IF p_bkrun IS INITIAL.
*-- not background processing
    CALL FUNCTION 'POPUP_TO_CONFIRM_STEP'
         EXPORTING
              textline1      = 'This may time out.'
              textline2      = 'Do you want to run in background?'
              titel          = 'Warning!!!'
              cancel_display = space
         IMPORTING
              answer         = v_answer.
    IF v_answer = 'J'.
*-- run in the background
      CALL FUNCTION 'JOB_OPEN'
           EXPORTING
                jobname          = 'ZTEST'
           IMPORTING
                jobcount         = v_jobcount
           EXCEPTIONS
                cant_create_job  = 1
                invalid_job_data = 2
                jobname_missing  = 3
                OTHERS           = 4.
      IF sy-subrc <> 0.
        MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
        EXIT.
      ENDIF.
*-- submit the program in the background
      SUBMIT ztest
        WITH p_bkrun = 'X'
        WITH p_vbeln = p_vbeln
        USER sy-uname
        VIA JOB 'ZTEST' NUMBER v_jobcount AND RETURN.
*-- close the job
      CALL FUNCTION 'JOB_CLOSE'
           EXPORTING
                jobcount             = v_jobcount
                jobname              = 'ZTEST'
                strtimmed            = 'X'
           EXCEPTIONS
                cant_start_immediate = 1
                invalid_startdate    = 2
                jobname_missing      = 3
                job_close_failed     = 4
                job_nosteps          = 5
                job_notex            = 6
                lock_failed          = 7
                OTHERS               = 8.
      IF sy-subrc <> 0.
        MESSAGE ID sy-msgid TYPE 'W' NUMBER sy-msgno
                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
      ENDIF.
      EXIT.
    ELSE.
      CLEAR v_answer.
    ENDIF.
  ENDIF.
  CHECK v_answer IS INITIAL.
  SELECT SINGLE * FROM vbak
                  INTO ls_vbak
                 WHERE vbeln = p_vbeln.
  IF sy-subrc <> 0.
    WRITE:/ 'Invalid Order Id.'.
  ENDIF.
END-OF-SELECTION.
  CHECK v_answer IS INITIAL.
  IF p_bkrun IS INITIAL.
    WRITE:/ 'Here is the result running the program in foreground.'.
  ELSE.
    WRITE:/ 'Here is the result running the program in background.'.
  ENDIF.
  WRITE:/ ls_vbak-vbeln,
          ls_vbak-vkorg.