Initializing a varying array of records?

Question

Hi everybody,
Given below is a sample code. I have created a varying array of records. However I am unable to initialize the same. Can anybody help me out?
DECLARE
TYPE XRECORD IS RECORD(x NUMBER, y VARCHAR2(12));
TYPE VARRAYTYPE IS VARYING ARRAY(10) OF XRECORD;
xvartab VARRAYTYPE;
BEGIN
----How do I populate/initialize the varying array
--The following line gives me an error
--xvartab := VARRAYTYPE(2,'XXXX');
NULL;
END;

Answer 1

declare
   type xrecord is record(x number, y varchar2(12)); -- declare record type
   xrec xrecord; -- declare working record of type xrecord 
   type varraytype is varying array(10) of xrecord; -- declare varray type
   xvartab varraytype := varraytype(); -- declare and initialise varray of type varraytype   
begin
   -- populate working record 
   xrec.x := 1;
   xrec.y := 'XXXX';
   -- make room for one new record in varray 
   xvartab.extend(1);
   -- insert record into element one of varray
   xvartab(1) := xrec;
   -- populate working record  
   xrec.x := 2;
   xrec.y := 'XXXX';
   -- make room for one new record in varray 
   xvartab.extend(1);
   -- insert record into element two of varray
   xvartab(2) := xrec;
   -- display record in element one of varray
   dbms_output.put_line('ELEMENT ONE : x='||xvartab(1).x||' and y='||xvartab(1).y);  
   -- display record in element two of varray  
   dbms_output.put_line('ELEMENT TWO : x='||xvartab(2).x||' and y='||xvartab(2).y);  
end;
SQL> /
ELEMENT ONE : x=1 and y=XXXX
ELEMENT TWO : x=2 and y=XXXX
PL/SQL procedure successfully completed.
SQL>