"Implicit" Binding in ABAP OO?: the ALV method grid- check_changed_data

Question

In this thread here:
Where/how would you add the actual DB update to BCALV_EDIT_03?
Uwe Schieferstein was kind enough to show that anyone can see the effect or outcome of the ALV check_changed_data method if they just add this code to the PAI of the SAP demo program BCALV_EDIT_03:
MODULE pai INPUT.
  TRANSLATE ok_code TO UPPER CASE.
  save_ok = ok_code.
  CLEAR ok_code.
  CASE save_ok.
    WHEN 'EXIT'.
      PERFORM exit_program.
    WHEN 'SAVE'.
      CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
        EXPORTING
          I_STRUCTURE_NAME                  = 'SFLIGHT'
          I_GRID_TITLE                      =
              'Before CHECK_DATA_CHANGED -> changes not yet retrieved'
        TABLES
          t_outtab                          = gt_outtab
        EXCEPTIONS
          OTHERS                            = 99.
      g_grid->check_changed_data( ).
      CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
        EXPORTING
          I_STRUCTURE_NAME                  = 'SFLIGHT'
          I_GRID_TITLE                      =
              'After CHECK_DATA_CHANGED -> changes retrieved'
        TABLES
          t_outtab                          = gt_outtab
        EXCEPTIONS
          OTHERS                            = 99.
      PERFORM save_data.
    WHEN OTHERS.
*     do nothing
  ENDCASE.
ENDMODULE.                    "pai INPUT
When looking at this code, the following question occurred to me:
<b>Question: How does check_changed_data know the itab to bring the changed back to, since it is called in the PAI with no arguments.</b>
The only answer I can see is that when the grid is first loaded in the PBO of BCALV_EDIT_03 in the usual way:
  if g_custom_container is initial.
    perform create_and_init_alv changing gt_outtab
                                         gt_fieldcat
                                         gs_layout.
  endif.
the ABAP OO engine implicitly "binds" the back-end table gt_outtab to the ALV contol (i.e. the instance of CL_GUI_ALV_GRID that the program creates.)
So, if you answer this question, please do one of two things:
a) confirm that check_changed_data "knows" the correct itab to bring the data back to because the ABAP OO engine has, in fact, implicitly "bound" the control to the itab gt_outtab;
or
b) if this is not true, explain how check_changed_data knows what itab to bring the data back to.
Thanks very much in advance for whatever time anyone can afford to spend on this question.
djh

Answer 1

Hello David
I have modified my previous sample report again to +demonstrate +that the
grid instance knows exactly which itab is displayed. Unfortunately it is already a few years ago when I attended the excellent SAP course BC412 (Dialog Programming using EnjoyControls, held by a chinese SAP employee with a beautiful Palatine dialect). Thus, I +cannot explain +the technical details (which are somehow related to the automation queue and the control framework). 
Here are the new modifications:
(1) Inbetween the data definitions and the local class definition I have added two parameters:
DATA: gt_outtab TYPE TABLE OF sflight.
PARAMETERS:
  p_byref    RADIOBUTTON GROUP rad1,  " pass itab by reference
  p_byval    RADIOBUTTON GROUP rad1.  " pass itab by value
* LOCAL CLASS Definition
(2) The parameters are evaluated in PBO module PBO:
*       MODULE PBO OUTPUT                                             *
MODULE pbo OUTPUT.
  SET PF-STATUS 'MAIN100'.
  SET TITLEBAR 'MAIN100'.
  IF g_custom_container IS INITIAL.
    IF ( p_byval = 'X' ).
      PERFORM create_and_init_alv_byval
                           CHANGING gt_outtab
                                    gt_fieldcat
                                    gs_layout.
    ELSE.  " ( p_byref = 'X' ).
      PERFORM create_and_init_alv CHANGING gt_outtab
                                           gt_fieldcat
                                           gs_layout.
    ENDIF.
  ENDIF.
