How to get the enclosing folder of an Application?

Question

Ok. re-visiting my Applescript to compare installed apps versus a list of predefined apps... here is my test code so far:
set appsPath to (path to applications folder)
tell application "Finder"
  set appList to name of every application file of entire contents of folder appsPath
end tell
set theApps to {"iMovie.app", "Microsoft Excel", "Microsoft Excel.app", "Adobe Acrobat 7.0 Professional.app", "Adobe After Effects CS4.app", "ColorEyes Display Pro.app", "Corel Painter X.app", "DiskTracker 2.3.2", "EPSON Scan.app", "Flash 8.app", "Product Ingest.app", "Product Tag.app", "Art Ingest.app", "TextWrangler.app", "Toast Titanium.app", "Suitcase Fusion 2.app", "Suitcase Fusion 3.app", "Fetch.app"}
repeat with anApp in theApps
  set vers to version of (application anApp)
  -- get parent path of anApp!!!!
  if (parentFolder is equal to "Applications" or parentFolder is equal to "Utilities") then
  set parentFolder to ""
  end if
  display alert anApp & ": Version: " & vers & " " & parentFolder
end repeat
The only thing I'm stuck on is how to get the parent folder of anApp. Basically we use several versions of software here that are not easily identifiable by the version attribute. However their enclosing folder has all the versioning info I need (e.g.: MS Excel 04's vers would be 110113, but the enclosing folder is "Microsoft Office 2004", and some departments get Office 2008, Office 2011, etc., so I need a human-friendly way to get the right versions)
I don't know if the "if" statement to check whether the parent is Applications or Utilities is correct as I haven't gotten that far in testing. I'm only interested in getting the parent of apps that have parent folder that is a sub-folder of Applications or Utilities.
Basically what I am trying to do here is write a text file containing all departmental apps, homefolder sizes, relevant partition sizes, etc. and spit it out at the tech responsible for migrating a user to a new mac (display alert is just convenient for testing purposes). In the past we've had too many "missed" items in QC like wrong apps installed, or wrong versions, or data not copied over properly, etc. So this way they can run this on the old system beforehand and the new system after, line everything up and check off if it matches. This is just a snippet...
TIA!
Andrew

Answer 1

Hi,
Andrew Caldwell wrote:
Is there a way to invoke these without the script opening each one?
You must use the bundle identifier instead of the name
Here a example :
set theApps to {"com.microsoft.excel", "com.adobe.Acrobat.Pro", "com.barebones.textwrangler", "com.roxio.Toast", "com.fetchsoftworks.Fetch"}
repeat with anApp in theApps
       tell application "Finder" to tell (application file id anApp)
              set vers to version
              set parentFolder to name of its container
       end tell
       if parentFolder is in {"Applications", "Utilities"} then set parentFolder to ""
       display alert anApp & ": Version: " & vers & " " & parentFolder
end repeat