How to convert raw data into pdf ?

Question

Hi everyone,
I have a requirement where I have to print the document present in application server.
I used below code to do this
* Open the file in binary mode
   OPEN DATASET gv_filepath FOR INPUT IN TEXT MODE ENCODING DEFAULT IGNORING CONVERSION ERRORS.
   DO.
     TRY.
* Since the file is opened in Binary mode, the entire contents of the
* file is read in one go!
         READ DATASET gv_filepath INTO gv_filedata.
         IF sy-subrc <> 0.
           EXIT.
         ENDIF.
       CATCH cx_sy_conversion_codepage.
     ENDTRY.
     APPEND gv_filedata TO gt_file_table.
     CLEAR gv_filedata.
   ENDDO.
   CLOSE DATASET gv_filepath.
DESCRIBE TABLE gt_file_table LINES lv_lines.
  lv_pages = lv_lines.
  lv_dest = 'LP01'.
  lv_spoolname = 'LOCW'.
  CALL FUNCTION 'RSPO_SX_OUTPUT_TEXTDATA'
    EXPORTING
*     NAME           = lv_spoolname
      DEST           = lv_dest
      ROWS           = lv_lines
      STARTROW       = 1
      PAGES          = 99
      RQTITLE        = 'Print Spool'
      RQCOPIES       = 1
      RQOWNER        = sy-uname
      IMMEDIATELY    = ' '
    IMPORTING
      RQID           = lv_spoolid
    TABLES
      TEXT_DATA      = gt_file_table
    EXCEPTIONS
      NAME_MISSING   = 1
      NAME_TWICE     = 2
      NOT_FOUND      = 3
      ILLEGAL_LAYOUT = 4
      INTERNAL_ERROR = 5
      SIZE_MISMATCH  = 6
      OTHERS         = 7.
  IF SY-SUBRC <> 0.
* Implement suitable error handling here
  ENDIF.
Passed the spool id generated to below FM but it is not converting into pdf
CALL FUNCTION 'CONVERT_ABAPSPOOLJOB_2_PDF'
    EXPORTING
      SRC_SPOOLID                    = lv_spoolid
     NO_DIALOG                      = ' '
     DST_DEVICE                     = 'LOCW'
     PDF_DESTINATION                = 'X'
*     NO_BACKGROUND                  =
*     GET_SIZE_FROM_FORMAT           =
*     USE_CASCADING                  = ' '
*   IMPORTING
*     PDF_BYTECOUNT                  = lv_bytecount
*     PDF_SPOOLID                    = lv_pdf1
*     LIST_PAGECOUNT                 =
*     BTC_JOBNAME                    =
*     BTC_JOBCOUNT                   =
*     BIN_FILE                       = lv_pdf
   TABLES
     PDF                            = lt_pdf
   EXCEPTIONS
     ERR_NO_ABAP_SPOOLJOB           = 1
     ERR_NO_SPOOLJOB                = 2
     ERR_NO_PERMISSION              = 3
     ERR_CONV_NOT_POSSIBLE          = 4
     ERR_BAD_DESTDEVICE             = 5
     USER_CANCELLED                 = 6
     ERR_SPOOLERROR                 = 7
     ERR_TEMSEERROR                 = 8
     ERR_BTCJOB_OPEN_FAILED         = 9
     ERR_BTCJOB_SUBMIT_FAILED       = 10
     ERR_BTCJOB_CLOSE_FAILED        = 11
     OTHERS                         = 12
  IF SY-SUBRC <> 0.
* Implement suitable error handling here
  ENDIF.
When I go to SP01 and check the spool generated it is in raw document type.
How can I convert this raw document to pdf type ??
Please help me to resolve this.
Regards,
Krishna

Answer 1

