How to extract List of Objects and Classes in BO

Question

Hi
I need to get a list of all Classes and Objects in a universe.
Is there a way to extract this list in an excel.
I dont need the PDF file which can be saved from a universe with all the universe information.
I just need a plain excel file with the classes, objects under it, object definitions etc.
Is there a VBA code to do so?
I know there is one to extract the user info from CMS.
Please help.
Thanks in advance.

Answer 1

Option Explicit
Dim DesignerApp As Designer.Application
Dim Univ As Designer.Universe
Dim Wksht As Excel.Worksheet
Sub GetInfo()
    Set DesignerApp = New Designer.Application
    DesignerApp.Visible = True
    Call DesignerApp.LoginAs
    Set Univ = DesignerApp.Universes.Open
    'DesignerApp.Visible = False
    Set Wksht = ThisWorkbook.Worksheets("Objects")
    Wksht.Unprotect
    Wksht.Columns().ClearContents
    Wksht.Cells(1, 1) = "Class"
    Wksht.Cells(1, 2) = "Objects"
    Wksht.Cells(1, 3) = "Table Reference"
    Wksht.Cells(1, 4) = "Object Description"
    Wksht.Cells(1, 5) = "Object Type"
    Wksht.Cells(1, 6) = "Qualification"
    Call GetObjectInfo(Univ.Classes, 1)
    Wksht.Protect
    DesignerApp.Quit
    Set DesignerApp = Nothing
End Sub
Private Sub GetObjectInfo(Clss, RowNum As Long)
    Dim Cls As Designer.Class
    Dim Obj As Designer.Object
    For Each Cls In Clss
        For Each Obj In Cls.Objects
            RowNum = RowNum + 1
            Wksht.Cells(RowNum, 1) = Cls.Name
            Wksht.Cells(RowNum, 2) = Obj.Name
            Wksht.Cells(RowNum, 3) = Obj.Select
            Wksht.Cells(RowNum, 4) = Obj.Description
            If Obj.Type = 2 Then
                Wksht.Cells(RowNum, 5) = "Character"
            ElseIf Obj.Type = 3 Then
                Wksht.Cells(RowNum, 5) = "Date"
            ElseIf Obj.Type = 1 Then
                Wksht.Cells(RowNum, 5) = "Number"
            Else
                Wksht.Cells(RowNum, 5) = "Long Text"
            End If
            If Obj.Qualification = dsDimensionObject Then Wksht.Cells(RowNum, 6) = "Dimension"
            If Obj.Qualification = dsDetailObject Then Wksht.Cells(RowNum, 6) = "Detail"
            If Obj.Qualification = dsMeasureObject Then Wksht.Cells(RowNum, 6) = "Measure"
        Next Obj
        If Cls.Classes.Count > 0 Then
            Call GetObjectInfo(Cls.Classes, RowNum)
        End If
    Next Cls
End Sub
Above is the macro to document BO universes (Classes, Objects, TableName.FieldName, Object description, Object Type and Object Qualification ).
You need to open the excel sheet->Go to TOOLS> MACRO --->VB EDITOR (Alt+F11) and paste this code in MODULE1
To run the macro, You need to press Alt+F8 key and Click RUN button. Then designer window pops out, enter user id and password and select the required universe.
Enjoy Macro