How to find the table name on which integrity constraint not found

Question

Hi All
How to acheive this
I have a lot of tables with lot of primary key - foreign key
relationship.
In plsql
when any inserts happen in the child table & the corresponding row is not present in the parent table, we get an exception
ORA-02291: integrity constraint (user1.ppk) violated - parent key not found
On this exception , in the exception block i want to trap teh name of the parent table on which the primary key for the particular child table was not there
Is it possible to retrieve the parent table in this way. I am looking for a generic plsql code block which can help to acheive this
Regards

Answer 1

scott@ORA92> SET SERVEROUTPUT ON
scott@ORA92> DECLARE
  2    e_no_parent_key EXCEPTION;
  3    PRAGMA            EXCEPTION_INIT (e_no_parent_key, -2291);
  4    v_fk_cons       VARCHAR2 (61);
  5    v_owner            VARCHAR2 (30);
  6    v_parent_table  VARCHAR2 (61);
  7    v_pk_cons       VARCHAR2 (30);
  8    v_parent_column VARCHAR2 (30);
  9  BEGIN
10    INSERT INTO emp (empno, deptno) VALUES (99, 60);
11  EXCEPTION
12    WHEN e_no_parent_key THEN
13        -- extract schema.constraint_name from sqlerrm:
14        v_fk_cons:= SUBSTR (SQLERRM,
15                      INSTR (SQLERRM, '(') + 1,
16                      INSTR (SQLERRM, ')') - (INSTR (SQLERRM, '(') + 1));
17        DBMS_OUTPUT.PUT_LINE ('Foreign key constraint violated: ' || v_fk_cons);
18        -- extract parent schema.table and parent key:
19        SELECT owner, table_name, constraint_name
20        INTO     v_owner, v_parent_table, v_pk_cons
21        FROM     user_constraints
22        WHERE     (owner, constraint_name) =
23            (SELECT r_owner, r_constraint_name
24             FROM     user_constraints
25             WHERE     owner || '.' || constraint_name = v_fk_cons);
26        DBMS_OUTPUT.PUT_LINE ('Parent table: ' || v_owner || '.' || v_parent_table);
27        DBMS_OUTPUT.PUT_LINE ('Parent key: ' || v_owner || '.' || v_pk_cons);
28        -- extract parent table columns:
29        FOR rec IN
30          (SELECT column_name
31           FROM   user_cons_columns
32           WHERE  owner = v_owner
33           AND    table_name = v_parent_table
34           AND    constraint_name = v_pk_cons)
35        LOOP
36          DBMS_OUTPUT.PUT_LINE
37            ('Parent table column: ' || rec.column_name);
38        END LOOP;
39  END;
40  /
Foreign key constraint violated: SCOTT.FK_DEPTNO
Parent table: SCOTT.DEPT
Parent key: SCOTT.PK_DEPT
Parent table column: DEPTNO
PL/SQL procedure successfully completed.