Ok, since I can't edit the post anymore, here the new version of code, without the use of SCMS_XSTRING_TO_BINARY for intermediate table. Reasons: effectively doubles the memory use and I don't want to check if the kernel is cutting off the hexdecimal nulls when the last spool line is written, or to relay of that behaviour.
Matthew Billingham, and other mods: it would be really nice if you could hide the old version please (this post here). The number of google results for that FM is scary and I really don't want to contribute to promoting its use...
REPORT zjbtst2.
PARAMETERS: p_file TYPE string
   LOWER CASE
   DEFAULT '/usr/sap/....'
   OBLIGATORY.
PARAMETERS: p_dest TYPE rspopname
  DEFAULT 'LP01'
  OBLIGATORY .
PERFORM main USING p_file p_dest.
*&      Form  main
FORM main
  USING
    i_file TYPE string
    i_dest TYPE  rspopname.
  DATA: lo_handle TYPE REF TO cl_rspo_spool_handle .
  DATA: l_spoolid TYPE rspoid.
  DATA: l_content TYPE xstring .
  DATA: l_message_text TYPE string .
  PERFORM get_file USING i_file CHANGING l_content .
  PERFORM new_spool USING i_dest CHANGING lo_handle l_spoolid.
  PERFORM write_spool USING lo_handle l_spoolid l_content .
  l_message_text = |Spool { l_spoolid } created| .
  MESSAGE l_message_text TYPE 'I' .
ENDFORM .                  "main
*&      Form  get_file
FORM get_file
   USING i_file TYPE string
   CHANGING c_content TYPE xstring.
  DATA: l_message_text TYPE string .
  CLEAR c_content .
  OPEN DATASET i_file FOR INPUT IN BINARY MODE
    MESSAGE l_message_text.
  IF sy-subrc NE 0 .
    MESSAGE l_message_text TYPE 'E' .
  ELSE.
    READ DATASET i_file INTO c_content .
    CLOSE DATASET i_file.
  ENDIF .
ENDFORM .                   "get_file
*&      Form  new_spool
FORM new_spool
   USING
     i_destination TYPE rspopname
   CHANGING
     co_handle TYPE REF TO cl_rspo_spool_handle
     c_spoolid TYPE rspoid .
  cl_rspo_spool_handle=>open(
    EXPORTING
      dest           = i_destination
      name           = 'Test'
      layout         = 'G_RAW'
      doctype        = 'BIN'
    IMPORTING
      ref            = co_handle
      spoolid        = c_spoolid
    EXCEPTIONS
      device_missing = 1
      name_twice     = 2
      no_such_device = 3
      operation_failed = 4
      OTHERS         = 5
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM .                    "new_spool
*&      Form  WRITE_SPOOL
FORM write_spool
  USING
    io_handle TYPE REF TO cl_rspo_spool_handle
    i_spoolid TYPE rspoid
    i_content TYPE xstring .
  DATA: l_buffer(128) TYPE x ."Hmm, 128 does work, 4096 doesn't...
  DATA: l_buffer_length TYPE i .
  DATA: l_full_buffers_count TYPE i .
  DATA: l_part_buffer_length TYPE i .
  DATA: l_offset TYPE i .
  DATA: l_length TYPE i .
  l_buffer_length = xstrlen( l_buffer ) .
  l_full_buffers_count = xstrlen( i_content ) DIV l_buffer_length .
  l_part_buffer_length = xstrlen( i_content ) MOD l_buffer_length .
  DO l_full_buffers_count + 1 TIMES .
    IF sy-index LE l_full_buffers_count .
      l_length = l_buffer_length .
    ELSEIF l_part_buffer_length GT 0 .
      l_length = l_part_buffer_length .
    ELSE.
      EXIT .
    ENDIF .
    l_buffer = i_content+l_offset(l_length) .
    ADD l_length TO l_offset .
    io_handle->write_binary(
      EXPORTING
        data           = l_buffer
        length         = l_length
      EXCEPTIONS
        not_open       = 1
        operation_failed = 2
        OTHERS         = 3
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
  ENDDO .
  io_handle->close(
    EXPORTING
      final          = 'X'
    EXCEPTIONS
      operation_failed = 1
      already_closed = 2
      OTHERS         = 3
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM .                    "write_spool