How to hold the value of a prompted password in a variable while file is open?

Question

I have this little VBA macro that uses ADODB to execute a SQL Server Agent job remotely.  It is in an Excel file, and there will be several other similar macros in the same Excel file.  They will be used at least 10 times, each time the user opens
the Excel file.  If I leave it like this, the user will be prompted for the password every single time they run one of the macros.  How can I change it to instead prompt the user for the password value initially when they open the file, store it
in a variable, and then utilize that variable value for the database connection every time they run one of the macros (to avoid repeated prompting)?  Also, are there any security concerns with my proposed approach?
Sub Test_SSIS()
Dim conn As Object
Set conn = CreateObject("ADODB.Connection")
conn.Provider = "sqloledb"
conn.Properties("Prompt") = adPromptComplete
conn.Open = "Data Source=MYSERVER;USER ID=JOHNDOE;"
conn.Execute "exec msdb.dbo.sp_start_job 'Test_remote_job_execution'"
End Sub

Answer 1

One possibility is to use the workbook_open event to prompt for and store the password temporarily in the registry. Add the following code to the thisworkbook module of the workbook
Option Explicit
Private Sub Workbook_Open()
Dim strPassword As String
strPassword = GetSetting("myApp", "Config", "Password", "")
If strPassword = "" Then
strPassword = InputBox("Enter password")
SaveSetting "myApp", "Config", "Password", strPassword
End If
lbl_Exit:
Exit Sub
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
RegKeyDelete "HKEY_CURRENT_USER\Software\VB and VBA Program Settings\myApp\Config\"
If RegKeyDelete("HKEY_CURRENT_USER\Software\VB and VBA Program Settings\myApp\") = True Then
MsgBox "Password cleared"
Else
MsgBox "Password not stored"
End If
lbl_Exit:
Exit Sub
End Sub
Function RegKeyDelete(i_RegKey As String) As Boolean
Dim myWS As Object
On Error GoTo ErrorHandler
Set myWS = CreateObject("WScript.Shell")
myWS.RegDelete i_RegKey
RegKeyDelete = True
Exit Function
lbl_Exit:
Exit Function
ErrorHandler:
RegKeyDelete = False
GoTo lbl_Exit
End Function
Then modify your macro code as follows:
Sub Test_SSIS()
Dim strPassword As String
Dim conn As Object
strPassword = GetSetting("myApp", "Config", "Password", "")
If strPassword = "" Then
strPassword = InputBox("Enter password")
SaveSetting "myApp", "Config", "Password", strPassword
End If
Set conn = CreateObject("ADODB.Connection")
conn.Provider = "sqloledb"
conn.Open "DATA SOURCE=MYSERVER;USER ID=JOHNDOE;Password=" & strPassword & ";"
conn.Execute "exec msdb.dbo.sp_start_job 'Test_remote_job_execution'"
End Sub
The workbook must obviously be saved as macro enabled
This will then prompt once when the workbook is opened. When the macro is run it will read the password from the registry thus not requiring a prompt, unless for some reason the password is missing or nothing has been entered as a value in the first box.
When the workbook is closed, the workbook before close event deletes the registry entries completely.
The only snag to this is if the workbook is crashed, the registry entry is not removed and there will be no prompt next time, until the workbook is closed correc tly. This might not be an issue, if the users don't know about it, so hide your code from them.
Graham Mayor - Word MVP
www.gmayor.com