I am trying to add a note in numbers when I can link an action required to my calendar... Is this possible? For example I am using numbers like a CRM and I would like to be able to have my next action required for a customer link to my calendar

Question

I am using numbers as a CRM and one of my columns is called 'Next Action Required' i.e
Next Action Required
Email Douglas on the 02-12-14 about information needed for tour
Call Thomas 0446 393 about booking trip
Thank you in anticipation
Doug

Answer 1

Utterly bizarre. I can't see your two follow-up posts when I'm logged in. However...
Things would be simple if Apple implemented Data Detectors for dates in Numbers, as they have in applications like TextEdit and Script Editor. Then you’d have a system-level means of quickly moving from a selected date in your CRM spreadsheet to Calendar.
Until that happy day arrives, though, we can approximate it with AppleScript and Automator.
First, make sure your Numbers table is called CRM and your column has the header Next action required. (You can change these if you want but you’ll also have to modify the script.) This is the basic setup:
Then, launch Automator and create a new workflow. From the Choose a type… dialog, specify Service.
At the top of the workflow, “Services receives selected…” should be set to text in Numbers.app. (You'll need to choose Other... from the pop-up and then navigate to Numbers.)
In the Library menu at the left, click on Utilities, then drag a Run AppleScript action into the main Automator pane. Delete all the boilerplate text from the script.
It should look like this:
Now copy and paste the script below into the Run AppleScript action.
on run {date_string}
  tell application "Numbers"
  tell document 1
  tell active sheet
  try
  set crm_table to (item 1 of (every table whose name is "CRM"))
  on error
  display dialog "No CRM table in this sheet"
  return
  end try
  tell crm_table
  try
  set the_selection to selection range
  set the_row to row 1 of the_selection
  on error
  display dialog "Select some text in a cell"
  return
  end try
  set the_col to item 1 of (column of the_selection)
  set header_cell to cell 1 of the_col
  if value of header_cell is "Next action required" then my run_calendar(date_string)
  end tell
  end tell
  end tell
  end tell
end run
on run_calendar(date_string)
  try
  set date_string to date_string as string
  set real_date to date (date_string)
  on error
  set real_date to (current date)
  end try
  tell application "Calendar"
  activate
  switch view to day view
  try
  view calendar at real_date
  on error the_err
  display dialog the_err
  end try
  end tell
end run_calendar
Click the little hammer at the top to make sure that the script compiles (indents and colours in). If it doesn’t, you may need to sort out some line breaks in the copied and pasted script.
Now save the workflow as Go to date in Calendar. Quit Automator.
So what does the script do? Basically, it looks at the selected text in a Numbers cell and checks to see that the table name is “CRM” and the column header is “Next Action Required”. It then tries to convert the selected text into a valid date. If it can, it takes you to that date in Calendar. If it can’t, it takes you to today’s date. In both cases it switches Calendar to day view. You have to bear in mind that if you select all of “10/10/14 Call John re contract” it won’t understand that part of this is a date, and won’t go to October 10.  You'd have to select just "10/10/14"
To run the Service, right-click or control-click on the selected text and go down to Services, then choose Go to date in Calendar:
Alternatively, run it from Services in the main Numbers menu.
You can set up a keyboard shortcut for any Service in System Preferences - Keyboard - Shortcuts. Post back if you need more info about this.
Tested with Numbers 3.5 (2109). This will not work with Numbers '09.
Hope this works for you, let us know how you get on.
H