How to format paragraph string to show content left, Right or middle of pdf document using iTextsharp ' vb

Question

Dear All
how to format paragraph string to show content left, Right or middle of pdf document using iTextsharp in visual basic and absolute position on the document.
Thanks

Answer 1

 Here is one more example that i have modified the GetCell function so that you can use it for adding all the cells to the document.  It takes several arguments to specify everything you need to create each cell.  It now lets
you specify the Text, the Text Alignment, the Text Font and color, weather the cell shows the Border, the BackColor of the cell, and the Padding values for the Left, Right, Top, and Bottom.
 If you study the code you should be able to figure out how it works.  From here you can figure out the rest of what you need to do and how to use the
GetCell function.
 With one quick google search for "iTextSharp Documentation" the first link to pop up was this link.
iTextSharp Documentation
Imports System.IO
Imports Its = iTextSharp.text
Public Class Form1
Private dt As New DataTable
Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
dt.Dispose()
End Sub
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
dt.Columns.Add("Name")
dt.Columns.Add("Age")
dt.Columns.Add("Birth Date")
dt.Rows.Add(New Object() {"Johnny", "23", Now.AddYears(-23).ToString})
dt.Rows.Add(New Object() {"Frank", "41", Now.AddYears(-41).ToString})
dt.Rows.Add(New Object() {"Rex", "33", Now.AddYears(-33).ToString})
dt.Rows.Add(New Object() {"Kim", "26", Now.AddYears(-26).ToString})
End Sub
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Dim MyPdfFilePath As String = "C:\TestFolder\MyPdf.pdf"
Dim pSize As New Its.Rectangle(Its.PageSize.A4)
Dim PdfDoc As Its.Document = New Its.Document(pSize, 10, 10, 10, 10)
Dim PdfImage As New Its.Jpeg(New Uri("C:\TestFolder\MyLogo.jpg"))
PdfImage.Alignment = Its.Jpeg.ALIGN_CENTER
Dim pTable As New Its.pdf.PdfPTable(1)
pTable.AddCell(getCell("Name : " & TextBox1.Text, Its.pdf.PdfPCell.ALIGN_CENTER, Its.FontFactory.GetFont("Arial", 15, Its.BaseColor.BLACK), False, Its.BaseColor.WHITE, 10, 0, 0, 0))
pTable.AddCell(getCell("Policy : " & TextBox2.Text, Its.pdf.PdfPCell.ALIGN_CENTER, Its.FontFactory.GetFont("Arial", 20, Its.BaseColor.RED), False, Its.BaseColor.WHITE, 10, 20, 0, 0))
Dim cTable As New Its.pdf.PdfPTable(dt.Columns.Count)
For Each col As DataColumn In dt.Columns
cTable.AddCell(getCell(col.ColumnName, Its.pdf.PdfPCell.ALIGN_CENTER, Its.FontFactory.GetFont("Arial", 12, Its.BaseColor.WHITE), True, Its.BaseColor.BLUE, 3, 5, 0, 0))
Next
Dim tblfont As Its.Font = Its.FontFactory.GetFont("Arial", 10, Its.BaseColor.BLACK)
For Each row As DataRow In dt.Rows
cTable.AddCell(getCell(row.Field(Of String)("Name"), Its.pdf.PdfPCell.ALIGN_LEFT, tblfont, True, Its.BaseColor.WHITE, 3, 4, 3, 0))
cTable.AddCell(getCell(row.Field(Of String)("Age"), Its.pdf.PdfPCell.ALIGN_CENTER, tblfont, True, Its.BaseColor.WHITE, 3, 4, 0, 0))
cTable.AddCell(getCell(row.Field(Of String)("Birth Date"), Its.pdf.PdfPCell.ALIGN_RIGHT, tblfont, True, Its.BaseColor.WHITE, 3, 4, 0, 3))
Next
Using fs As New FileStream(MyPdfFilePath, FileMode.Create, FileAccess.Write, FileShare.None)
Using pdfWrite As Its.pdf.PdfWriter = Its.pdf.PdfWriter.GetInstance(PdfDoc, fs)
PdfDoc.Open()
PdfDoc.Add(PdfImage)
PdfDoc.Add(pTable)
PdfDoc.Add(cTable)
PdfDoc.Close()
End Using
End Using
PdfDoc.Dispose()
End Sub
''' <summary>Creates a new cell for the table.</summary>
''' <param name="text">The text string for the cell.</param>
''' <param name="alignment">Alighnment for the text string.</param>
''' <param name="textfont">The font used for the text string.</param>
''' <param name="border">True to show the cell border. False to hide the cell border.</param>
''' <param name="backcolor">The background color of the cell.</param>
''' <param name="padtop">The amount of padding on the top of the text string.</param>
''' <param name="padbottom">The amount of padding on the bottom of the text string.</param>
''' <param name="padleft">The amount of padding on the left of the text string.</param>
''' <param name="padright">The amount of padding on the right of the text string.</param>
Public Function getCell(ByVal text As String, ByVal alignment As Integer, ByVal textfont As Its.Font, ByVal border As Boolean, ByVal backcolor As Its.BaseColor, ByVal padtop As Single, ByVal padbottom As Single, ByVal padleft As Single, ByVal padright As Single) As Its.pdf.PdfPCell
Dim cell As New Its.pdf.PdfPCell(New Its.Phrase(text, textfont))
cell.BackgroundColor = backcolor
cell.PaddingLeft = padleft
cell.PaddingRight = padright
cell.PaddingTop = padtop
cell.PaddingBottom = padbottom
cell.HorizontalAlignment = alignment
If Not border Then cell.Border = Its.pdf.PdfPCell.NO_BORDER
Return cell
End Function
End Class
If you say it can`t be done then i`ll try it