How to refer to libraries

Question

Hi,
given an open document with different libraries open (especially graphic styles libraries), how do i reference a particular graphic style in one of the libraries to apply it to an element?
Not intended to be a cross posting (i accidentially started a similar thread in the general use forum but i seem not to get answers there).
[EDIT] Forgot to mention: Illu-Ver.: CS4, intended scripting environment: Extend Script Toolkit [/EDIT]
Nachricht geändert durch moebius_tm

Answer 1

Should it be of any use to you or anybody else here. This is how I was doing this some time back. Like I said if you use 'graphic styles' then they bring all the extra used pallet objects with them which can be a bit of a time saver the only one that you would have to handle separately is 'symbols' as these are placed items not applied requiring you to place an instance of it then copying over.
Graphic Styles
tell application "Adobe Illustrator"
set user interaction level to never interact
activate
make new document with properties ¬
{color space:CMYK, width:500, height:500}
set Doc_Ref to name of current document
tell document Doc_Ref
do script "Delete Unused Palette Items" from "Default Actions" without dialogs
do script "Delete Unused Palette Items" from "Default Actions" without dialogs
delete swatch "Smoke"
end tell
my Load_Graphic_Styles(Doc_Ref, "Marks_Graphic_Styles.ai")
repeat the result times
tell document Doc_Ref
delete path item 1
-- do stuff with your graphic style
end tell
end repeat
set user interaction level to interact with all
end tell
on Load_Graphic_Styles(Doc_Ref, Presets_Name)
set Apps_Folder to (path to applications folder as Unicode text)
set Preset_Folder to "Adobe Illustrator CS2:Presets.localized:Graphic Styles.localized:"
try
set Preset_Path to Apps_Folder & Preset_Folder & Presets_Name as alias
set This_Count to 0
tell application "Adobe Illustrator"
open Preset_Path
-- ignore 1 {"Default"}
repeat with i from 2 to count of (graphic styles of document Presets_Name)
make new rectangle at beginning of document Presets_Name with properties ¬
{fill color:{cyan:0, magenta:0, yellow:0, black:0}, stroked:false, width:10, height:10}
apply graphic style i of document Presets_Name to path item 1 of document Presets_Name
duplicate path item 1 of document Presets_Name to beginning of document Doc_Ref
set This_Count to This_Count + 1
end repeat
close document Presets_Name saving no
end tell
return This_Count
on error
error "Your preset does NOT exist where expected!!"
end try
end Load_Graphic_Styles
Symbols
tell application "Adobe Illustrator"
set user interaction level to never interact
activate
make new document with properties ¬
{color space:CMYK, width:500, height:500}
set Doc_Ref to name of current document
tell document Doc_Ref
do script "Delete Unused Palette Items" from "Default Actions" without dialogs
do script "Delete Unused Palette Items" from "Default Actions" without dialogs
delete swatch "Smoke"
end tell
my Load_Symbols(Doc_Ref, "Marks_Symbols.ai")
repeat the result times
tell document Doc_Ref
delete symbol item 1
-- do stuff with your brush
end tell
end repeat
set user interaction level to interact with all
end tell
on Load_Symbols(Doc_Ref, Presets_Name)
set Apps_Folder to (path to applications folder as Unicode text)
set Preset_Folder to "Adobe Illustrator CS2:Presets.localized:Symbols.localized:"
try
set Preset_Path to Apps_Folder & Preset_Folder & Presets_Name as alias
set This_Count to 0
tell application "Adobe Illustrator"
open Preset_Path
repeat with i from 1 to count of (symbols of document Presets_Name)
make new symbol item at beginning of document Presets_Name with properties ¬
{symbol:symbol i of document Presets_Name}
duplicate symbol item 1 of document Presets_Name to beginning of document Doc_Ref
set This_Count to This_Count + 1
end repeat
close document Presets_Name saving no
end tell
return This_Count
on error
error "Your preset does NOT exist where expected!!"
end try
end Load_Symbols
This should be pretty self explanatory just pass the handler the files name string. It expects the file to exist in your App presets folders…