How to transfer data within blob column to server

Question

Hi,
I have the following requirement where i have a table which has a blob column that holds the files that are attached to a page using front end. I need to fetch these files and import them to server. How do i go about in achieving this?
Any in\puts would be of great help.
Thanks In Advance.

Answer 1

876841 wrote:
Hi,
I have the following requirement where i have a table which has a blob column that holds the files that are attached to a page using front end. I need to fetch these files and import them to server. How do i go about in achieving this?
Any in\puts would be of great help.Well, if the blob data is stored in columns on the database then it already resides on the server. If you need to save that data as files on the server then it's just a case of writing out the data to a file in the appropriate directory location.
Example code... (untested)...
As sys user:
CREATE OR REPLACE DIRECTORY MY_FILES AS 'c:\myfiles';
GRANT READ,WRITE ON DIRECTORY MY_FILES TO myuser;As myuser:
DECLARE
   -- Data Variables
   v_blob             BLOB;
   v_data_length      NUMBER;
   -- Loop Control Variables
   v_offset           NUMBER := 1;
   v_chunk   CONSTANT NUMBER := 32767; -- maximum chunk size
   -- UTL_FILE variables
   fh                 UTL_FILE.file_type;
BEGIN
   v_blob := ... populate the blob variable here
   v_data_length := DBMS_LOB.getlength (v_blob);
   -- Open the file
   fh := UTL_FILE.fopen ('MY_FILES', 'myfile.dat', 'wb', v_chunk);
   LOOP
      -- Exit when our file offset is bigger than our file
      EXIT WHEN v_offset > v_data_length;
      -- Write the output chunk by chunk
      UTL_FILE.put_raw (fh, DBMS_LOB.SUBSTR (v_blob, v_chunk, v_offset), TRUE);
      -- Increment the offset by the amount written
      v_offset := v_offset + v_chunk;
   END LOOP;
   -- Close the file
   UTL_FILE.fclose (fh);
END;