How to batch convert Word files to pdf

Question

How do I batch convert Word files to pdf using Automator

Answer 1

Here is a drag/drop AppleScript solution that uses the command-line LibreOffice capability to convert MS Word (.doc, .docx) files into PDF. Drag/Drop a single file, or a folder of Word documents, and it will write the respective PDF back to the original file location. When it is done, an OS X Notification will slide out onto the Desktop and provide the count of processed files.
Save this AppleScript as a Desktop application that remains open after running. If you ignore the latter, the notification will not show when it is done. Tested on Mavericks 10.9.5.
property name_extension : {"doc", "docx"}
global fileCnt
on open of finderObjects
    set fileCnt to 0
    repeat with i in (finderObjects)
    if folder of (info for i) is true then
        tell application "Finder" to set temp to (entire contents of i)
        repeat with j in (temp)
            process_files(j)
        end repeat
    else
          process_files(i)
    end if
    end repeat
    display notification "Processed Files: " & fileCnt with title "Word2PDF" subtitle "Processing Complete"
end open
on process_files(fname)
     set cmd to "/Applications/LibreOffice.app/Contents/MacOS/soffice "
     set cmdArgs to "--headless --convert-to pdf:writer_pdf_Export --outdir "
     tell application "Finder"
          set nameExt to name extension of fname
          set outDir to do shell script "dirname " & POSIX path of (fname as alias)
          if name extension of fname is in name_extension then
               try
                    do shell script cmd & cmdArgs & outDir & space & POSIX path of (fname as alias)
                    set fileCnt to fileCnt + 1
               on error errorMessage number errorNumber
                    display alert "Processing Error: " message "[ " & errorNumber & " ] " & errorMessage
                    error number -128
               end try
          end if
     end tell
     return
end process_files