How to convert raw data to original data

Question

Hi,
I'm using db10g.
I have stored the blob of a word doc into the database using dbms_lob package.
Now during retrieval, i'm getting the raw data using the code
dbms_lob.read( l_lob, l_amt, l_off, l_raw );
l_raw is of type raw.
I want to convert the raw data to original string.
Please Help
Thanks

Answer 1

Divya wrote:
I think I have clearly told that i have blobs of different files in my database.
The files are of different type, I have blob of pdf,doc,html,xml,gif etc...
and in the procedure i have posted(get_file_contents), it is a database procedure and i'm calling it from the forms.
So i'm passing the file_name and file_id to the procedure(file_name and file_id are the columns in the table.
Table 'Blob_Details' have 4 columns file_id,file_name,file_type,theblob) and a varchar variable final_data.
final_data varchar(32000)
and in the procedure i'm taking the blob from database, reading it using dbms_lob.read in a loop and casting it to varchar and storing the contents in the variable final_data.
So coming out of the loop, the variable final_data will have the contents of the given file.BLOB data (such as word or excel documents and PDFs containing images etc.) are Binary data, not Character data. Converting that raw binary data to VARCHAR will cause issues.
If you have loaded a binary file and stored it on the database as a BLOB (Binary data) and you now want to create the original file from that BLOB, you will simply need to read the BLOB data from the database into BLOB variable and process it in chunks, using UTL_FILE to write out, in Binary mode, that data to a file with the appropriate filename. The actual process is quite simple...
As sys user:
CREATE OR REPLACE DIRECTORY MY_FILES AS 'c:\myfiles';
GRANT READ,WRITE ON DIRECTORY MY_FILES TO myuser;As myuser:
DECLARE
   -- Data Variables
   v_blob             BLOB;
   v_data_length      NUMBER;
   -- Loop Control Variables
   v_offset           NUMBER := 1;
   v_chunk   CONSTANT NUMBER := 32767; -- maximum chunk size
   -- UTL_FILE variables
   fh                 UTL_FILE.file_type;
BEGIN
   v_blob := ... populate the blob variable here
   v_data_length := DBMS_LOB.getlength (v_blob);
   -- Open the file
   fh := UTL_FILE.fopen ('MY_FILES', 'myfile.dat', 'wb', v_chunk);
   LOOP
      -- Exit when our file offset is bigger than our file
      EXIT WHEN v_offset > v_data_length;
      -- Write the output chunk by chunk
      UTL_FILE.put_raw (fh, DBMS_LOB.SUBSTR (v_blob, v_chunk, v_offset), TRUE);
      -- Increment the offset by the amount written
      v_offset := v_offset + v_chunk;
   END LOOP;
   -- Close the file
   UTL_FILE.fclose (fh);
END;