How to get Listener Information using PL/SQL code

Question

How to get Listener Information using PL/SQL code

Answer 1

user2075318 wrote:
How to get Listener Information using PL/SQL codeThis approach (somewhat of a hack) can be used - but it does not really provide meaningful data at application layer.
SQL> create or replace function TnsPing( ipAddress varchar2, port number default 1521 ) return varchar2 is
  2          type THexArray is table of varchar2(2);
  3          --// tnsping packet (should be 10g and 11g listener compatible)
  4          TNS_PING_PACKET constant THexArray := new THexArray(
  5                  '00', '57', '00', '00', '01', '00', '00', '00',
  6                  '01', '39', '01', '2C', '00', '00', '08', '00',
  7                  '7F', 'FF', '7F', '08', '00', '00', '01', '00',
  8                  '00', '1D', '00', '3A', '00', '00', '00', '00',
  9                  '00', '00', '00', '00', '00', '00', '00', '00',
10                  '00', '00', '00', '00', '00', '00', '00', '00',
11                  '00', '00', '00', '00', '00', '00', '00', '00',
12                  '00', '00', '28', '43', '4F', '4E', '4E', '45',
13                  '43', '54', '5F', '44', '41', '54', '41', '3D',
14                  '28', '43', '4F', '4D', '4D', '41', '4E', '44',
15                  '3D', '70', '69', '6E', '67', '29', '29'
16          );
17 
18          socket  UTL_TCP.connection;
19          txBytes number;
20          rxBytes number;
21          rawBuf  raw(1024);
22          resp    varchar2(1024);
23  begin
24          socket := UTL_TCP.open_connection(
25                          remote_host => ipAddress,
26                          remote_port => port,
27                          tx_timeout => 10
28                  );
29 
30          --// convert hex array into a raw buffer
31          for i in 1..TNS_PING_PACKET.Count loop
32                  rawBuf := rawBuf || HexToRaw( TNS_PING_PACKET(i) );
33          end loop;
34 
35          --// send packet
36          txBytes := UTL_TCP.write_raw( socket, rawBuf, TNS_PING_PACKET.Count  );
37 
38          --// read response
39          rxBytes := UTL_TCP.read_raw( socket, rawBuf, 1024 );
40 
41          UTL_TCP.close_connection( socket );
42 
43          --// convert response to varchar2
44          resp := UTL_RAW.Cast_To_Varchar2( rawBuf );
45 
46          --// strip the header from the response and return the text only
47          return( substr(resp,13) );
48  end;
49  /
Function created.
SQL>
SQL> select tnsping( '10.251.93.30' ) as TNSPING from dual;
TNSPING
(DESCRIPTION=(TMP=)(VSNNUM=169869568)(ERR=0)(ALIAS=LISTENER))
SQL> select tnsping( '10.251.95.69' ) as TNSPING from dual;
TNSPING
(DESCRIPTION=(TMP=)(VSNNUM=0)(ERR=0)(ALIAS=LISTENER))
SQL>