ENDMODULE.                    "pbo OUTPUT
(3) And here is the difference between the two routines:
*&      Form  create_and_init_alv_byval
*       text
*      <--P_GT_OUTTAB  text
*      <--P_GT_FIELDCAT  text
*      <--P_GS_LAYOUT  text
FORM create_and_init_alv_byval
                  CHANGING
                        value(pt_outtab)  LIKE gt_outtab[]  " by value
                        pt_fieldcat TYPE lvc_t_fcat
                        ps_layout TYPE lvc_s_layo.
  PERFORM create_and_init_alv CHANGING pt_outtab
                                       pt_fieldcat
                                       ps_layout.
ENDFORM.                    " create_and_init_alv_byval
*&      Form  CREATE_AND_INIT_ALV
*       text
*      <--P_GT_OUTTAB  text
*      <--P_GT_FIELDCAT  text
*      <--P_GS_LAYOUT  text
FORM create_and_init_alv
                  CHANGING
                        pt_outtab  LIKE gt_outtab[]  " by reference
                        pt_fieldcat TYPE lvc_t_fcat
                        ps_layout TYPE lvc_s_layo.
  DATA: lt_exclude TYPE ui_functions.
Now the crucial point is that the globally visible itab gt_outtab is passed
(a) by value to method g_grid->set_table_for_first_display (routine CREATE_AND_INIT_ALV_BYVAL)
(b) by reference to method g_grid->set_table_for_first_display (routine CREATE_AND_INIT_ALV_BYVAL)
If you run the report with the default (p_byref = 'X') then the report behave exactly like the original sample report.
However, if you choose p_byval = 'X' then the reports dumps as soon as you try to change the values of the ALV list (e.g. change a planetype and hit ENTER or even sorting is sufficient).
Why? The itab passed by value to the grid instance is not the same like gt_outtab!
Conclusion: Do not try to fool the grid instance...
Regards
  Uwe
PS: The entire coding of the adjusted sample reports is shown below:
report ZUS_SDN_BCALV_EDIT_03_SAVE_1.
**PROGRAM bcalv_edit_03.
* Purpose:
* ~~~~~~~~
* In this example the user may change values of fields
* SEATSOCC (occupied seats) and/or PLANETYPE. The report checks
* the input value(s) semantically and provides protocol
* messages in case of error.
* To check program behavior
* ~~~~~~~~~~~~~~~~~~~~~~~~~
* Change values of the column "occupied seats" or "Planetype" or
* both (in the same line). Try to provocate errors.
* Click on the check symbol or press return to initiate checking.
* (ALV also checks input before any functions like sorting,
* filtering or doubleclick are processed. These functions are
* only active if the input does not contain any errors).
* The ALV Grid Control first checks if the input is correct
* according to DDIC-Information (Type, lenght). Then semantic
* checks are made by the application using event handler method
* HANDLE_DATA_CHANGED.
* Essential steps (search for '§')
* ~~~~~~~~~~~~~~~
* 1.Set status of columns PLANETYPE and SEATSOCC to editable.
* 2.Optionally restrict generic functions to 'change only'.
*   (The user shall not be able to add new lines).
* 3.Optionally register ENTER to raise event DATA_CHANGED.
*   (Per default the user may check data by using the check icon).
* 4.Define and implement event handler to handle event DATA_CHANGED.
* 5.Loop over table MT_GOOD_CELLS to check all values that are
*   valid due to checks according to information of the DDIC.
* 6.Within a check cycle:
* 6a.Get new cell value to check it using method GET_CELL_VALUE.
*    (In this case SEATSOCC).
* 6b.If the value is valid you may want to change values of
*    other cells.
* 6c.If the value is not valid create an protocol entry in
*    the application log.
* 6d.To access old values (which where not changed in this check cycle)
*    use your output table GT_OUTTAB.
* 7.Display application log if an error has occured.
DATA: ok_code LIKE sy-ucomm,
      save_ok LIKE sy-ucomm,
      g_container TYPE scrfname VALUE 'BCALV_GRID_DEMO_0100_CONT1',
      g_grid  TYPE REF TO cl_gui_alv_grid,
      g_custom_container TYPE REF TO cl_gui_custom_container,
      gt_fieldcat TYPE lvc_t_fcat,
      gs_layout TYPE lvc_s_layo,
      g_max TYPE i VALUE 100.
