How do I color an entire layer?

Question

G'day.
I'm new to scripting illustrator, and I'd like to be able to set the color of everything on a layer to red ( or any other color). Is it possible?
I've tried selecting all with the GUI, and setting the default stroke color while the layer is selected, but that process adds extra width to the image parts, and only works on some parts.
Regards
Brian

Answer 1

The above JavaScript actually loops thru page items not path items (unless you only have path items on the page)
You did not state any particular language to do this in but were using AppleScript in another post (I think) so here's something that should get you started. This is only for path items only but you could include other elements of your layer.
BTW in the GUI you could just draw a big rectangle behind all your layer items then select all and 'make opacity mask'
I can't get this to work in script even by calling on an action.
tell application "Adobe Illustrator"
activate
set Doc_Ref to the current document
tell Doc_Ref
set Swatch_Ref to index of swatch named "Mars Red"
-- See if we have used global color for tints
if class of color of swatch Swatch_Ref = spot color info then
set Global_Color to true
else
set Global_Color to false
end if
repeat with i from 1 to count of path items of layer "Marks"
set This_Path_Item to path item i of layer "Marks"
if filled of This_Path_Item = true then
-- See if we have used global color for tints
if class of fill color of This_Path_Item = spot color info and Global_Color = true then
set This_Fill_Tint to tint of fill color of This_Path_Item
set fill color of This_Path_Item to color of swatch Swatch_Ref
set tint of fill color of This_Path_Item to This_Fill_Tint
else
set fill color of This_Path_Item to color of swatch Swatch_Ref
end if
end if
if stroked of This_Path_Item = true then
-- See if we have used global color for tints
if class of stroke color of This_Path_Item = spot color info and Global_Color = true then
set This_Stroke_Tint to tint of stroke color of This_Path_Item
set stroke color of This_Path_Item to color of swatch Swatch_Ref
set tint of stroke color of This_Path_Item to This_Stroke_Tint
else
set stroke color of This_Path_Item to color of swatch Swatch_Ref
end if
end if
end repeat
end tell
end tell