How do I find out the ID of a reminder created with an applescript?

Question

I created an applescript to create a reminder from Quicksilver, but I want it to show the reminder once it has been created if Reminders was already open. If I use this, then another reminder with the same name sometimes gets shown. How do I find out the ID of a reminder when I create it and set it to a variable so that it will select the reminde I want it to, and if this is not possible, how should I do it?
Here is the applescript:
using terms from application "Quicksilver"
          on process text reminderData
                    if reminderData is "help" then return "Syntax: \"Name:Priority Time Date List Notes\""
                    set isName to true
                    set isPriority to false
                    set hasBeenPriority to false
                    set priorityEntered to false
                    set isTime to false
                    set hasBeenTime to false
                    set timeEntered to false
                    set isDate to false
                    set hasBeenDate to false
                    set dateEntered to false
                    set isList to false
                    set hasBeenList to false
                    set listEntered to false
                    set isNotes to false
                    set reminderName to ""
                    set reminderPriority to ""
                    set reminderTime to ""
                    set reminderDate to ""
                    set reminderNotes to ""
                    set reminderList to ""
                    set reminderDataCharacters to the characters of reminderData
                    repeat with i from 1 to number of items in reminderDataCharacters
                              set currentItem to item i of reminderDataCharacters
                              if isName is false and hasBeenPriority is false then set isPriority to true
                              if hasBeenPriority and hasBeenTime is false then set isTime to true
                              if hasBeenTime and hasBeenDate is false then set isDate to true
                              if hasBeenDate and hasBeenList is false then set isList to true
                              if hasBeenList then set isNotes to true
                              if isName then
                                        if currentItem is ":" then
                                                  set isName to false
                                        else
                                                  set reminderName to reminderName & currentItem
                                        end if
                              end if
                              if isPriority then
                                        if currentItem is "!" or currentItem is "-" then
                                                  if currentItem is "!" then set reminderPriority to reminderPriority & "!"
                                                  set priorityEntered to true
                                        else
                                                  if currentItem is " " and priorityEntered then
                                                            set isPriority to false
                                                            set hasBeenPriority to true
                                                  end if
                                        end if
                              end if
                              if isTime then
                                        if currentItem is " " then
                                                  if timeEntered then
                                                            set isTime to false
                                                            set hasBeenTime to true
                                                  end if
                                        else
                                                  if currentItem is not "-" then set reminderTime to reminderTime & currentItem
                                                  set timeEntered to true
                                        end if
                              end if
                              if isDate then
                                        if currentItem is " " then
                                                  if dateEntered then
                                                            set isDate to false
                                                            set hasBeenDate to true
                                                  end if
                                        else
                                                  if currentItem is not "-" then set reminderDate to reminderDate & currentItem
                                                  set dateEntered to true
                                        end if
                              end if
                              if isList then
                                        if currentItem is " " then
                                                  if listEntered then
                                                            set isList to false
                                                            set hasBeenList to true
                                                  end if
                                        else
                                                  if currentItem is not "-" then set reminderList to reminderList & currentItem
                                                  set listEntered to true
                                        end if
                              end if
                              if isNotes then set reminderNotes to reminderNotes & currentItem
                    end repeat
                    if reminderDate is not "" then
                              if reminderTime is "" then set reminderTime to time string of (current date)
                    end if
                    if reminderTime is not "" and reminderTime does not contain "am" and reminderTime does not contain "pm" then
                              try
                                        if (item 1 of the characters of reminderTime) as number is greater than or equal to 8 and (item 1 of the characters of reminderTime) as number is less than or equal to 11 then
                                                  set reminderTime to reminderTime & "am"
                                        else
                                                  set reminderTime to reminderTime & "pm"
                                        end if
                              end try
                    end if
                    try
                              set reminderDateAndTime to date (date string of (date (reminderDate & "/" & last word of (date string of (current date)))) & " " & time string of (date reminderTime))
                    on error
                              set reminderDateAndTime to false
                    end try
  createReminder(reminderName, reminderPriority, reminderNotes, reminderList, reminderDateAndTime)
                    tell application "Quicksilver" to show notification "The reminder was created successfully" text "Quicksilver successfully created your reminder."
          end process text
          on createReminder(theName, thePriority, theNotes, theList, theDate)
                    if thePriority is 1 then set thePriority to 9
                    if thePriority is "!" then set thePriority to 9
                    if thePriority is 2 then set thePriority to 5
                    if thePriority is "!!" then set thePriority to 5
                    if thePriority is 3 then set thePriority to 1
                    if thePriority is "!!!" then set thePriority to 1
                    tell application "System Events"
                              if exists process "Reminders" then
                                        set wasOpen to true
                              else
                                        set wasOpen to false
                              end if
                    end tell
                    tell application "Reminders"
                              if theDate is false then
                                        try
  make new reminder at list theList with properties {name:theName, body:theNotes, priority:thePriority}
                                        on error
  make new reminder with properties {name:theName, body:theNotes, priority:thePriority}
                                        end try
                              else
                                        try
  make new reminder at list theList with properties {name:theName, body:theNotes, remind me date:theDate, priority:thePriority}
                                        on error
  make new reminder with properties {name:theName, body:theNotes, remind me date:theDate, priority:thePriority}
                                        end try
                              end if
                              if wasOpen then
  show reminder theName
                              else
                                        quit
                              end if
                    end tell
          end createReminder
end using terms from

Answer 1

This seems to find the ID, which is sort of the answer to my question, but I still don't seem to be able to use it to show to right reminder. I get this error:
error "Reminders got an error: Can’t make reminder id \"1E436B16-561C-4F88-8CA6-78029BE68BBF\" into type integer." number -1700 from reminder id "1E436B16-561C-4F88-8CA6-78029BE68BBF" to integer
What is wrong, and how should I fix it?
Here is the createReminder block now:
on createReminder(theName, thePriority, theNotes, theList, theDate)
          if thePriority is 1 then set thePriority to 9
          if thePriority is "!" then set thePriority to 9
          if thePriority is 2 then set thePriority to 5
          if thePriority is "!!" then set thePriority to 5
          if thePriority is 3 then set thePriority to 1
          if thePriority is "!!!" then set thePriority to 1
          tell application "System Events"
                    if exists process "Reminders" then
                              set wasOpen to true
                    else
                              set wasOpen to false
                    end if
          end tell
          tell application "Reminders"
                    if theDate is false then
                              try
                                        set theReminder to make new reminder at list theList with properties {name:theName, body:theNotes, priority:thePriority}
                              on error
                                        set theReminder to make new reminder with properties {name:theName, body:theNotes, priority:thePriority}
                              end try
                    else
                              try
                                        set theReminder to make new reminder at list theList with properties {name:theName, body:theNotes, remind me date:theDate, priority:thePriority}
                              on error
                                        set theReminder to make new reminder with properties {name:theName, body:theNotes, remind me date:theDate, priority:thePriority}
                              end try
                    end if
                    set theID to the id of theReminder
                    if wasOpen then
  show theID
                    else
  quit
                    end if
          end tell
end createReminder