* local class to handle semantic checks
CLASS lcl_event_receiver DEFINITION DEFERRED.
DATA: g_event_receiver TYPE REF TO lcl_event_receiver.
DATA: gt_outtab TYPE TABLE OF sflight.
PARAMETERS:
  p_byref    RADIOBUTTON GROUP rad1,  " pass itab by reference
  p_byval    RADIOBUTTON GROUP rad1.  " pass itab by value
* LOCAL CLASS Definition
*§4.Define and implement event handler to handle event DATA_CHANGED.
CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
* This flag is set if any error occured in one of the
* following methods:
    DATA: error_in_data TYPE c  READ-ONLY.
    METHODS:
      handle_data_changed
         FOR EVENT data_changed OF cl_gui_alv_grid
             IMPORTING er_data_changed.
  PRIVATE SECTION.
*** This flag is set if any error occured in one of the
*** following methods:
**    DATA: error_in_data TYPE c.
* Methods to modularize event handler method HANDLE_DATA_CHANGED:
    METHODS: check_planetype
     IMPORTING
        ps_good_planetype TYPE lvc_s_modi
        pr_data_changed TYPE REF TO cl_alv_changed_data_protocol.
    METHODS: ch_new_plane_v_new_seatsocc
           IMPORTING
              psg_plane TYPE lvc_s_modi
              psg_socc TYPE lvc_s_modi
              ps_saplane TYPE saplane
              pr_data_changed TYPE REF TO cl_alv_changed_data_protocol.
    METHODS: ch_new_plane_v_old_seatsocc
           IMPORTING
              psg_plane TYPE lvc_s_modi
              ps_saplane TYPE saplane
              pr_data_changed TYPE REF TO cl_alv_changed_data_protocol.
    METHODS: check_seatsocc
           IMPORTING
              ps_good TYPE lvc_s_modi
              pr_data_changed TYPE REF TO cl_alv_changed_data_protocol.
* This is a suggestion how you could comment your checks in each method:
* CHECK: fieldname(old/new value) !<comp> fieldname(old/new value)
* IF NOT: (What to tell the user is wrong about the input)
* Remarks:
*  fieldname:       fieldname of table for the corresponding column
*  (old/new value): ckeck with value of GT_OUTTAB or MT_GOOD_CELLS.
*  !<comp>        : the value is valid if the condition <comp> holds.
* Example:
*  CHECK seatsocc(new) !>= seatsmax(old)
*  IF NOT: There are not enough number of seats according to this
*          planetype.
ENDCLASS.                    "lcl_event_receiver DEFINITION
CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_data_changed.
    DATA: ls_good TYPE lvc_s_modi.
    error_in_data = space.
* semantic checks
* Identify columns which were changed and check input
* against output table gt_outtab or other new input values of one row.
* Table er_data_changed->mt_good_cells holds all cells that
* are valid according to checks against their DDIC data.
* No matter in which order the input was made this table is
* ordered by rows (row_id). For each row, the entries are
* sorted by columns according to their order in the fieldcatalog
* (not the defined order using field COL_POS but the order
* given by the position of the record in the fieldcatalog).
* The order is relevant if new inputs in several columns of
* the same row are dependent. In this example,
* method 'ch_new_plane_v_new_seatsocc' needs only to be called
* once since we know that the corresponding check is already done
* when checking column PLANETYPE (see also method 'check_seatsocc').
*§5.Loop over table MT_GOOD_CELLS to check all values that are
*   valid due to checks according to information of the DDIC.
    LOOP AT er_data_changed->mt_good_cells INTO ls_good.
      CASE ls_good-fieldname.
