How pass a parameter with forward slash to plsql script

Question

Hi,
I am trying pass a parameter to plsql script from command line using sqlplus, and the parameter is a file directory and has '/'. Seems the system couldn't recognize the value.
here is my code in DECLARE:
l_FileDir VARCHAR2(200) := &&FileDir ;
I pass value '/usr/tmp' (with the single quote in the string)
Can someone tell me how I do it?
Thanks,
Kate
Edited by: user12100435 on Feb 25, 2010 8:31 AM

Answer 1

user12100435 wrote:
I think you are right. The issue is not file-separator character issue. because the exact same script run in another envoironment. And it's not file directory or permission issue because if I use hardcoded value, the code works fine.
The error message is invalid File directory.
Here is the related part of the code.
-- open file handler
IF UTL_FILE.IS_OPEN(l_FileHandler) THEN
UTL_FILE.FCLOSE(l_FileHandler);
ELSE
l_FileHandler := UTL_FILE.FOPEN ( location => l_FileDir,
filename => l_FileName,
open_mode => 'W',
max_linesize => 32767 );
END IF;Ok, based on your input so far, I have cooked up a simple testcase.
Make sure you are doing something similar to this -
test@XE>
test@XE> -- show the contents of the anonymous PL/SQL script
test@XE> -- You are probably passing two parameters - the file location and the file name
test@XE> --
test@XE> ! cat test5.sql
DECLARE
  l_FileHandler UTL_FILE.FILE_TYPE;
  l_FileDir     VARCHAR2(200) := '&1' ; 
  l_FileName    VARCHAR2(200) := '&2' ; 
BEGIN
  -- open file handler
  IF UTL_FILE.IS_OPEN(l_FileHandler) THEN
    UTL_FILE.FCLOSE(l_FileHandler);
  ELSE
    l_FileHandler := UTL_FILE.FOPEN ( location => l_FileDir,
                                      filename => l_FileName,
                                      open_mode => 'W',
                                      max_linesize => 32767 );
    UTL_FILE.PUT_LINE(file => l_FileHandler, buffer => 'Hello, World!');
    UTL_FILE.FCLOSE(file => l_FileHandler);
  END IF;
END;
test@XE>
test@XE> -- execute it
test@XE> @test5.sql '/usr/tmp' 'first.txt'
old   3:   l_FileDir     VARCHAR2(200) := '&1' ;
new   3:   l_FileDir     VARCHAR2(200) := '/usr/tmp' ;
old   4:   l_FileName    VARCHAR2(200) := '&2' ;
new   4:   l_FileName    VARCHAR2(200) := 'first.txt' ;
DECLARE
ERROR at line 1:
ORA-29280: invalid directory path
ORA-06512: at "SYS.UTL_FILE", line 33
ORA-06512: at "SYS.UTL_FILE", line 436
ORA-06512: at line 10
test@XE>
test@XE> -- Create a directory object that points to "/usr/tmp"
test@XE> create directory log_dir as '/usr/tmp';
Directory created.
test@XE>
test@XE> -- now invoke the script
test@XE> -- Note - I pass the value "LOG_DIR" in uppercase. That's the name of my directory object.
test@XE> --
test@XE> @test5.sql 'LOG_DIR' 'first.txt'
old   3:   l_FileDir     VARCHAR2(200) := '&1' ;
new   3:   l_FileDir     VARCHAR2(200) := 'LOG_DIR' ;
old   4:   l_FileName    VARCHAR2(200) := '&2' ;
new   4:   l_FileName    VARCHAR2(200) := 'first.txt' ;
PL/SQL procedure successfully completed.
test@XE>
test@XE> -- Since my Oracle client is on the same machine as the Oracle server, I can check
test@XE> -- this file "/usr/tmp/first.txt" quite easily
test@XE>
test@XE> ! cat /usr/tmp/first.txt
Hello, World!
test@XE>
test@XE> isotope