How to get SUBSCRIBED calendars synched on iPhone/MobileMe

Question

Create, and place this Apple script in your Appliations folder
Instructions follow the script...
-- iCal Duplicator 2.0
-- MobileMe Push Sync with iCal does not currently support susbcribed calendars. This has disappointed some like
-- myself, who rely extensively on subscribed calendars. This kludgy solution copies events from a subscribed calendar
-- to a local calendar. Set your calendar names in the script, then run the script on a weekly/daily basis or manually to
-- update your local copy/copies based on the subscribed calendar.
-- Support for copying from multiple calendars has been added. You'll need to enter the source and destination names as
-- pairs. If you want multiple subscribed calendars copied into one local calendar, you can enter the local calendar names
-- multiple times as I have for the "Combined - Local" calendar.
-- Christian Lindemer, July 15th, 2008 {macosxhints (a) dethbunny (.) net}
-- * * * Edit values to match actual calendar names * * *
-- The subscribed calendars
property sourceCalendarNames : {"Davidcopy", "Othercopy"}
-- The blank local calendar(s) to copy in to, in the same order as the source calendars
property destinationCalendarNames : {"Davidcopy", "Other"}
-- how many days to go back - the more you add, the slower the script runs.
property oldEntryDays : 1
on run
--make sure we have valid names.
try
tell application "iCal"
repeat with testName in sourceCalendarNames
--this throws an error if there is no calendar with the given name, thus checking the calendar's validity.
set testCal to (the first calendar whose title is the testName)
end repeat
repeat with testName in destinationCalendarNames
set testCal to (the first calendar whose title is the testName)
end repeat
end tell
on error
--if a name can't be found, alert user and halt.
calendarNotFound(testName)
return --this effectively quits the script
end try
repeat with destName in destinationCalendarNames
clearEvents(destName)
end repeat
set calendarCount to 1
--repeat through all calendar names
repeat with sourceName in sourceCalendarNames
--get the calendar names and pass them to the copyEvents function
set destinationName to item calendarCount of destinationCalendarNames
copyEvents(sourceName, destinationName)
set calendarCount to (calendarCount + 1)
end repeat --repeat through all calendar pairs
end run
on calendarNotFound(notFoundName)
display alert "Calendar named " & notFoundName & " was not found in iCal. Please edit the script to match your calendars."
end calendarNotFound
on clearEvents(destCalName)
tell application "iCal"
--Clear the destination calendar
set destCalendar to (the first calendar whose title is the destCalName)
set calendarEvents to (events of destCalendar) -- get the destination calendar's event list
repeat with myEvent in calendarEvents -- delete each existing event
delete myEvent
end repeat
end tell
end clearEvents
on copyEvents(sourceCalName, destCalName)
tell application "iCal"
set sourceCalendar to (the first calendar whose title is the sourceCalName)
set destCalendar to (the first calendar whose title is the destCalName)
set calendarEvents to (events of sourceCalendar) -- get the calendar's event list
repeat with myEvent in calendarEvents -- repeat for each item found in the source event list
--Don't bother with old events
if start date of myEvent > ((current date) - oldEntryDays * days) then --event is in future, or within prefs for old entries
-- gather relevant details of event to create new event with
set eventStart to start date of myEvent
set eventEnd to end date of myEvent
set eventAllDay to allday event of myEvent
set eventSummary to summary of myEvent
-- create event in destination calendar with details of subscribed event
tell destCalendar
make new event at end with properties {summary:eventSummary, start date:eventStart, end date:eventEnd, allday event:eventAllDay}
end tell
end if --if not older than 'oldEntryDays' days ago
end repeat --iterate through entries in source calendar
end tell
end copyEvents
Let's say you have a subscribed calendar named "David"
Go into iCal and create a new calendar ("on my Mac") named "Davidcopy" with the same color as your subscribed calendar.
Repeat for any other subscribed cals you want to sync to iPhone.
Open the CopyCal script
Edit the first line of (uncommented) code which starts with property sourceCalendarNames:
Change the names of the cals in this list to match the subscribed cals you wish to copy
Edit the list on the next line to match the NEW cals you created ("Davidcopy" etc)
Next look at iCal and uncheck the subscribed cals.
Run the script and watch the copying take place.
Now to automate this, set up an event everyday (as often as you like). Preferably this can be in another calendar you don't publish - so everyone doesn't have it cluttering their view of your cal.
For example I have events named "sync" at 9:30am and 5pm every weekday. For the alarm, use "Run Script" and choose the CopyCal.scpt.

Answer 1

on copyEvents(sourceCalName, destCalName)
tell application "iCal"
set sourceCalendar to (the first calendar whose title is the sourceCalName)
set destCalendar to (the first calendar whose title is the destCalName)
set calendarEvents to (events of sourceCalendar) -- get the calendar's event list
repeat with myEvent in calendarEvents -- repeat for each item found in the source event list
--Don't bother with old events
if start date of myEvent > ((current date) - oldEntryDays * days) then --event is in future, or within prefs for old entries
-- gather relevant details of event to create new event with
set eventStart to start date of myEvent
set eventEnd to end date of myEvent
set eventAllDay to allday event of myEvent
set eventSummary to summary of myEvent
set eventRecurrence to recurrence of myEvent
-- create event in destination calendar with details of subscribed event
tell destCalendar
make new event at end with properties {summary:eventSummary, start date:eventStart, end date:eventEnd, allday event:eventAllDay, recurrence:eventRecurrence}
end tell
end if --if not older than 'oldEntryDays' days ago
end repeat --iterate through entries in source calendar
end tell
end copyEvents