How to send a mail as an attachment in a mail with AppleScript?

Question

Hi,
I want to manage my spam using the advices found in support.apple website :
OS X Mail
Open the message and choose “Forward as Attachment” from the Message menu.
Forward the message to iCloud [email protected].
Forward the message again to abuse@domain, replacing domain with the part of the sender's email address after the @ symbol. For example, if the sender's email address is [email protected], forward the message to [email protected].
I don't know how to make a message as an attachment...
set theAttachment to theMessage
make new attachment with properties {file name:theAttachment} at after last paragraph
Here is my whole script, if it runs, it could be useful :
tell application "Mail"
  -- envoi les messages sélectionnés en PJ à [email protected]
          set theMessages to the selection
          repeat with theMessage in theMessages
                    set theAttachment to theMessage
                    set newMessage to make new outgoing message at end of outgoing messages
                    tell newMessage
                              set subject to "Fwd: " & theMessage's subject
  make new to recipient with properties {address:"[email protected]"}
                              tell content of theMessage
  make new attachment with properties {file name:theAttachment} at after last paragraph
                              end tell
                    end tell
  send newMessage
          end repeat
  -- envoi les messages sélectionnés en PJ à abuse@<domaine du spammeur>
          set theMessages to the selection
          repeat with theMessage in theMessages
                    set theAttachment to theMessage
                    set newMessage to make new outgoing message at end of outgoing messages
                    tell newMessage
                              set subject to "Fwd: " & theMessage's subject
                              set theSpamAddress to theMessage's sender
                              set AppleScript's text item delimiters to {"@"}
                              set spamerDomainName to text item 2 of theSpamAddress
                              set theNewSpamAddress to "abuse@" & spamerDomainName
  make new to recipient with properties {address:theNewSpamAddress}
                              tell content of theMessage
  make new attachment with properties {file name:theAttachment} at after last paragraph
                              end tell
                    end tell
  send newMessage
          end repeat
end tell
Thank you!

Answer 1

Perfect!
You clearly give me the way. Actually I have used the AppleScript Language Guide from https://developer.apple.com to finalize my AppleScript.
You just need to select the spam message(s) in "Mail" application, then run the script.
As I mentionned previously, it just do this automatically :
OS X Mail
Open the message and choose “Forward as Attachment” from the Message menu.
Forward the message to iCloud [email protected].
Forward the message again to abuse@domain, replacing domain with the part of the sender's email address after the @ symbol. For example, if the sender's email address is [email protected], forward the message to [email protected].
Here is the entire working script :
-- Ce script permet de lutter contre le spam.
-- Je me suis appuyé sur les conseils sur http://support.apple.com/kb/TS4019?viewlocale=fr_FR
tell application "Mail"
          set theMessages to the selection
          repeat with theMessage in theMessages
  -- enregistre le message dans un fichier pour le mettre en PJ ensuite
                    set msgContent to source of theMessage
                    set tmpFile to ((path to desktop) as rich text) & "ForwardedMessage"
                    set referenceNumber to open for access tmpFile with write permission
  write msgContent to referenceNumber
  close access referenceNumber
  -- envoi le message sélectionné en PJ à [email protected]
                    set newMessage to make new outgoing message at end of outgoing messages
                    tell newMessage
                              set subject to "Fwd: " & theMessage's subject
  make new to recipient with properties {address:"[email protected]"}
                              tell content of newMessage
  make new attachment with properties {file name:tmpFile} at after last paragraph
                              end tell
                    end tell
  send newMessage
  -- envoi le message sélectionné en PJ à abuse@<domaine du spammeur>
                    set newMessage to make new outgoing message at end of outgoing messages
                    tell newMessage
                              set subject to "Fwd: " & theMessage's subject
                              set theSpamAddress to theMessage's sender
                              set AppleScript's text item delimiters to {"@"}
                              set theSpamAddress to text item 2 of theSpamAddress
                              set AppleScript's text item delimiters to {">"}
                              set spamerDomainName to text item 1 of theSpamAddress
                              set theNewSpamAddress to "abuse@" & spamerDomainName
  make new to recipient with properties {address:theNewSpamAddress}
                              tell content of newMessage
  make new attachment with properties {file name:tmpFile} at after last paragraph
                              end tell
                    end tell
  send newMessage
          end repeat
end tell