Importing CSV dates - wrong format

Question

Hi,
I have some CSV data I want to import into Numbers and the CSV has dates. I work with "British" style dd/mm/yy dates but the CSV is "American" mm/dd/yy. How can I persuade Numbers to translate between the two styles?
Thanks,
Dave

Answer 1

Run this script or drag & drop the csv on the script icon (saved as an application).
The embedded dates will be changed from US format to English (French) one.
The edited csv file will be saved in the Temporary items folder an opened by Numbers.
--[SCRIPT csvUStocsvUSEN]
--=====
Yvan KOENIG (VALLAURIS, France)
2011/01/04
--=====
property theApp : "Numbers"
property permitted : {"public.comma-separated-values-text", "public.csv"}
--=====
on run
if my parle_anglais() then
set myPrompt to "Choose a csv file…"
else
set myPrompt to "Choisir un fichier csv…"
end if -- parleAnglais
set allowed to my permitted
if 5 = (system attribute "sys2") then (*
it's Mac OS X 10.5.x with a buggued Choose File *)
set allowed to {}
end if -- 5 = (system…
my commun(choose file with prompt myPrompt of type allowed without invisibles) (* un alias *)
end run
--=====
on open (sel)
my commun(item 1 of sel) (* an alias *)
end open
--=====
on commun(le_csv)
local uti, en_texte, nom_fichier, p2t
tell application "System Events"
try
set uti to type identifier of disk item ("" & le_csv)
on error
set uti to "???"
end try
end tell
if uti is not in permitted then
if my parleanglais() then
error "The document “" & le_csv & "” isn’t a csv one !"
else
error "Le document « " & le_csv & " » n’est pas un fichier csv !"
end if
end if
set les_lignes to paragraphs of (read le_csv)
repeat with l from 1 to count of les_lignes
set une_ligne to item l of les_lignes
if une_ligne contains "/" then
set une_ligne to my decoupe(une_ligne, ",")
repeat with c from 1 to count of une_ligne
set maybe to my decoupe(item c of une_ligne, "/")
if (count of maybe) = 3 then
set item c of une_ligne to my recolle({item 2 of maybe, item 1 of maybe, item 3 of maybe}, "/")
end if -- count of maybe…
end repeat
set item l of les_lignes to my recolle(une_ligne, ",")
end if
-- set item l of les_lignes to my remplace(item l of les_lignes, ",", ";") -- Useful for French systems
end repeat
set en_texte to my recolle(les_lignes, return)
set nom_fichier to (do shell script "date +%Y%m%d%H%M%S.csv")
set p2t to (path to temporary items from user domain)
set lenouveaucsv to ("" & p2t & nom_fichier)
tell application "System Events" to make new file at end of p2t with properties {name:nom_fichier}
set la_longueur to count of en_texte
write en_texte to file lenouveaucsv
tell application "System Events"
repeat while size of file lenouveaucsv < la_longueur
delay 0.2
end repeat
end tell
tell application "Numbers" to open file lenouveaucsv
end commun
--=====
on decoupe(t, d)
local oTIDs, l
set oTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to oTIDs
return l
end decoupe
--=====
on recolle(l, d)
local oTIDs, t
set oTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to d
set t to l as text
set AppleScript's text item delimiters to oTIDs
return t
end recolle
--=====
replaces every occurences of d1 by d2 in the text t
on remplace(t, d1, d2)
local oTIDs, l
set oTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to d1
set l to text items of t
set AppleScript's text item delimiters to d2
set t to l as text
set AppleScript's text item delimiters to oTIDs
return t
end remplace
--=====
on parle_anglais()
return (do shell script "defaults read 'Apple Global Domain' AppleLocale") does not start with "fr_"
end parle_anglais
--=====
-- [/SCRIPT]
Yvan KOENIG (VALLAURIS, France) mardi 4 janvier 2011 09:39:38