* check if column PLANETYPE of this row was changed
        WHEN 'PLANETYPE'.
          CALL METHOD check_planetype
            EXPORTING
              ps_good_planetype = ls_good
              pr_data_changed   = er_data_changed.
* check if column SEATSOCC of this row was changed
        WHEN 'SEATSOCC'.
          CALL METHOD check_seatsocc
            EXPORTING
              ps_good         = ls_good
              pr_data_changed = er_data_changed.
      ENDCASE.
    ENDLOOP.
*§7.Display application log if an error has occured.
    IF error_in_data EQ 'X'.
      CALL METHOD er_data_changed->display_protocol.
    ENDIF.
  ENDMETHOD.                    "handle_data_changed
  METHOD check_planetype.
* Overview of checks according to field PLANETYPE
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* a) Does the Planetype exists? (check against check table SAPLANE)
* b) Are the number of seats (SEATSMAX) of the new planetype
*    sufficient to fullfill requested bookings (SEATSOCC)?
*    b1) SEATSOCC (occupied seats) also changed within
*        this check cycle.
*    b2) SEATSOCC has not changed within this cycle.
    DATA: l_planetype TYPE s_planetye,
          ls_saplane TYPE saplane,
          ls_good_seatsocc TYPE lvc_s_modi.
* Get new cell value to check it.
* (In this case: PLANETYPE).
    CALL METHOD pr_data_changed->get_cell_value
      EXPORTING
        i_row_id    = ps_good_planetype-row_id
        i_fieldname = ps_good_planetype-fieldname
      IMPORTING
        e_value     = l_planetype.
* existence check: Does the plane exists?
    SELECT SINGLE * FROM saplane INTO ls_saplane WHERE
                                     planetype = l_planetype.
    IF sy-subrc NE 0.
* In case of error, create a protocol entry in the application log.
* Possible values for message type ('i_msgty'):
*    'A': Abort (Stop sign)
*    'E': Error (red LED)
*    'W': Warning (yellow LED)
*    'I': Information (green LED)
      CALL METHOD pr_data_changed->add_protocol_entry
        EXPORTING
          i_msgid     = '0K'
          i_msgno     = '000'
          i_msgty     = 'E'
          i_msgv1     = text-m03           "Flugzeugtyp
          i_msgv2     = l_planetype
          i_msgv3     = text-m05           "exitstiert nicht
          i_fieldname = ps_good_planetype-fieldname
          i_row_id    = ps_good_planetype-row_id.
      error_in_data = 'X'.
      EXIT. "plane does not exit, so we're finished here!
    ENDIF.
* Check if other relevant fields of this row have been changed, too.
    READ TABLE pr_data_changed->mt_good_cells INTO ls_good_seatsocc
                       WITH KEY row_id    = ps_good_planetype-row_id
                                fieldname = 'SEATSOCC'.
    IF sy-subrc = 0.
      CALL METHOD ch_new_plane_v_new_seatsocc
        EXPORTING
          psg_plane       = ps_good_planetype
          psg_socc        = ls_good_seatsocc
          ps_saplane      = ls_saplane
          pr_data_changed = pr_data_changed.
    ELSE.
      CALL METHOD ch_new_plane_v_old_seatsocc
        EXPORTING
          psg_plane       = ps_good_planetype
          ps_saplane      = ls_saplane
          pr_data_changed = pr_data_changed.
    ENDIF.
  ENDMETHOD.                           " CHECK_PLANETYPE
  METHOD ch_new_plane_v_new_seatsocc.
    DATA: l_seatsocc TYPE s_seatsocc.
*§5a.Get new cell value to check it using method GET_CELL_VALUE.
* (In this case SEATSOCC).
    CALL METHOD pr_data_changed->get_cell_value
      EXPORTING
        i_row_id    = psg_socc-row_id
        i_fieldname = psg_socc-fieldname
      IMPORTING
        e_value     = l_seatsocc.
