How to use using clause in execute immediate statement??

Question

Hi ALL,
Can u help me ....
This is the code which I have written...
declare
type rec_typ is table of forall_test%rowtype;
v_rectype rec_typ:=rec_typ();
begin
--poputating records
for i in 1..10000 loop
v_rectype.extend;
v_rectype(v_rectype.last).id:=i;
v_rectype(v_rectype.last).code:=to_char(i);
v_rectype(v_rectype.last).description:='Description :'||to_char(i);
end loop;
execute immediate 'truncate table forall_test';
forall i in v_rectype.first..v_rectype.last
execute immediate 'insert into forall_test values :1' using v_rectype(i);
commit;
end;
But I am getting this ERROR....
execute immediate 'insert into forall_test values :1' using v_rectype(i);
ERROR at line 14:
ORA-06550: line 14, column 61:
PLS-00457: expressions have to be of SQL types
ORA-06550: line 14, column 1:
PL/SQL: Statement ignored
Thanks & Regards,
T.Halder

Answer 1

Thatmeans using statement cannot be a non sql type.True: You need an sql type for this:
e.g. with
create or replace type emp_typ
as
   object (empno number (4),
           ename varchar2 (10 byte),
           job varchar2 (9 byte),
           mgr number (4),
           hiredate date,
           sal number (7, 2),
           comm number (7, 2),
           deptno number (2))
create or replace type emp_tab as table of emp_typ
/you can do
--- an empty test table
SQL> create table emp2
as
   select *
   from emp
   where 1 = 2
Table created.
SQL> declare
   emp2_tab       emp_tab;
begin
  /* fill the collection */
   select emp_typ (empno,
                   ename,
                   job,
                   mgr,
                   hiredate,
                   sal,
                   comm,
                   deptno)
   bulk collect into emp2_tab
   from emp
   where empno like '77%';
  --  forall loop
   forall c in 1 .. emp2_tab.count
      execute immediate 'begin
                           insert into emp2 select * from table(cast(emp_tab(:1) as emp_tab)) t;
                           update emp2 set sal = null where empno = (:1).empno and empno = 7788;
                         end;' using emp2_tab (c);
end;
PL/SQL procedure successfully completed.
SQL> select empno, ename, sal from emp2
     EMPNO ENAME             SAL
      7782 CLARK            2450
      7788 SCOTT               
2 rows selected.