How to Split the string using Substr and instr using loop condition

Question

Hi every body,
I have below requirement.
I need to split the string and append with single quotes('') followed by , (comma) and reassign entire values into another variable. so that i can use it where clause of update statement
for example I am reciveing value as follows
ALN varchar2(2000):=(12ERE-3MT-4Y,4IT-5O-SD,OP-K5-456,P04-SFS9-098,90P-SSF-334,3434-KJ4-O28,AS3-SFS0-J33,989-3KL-3434);
Note: In the above variable i see 8 transactions, where as in real scenario i donot how many transaction i may recive.
after modification i need above transactions should in below format
ALTR Varchar2(2000):=('12ERE-3MT-4Y','4IT-5O-SD','OP-K5-456','P04-SFS9-098','90P-SSF-334','3434-KJ4-O28','AS3-SFS0-J33','989-3KL-3434');
kindly help how to use substr and instr in normal loop or for loop or while loop while modifying the above transactions.
Please help me to sort out this issue.
Many Thanks.
Edited by: user627525 on Dec 15, 2011 11:49 AM

Answer 1

Try this - may not be the best way but...:
create or replace type myTableType as table of varchar2(255)
declare
v_array mytabletype;
v_new_str varchar2(4000);
function str2tbl
         (p_str   in varchar2,
          p_delim in varchar2 default '.')
         return      myTableType
    as
        l_str        long default p_str || p_delim;
         l_n        number;
         l_data     myTableType := myTabletype();
    begin
        loop
            l_n := instr( l_str, p_delim );
            exit when (nvl(l_n,0) = 0);
            l_data.extend;
            l_data( l_data.count ) := ltrim(rtrim(substr(l_str,1,l_n-1)));
            l_str := substr( l_str, l_n+length(p_delim) );
        end loop;
        return l_data;
   end;
begin
  v_array := str2tbl ('12ERE-3MT-4Y,4IT-5O-SD,OP-K5-456,P04-SFS9-098,90P-SSF-334,3434-KJ4-O28,AS3-SFS0-J33,989-3KL-3434', ',');
      FOR i IN 1 .. v_array.COUNT LOOP
         v_new_str := v_new_str || ''''||v_array(i)||'''' || ',';
      END LOOP;
   dbms_output.put_line(RTRIM(v_new_str, ','));
end;  
OUTPUT:
=======
'12ERE-3MT-4Y','4IT-5O-SD','OP-K5-456','P04-SFS9-098','90P-SSF-334','3434-KJ4-O28','AS3-SFS0-J33','989-3KL-3434'HTH
Edited by: user130038 on Dec 15, 2011 12:11 PM