* CHECK:  SEATSMAX(of new planetype) !>= SEATSOCC(new value)
* IF NOT: Message for wrong planetype
    IF ps_saplane-seatsmax GE l_seatsocc.
*§5b.If the value is valid you may want to change values of
*    other cells.
      CALL METHOD pr_data_changed->modify_cell
        EXPORTING
          i_row_id    = psg_plane-row_id
          i_fieldname = 'SEATSMAX'
          i_value     = ps_saplane-seatsmax.
    ELSE.
*§5c.If the value is not valid create an protocol entry in
*    the application log.
* Possible values for message type ('i_msgty'):
*    'A': Abort (Stop sign)
*    'E': Error (red LED)
*    'W': Warning (yellow LED)
*    'I': Information (green LED)
      CALL METHOD pr_data_changed->add_protocol_entry
        EXPORTING
          i_msgid     = '0K'
          i_msgno     = '000'
          i_msgty     = 'E'
          i_msgv1     = text-m03               "Flugzeugtyp
          i_msgv2     = ps_saplane-planetype
          i_msgv3     = text-m04             "hat nicht genug Sitzplätze
          i_fieldname = psg_plane-fieldname
          i_row_id    = psg_plane-row_id.
      error_in_data = 'X'.
    ENDIF.
  ENDMETHOD.                    "ch_new_plane_v_new_seatsocc
  METHOD ch_new_plane_v_old_seatsocc.
    DATA: l_old_seatsocc TYPE s_seatsocc,
          ls_outtab TYPE sflight.
*§5d.To access old values (which where not changed in this check cycle)
*    use your output table GT_OUTTAB.
    READ TABLE gt_outtab INTO ls_outtab INDEX psg_plane-row_id.
    l_old_seatsocc = ls_outtab-seatsocc.
* CHECK:  SEATSMAX(of new planetype) !>= SEATSOCC(old value)
* IF NOT: Message for wrong planetype
    IF ps_saplane-seatsmax GE l_old_seatsocc.
* ok->field seatsmax can be changed
      CALL METHOD pr_data_changed->modify_cell
        EXPORTING
          i_row_id    = psg_plane-row_id
          i_fieldname = 'SEATSMAX'
          i_value     = ps_saplane-seatsmax.
    ELSE.
      CALL METHOD pr_data_changed->add_protocol_entry
        EXPORTING
          i_msgid     = '0K'
          i_msgno     = '000'
          i_msgty     = 'E'
          i_msgv1     = text-m03                "Flugzeugtyp
          i_msgv2     = ps_saplane-planetype
          i_msgv3     = text-m04             "hat nicht genug Sitzplätze
          i_fieldname = psg_plane-fieldname
          i_row_id    = psg_plane-row_id.
      error_in_data = 'X'.
    ENDIF.
  ENDMETHOD.                    "ch_new_plane_v_old_seatsocc
*&      Form  CHECK_SEATSOCC
*       text
*      -->P_LS_GOOD  text
*      -->P_ER_DATA_CHANGED  text
  METHOD check_seatsocc.
    DATA: l_seatsocc TYPE s_seatsocc,
          l_old_seatsmax TYPE s_seatsmax,
          ls_outtab TYPE sflight,
          ls_good TYPE lvc_s_modi.
* Check if the planetype has changed, too.
    READ TABLE pr_data_changed->mt_good_cells INTO ls_good
                       WITH KEY row_id    = ps_good-row_id
                                fieldname = 'PLANETYPE'.
    IF sy-subrc EQ 0.
* remark: the check
*   seatsocc (new value) <= seatsmax (new value)
* was already handled by form 'ch_new_plane_v_new_seatsocc'.
* so we are finished here.
      EXIT.
    ENDIF.
* CHECK: seatsocc (new value) <= seatsmax (old value)
* IF NOT: Message that SEATSOCC is to high.
* get new cell value of SEATSOCC.
    CALL METHOD pr_data_changed->get_cell_value
      EXPORTING
        i_row_id    = ps_good-row_id
        i_fieldname = ps_good-fieldname
      IMPORTING
        e_value     = l_seatsocc.
* get old cell value of SEATSMAX
    READ TABLE gt_outtab INTO ls_outtab INDEX ps_good-row_id.
    l_old_seatsmax = ls_outtab-seatsmax.
    IF l_seatsocc > l_old_seatsmax.
      CALL METHOD pr_data_changed->add_protocol_entry
        EXPORTING
          i_msgid     = '0K'
          i_msgno     = '000'
          i_msgty     = 'E'
          i_msgv1     = text-m01  "Die Anzahl der belegten Plätze
          i_msgv2     = text-m02 "übersteigt die Kapazität des Flugzeugs
          i_msgv3     = ls_outtab-planetype
          i_fieldname = ps_good-fieldname
          i_row_id    = ps_good-row_id.
      error_in_data = 'X'.
    ENDIF.
  ENDMETHOD.                           " CHECK_SEATSOCC
ENDCLASS.                    "lcl_event_receiver IMPLEMENTATION
*       MAIN                                                          *
END-OF-SELECTION.
  CALL SCREEN 100.
*       MODULE PBO OUTPUT                                             *
MODULE pbo OUTPUT.
  SET PF-STATUS 'MAIN100'.
  SET TITLEBAR 'MAIN100'.
  IF g_custom_container IS INITIAL.
    IF ( p_byval = 'X' ).
      PERFORM create_and_init_alv_byval
                           CHANGING gt_outtab
                                    gt_fieldcat
                                    gs_layout.
    ELSE.  " ( p_byref = 'X' ).
      PERFORM create_and_init_alv CHANGING gt_outtab
                                           gt_fieldcat
                                           gs_layout.
    ENDIF.
  ENDIF.
ENDMODULE.                    "pbo OUTPUT
*       MODULE PAI INPUT                                              *
MODULE pai INPUT.
  TRANSLATE ok_code TO UPPER CASE.
  save_ok = ok_code.
  CLEAR ok_code.
  CASE save_ok.
    WHEN 'EXIT'.
      PERFORM exit_program.
    WHEN 'SAVE'.
      CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
        EXPORTING
          i_structure_name                  = 'SFLIGHT'
          i_grid_title                      =
              'Before CHECK_DATA_CHANGED -> changes not yet retrieved'
        TABLES
          t_outtab                          = gt_outtab
        EXCEPTIONS
          OTHERS                            = 99.
      g_grid->check_changed_data( ).
      CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
        EXPORTING
          i_structure_name                  = 'SFLIGHT'
          i_grid_title                      =
              'After CHECK_DATA_CHANGED -> changes retrieved'
        TABLES
          t_outtab                          = gt_outtab
        EXCEPTIONS
          OTHERS                            = 99.
      PERFORM save_data.
    WHEN OTHERS.
*     do nothing
  ENDCASE.
ENDMODULE.                    "pai INPUT
*&      Form  SAVE_DATA
*       text
*  -->  p1        text
*  <--  p2        text
FORM save_data .
  IF ( g_event_receiver->error_in_data = 'X' ).
    MESSAGE 'Error in data -> saving not possible' TYPE 'S'.
  ELSE.
    MESSAGE 'Data saved' TYPE 'S'.  " simulates DB update
  ENDIF.
ENDFORM.                    " SAVE_DATA
*       FORM EXIT_PROGRAM                                             *
FORM exit_program.
  LEAVE PROGRAM.
ENDFORM.                    "exit_program
*&      Form  BUILD_FIELDCAT
*       text
*      <--P_GT_FIELDCAT  text
FORM build_fieldcat CHANGING pt_fieldcat TYPE lvc_t_fcat.
  DATA ls_fcat TYPE lvc_s_fcat.
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name = 'SFLIGHT'
    CHANGING
      ct_fieldcat      = pt_fieldcat.
  LOOP AT pt_fieldcat INTO ls_fcat.
    IF    ls_fcat-fieldname EQ 'PLANETYPE'
       OR ls_fcat-fieldname EQ 'SEATSOCC'.
*§1.Set status of columns PLANETYPE and SEATSOCC to editable.
      ls_fcat-edit = 'X'.
* Field 'checktable' is set to avoid shortdumps that are caused
* by inconsistend data in check tables. You may comment this out
* when the test data of the flight model is consistent in your system.
      ls_fcat-checktable = '!'.  "do not check foreign keys
      MODIFY pt_fieldcat FROM ls_fcat.
    ENDIF.
  ENDLOOP.
ENDFORM.                    "build_fieldcat
*&      Form  create_and_init_alv_byval
*       text
*      <--P_GT_OUTTAB  text
*      <--P_GT_FIELDCAT  text
*      <--P_GS_LAYOUT  text
FORM create_and_init_alv_byval
                  CHANGING
                        value(pt_outtab)  LIKE gt_outtab[]  " by value
                        pt_fieldcat TYPE lvc_t_fcat
                        ps_layout TYPE lvc_s_layo.
  PERFORM create_and_init_alv CHANGING pt_outtab
                                       pt_fieldcat
                                       ps_layout.
ENDFORM.                    " create_and_init_alv_byval
*&      Form  CREATE_AND_INIT_ALV
*       text
*      <--P_GT_OUTTAB  text
*      <--P_GT_FIELDCAT  text
*      <--P_GS_LAYOUT  text
FORM create_and_init_alv
                  CHANGING
                        pt_outtab  LIKE gt_outtab[]  " by reference
                        pt_fieldcat TYPE lvc_t_fcat
                        ps_layout TYPE lvc_s_layo.
  DATA: lt_exclude TYPE ui_functions.
  CREATE OBJECT g_custom_container
         EXPORTING container_name = g_container.
  CREATE OBJECT g_grid
         EXPORTING i_parent = g_custom_container.
* Build fieldcat and set columns PLANETYPE and SEATSOCC
* edit enabled.
  PERFORM build_fieldcat CHANGING pt_fieldcat.
*§2.Optionally restrict generic functions to 'change only'.
*   (The user shall not be able to add new lines).
  PERFORM exclude_tb_functions CHANGING lt_exclude.
  SELECT * FROM sflight INTO TABLE pt_outtab UP TO g_max ROWS.
  CALL METHOD g_grid->set_table_for_first_display
    EXPORTING
      is_layout            = ps_layout
      it_toolbar_excluding = lt_exclude
    CHANGING
      it_fieldcatalog      = pt_fieldcat
      it_outtab            = pt_outtab.
* set editable cells to ready for input
  CALL METHOD g_grid->set_ready_for_input
    EXPORTING
      i_ready_for_input = 1.
*§3.Optionally register ENTER to raise event DATA_CHANGED.
*   (Per default the user may check data by using the check icon).
  CALL METHOD g_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_enter.
  CREATE OBJECT g_event_receiver.
  SET HANDLER g_event_receiver->handle_data_changed FOR g_grid.
ENDFORM.                               "CREATE_AND_INIT_ALV
*&      Form  EXCLUDE_TB_FUNCTIONS
*       text
*      <--P_LT_EXCLUDE  text
FORM exclude_tb_functions CHANGING pt_exclude TYPE ui_functions.
* Only allow to change data not to create new entries (exclude
* generic functions).
  DATA ls_exclude TYPE ui_func.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_copy_row.
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_delete_row.
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_append_row.
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_insert_row.
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_move_row.
  APPEND ls_exclude TO pt_exclude.
ENDFORM.                               " EXCLUDE_TB_FUNCTIONS