Internal Oracle Error in SYS.UTL_HTTP.READ_TEXT - ORA-6512 @ line 1336

Question

I have a PLSQL program that performs an HTTP POST to fetch data from an external website. The website is returning the contents of a file in the HTTP response. This program has been working for years and just started giving us trouble recently at a particular client. The issue cannot be reproduced locally, only on a specific client machine when trying to download a particular set of XML files through this HTTP interface.
The stack trace is:
ORA-29273: HTTP request failed
ORA-06512: at "SYS.UTL_HTTP", line 1336
ORA-06502: PL/SQL: numeric or value error
ORA-06512: at "SYS.UTL_HTTP", line 1336The code in question is:
PROCEDURE SEND_REQUEST
    p_REQUEST      IN CLOB,
    p_RESPONSE     OUT CLOB,
    p_HEADERNAMES  OUT STRING_COLLECTION,
    p_HEADERVALUES OUT STRING_COLLECTION,
    p_ERRORMESSAGE OUT VARCHAR2
) IS
    v_HTTP_REQ    UTL_HTTP.REQ;
    v_HTTP_RESP   UTL_HTTP.RESP;
    v_REQUEST_LEN NUMBER;
    v_POS         NUMBER;
    v_COUNT       NUMBER;
    v_TEXT        VARCHAR2(8192);
    v_LEN         NUMBER;
BEGIN
    -- raise Request_Failed error if an HTTP error occurs
    UTL_HTTP.SET_RESPONSE_ERROR_CHECK(TRUE);
    UTL_HTTP.SET_DETAILED_EXCP_SUPPORT(FALSE);
    -- extend timeout to 10 minutes
    UTL_HTTP.SET_TRANSFER_TIMEOUT(60 * 10);
    v_HTTP_REQ := UTL_HTTP.BEGIN_REQUEST(G_URL, 'POST');
    -- disable cookies for this request
    UTL_HTTP.SET_COOKIE_SUPPORT(v_HTTP_REQ, FALSE);
    -- authentication
    IF g_USERNAME IS NOT NULL THEN
        UTL_HTTP.SET_AUTHENTICATION(v_HTTP_REQ, g_USERNAME, g_PASSWORD);
    END IF;
    -- upload request body
    v_REQUEST_LEN := DBMS_LOB.GETLENGTH(p_REQUEST);
    UTL_HTTP.SET_HEADER(v_HTTP_REQ, 'Content-Type', 'application/x-www-form-urlencoded');
    UTL_HTTP.SET_HEADER(v_HTTP_REQ, 'Content-Length', v_REQUEST_LEN);
    -- write the CLOB request data
    v_POS := 1;
    WHILE v_POS <= v_REQUEST_LEN LOOP
        v_LEN := 8192;
        DBMS_LOB.READ(p_REQUEST, v_LEN, v_POS, v_TEXT);
        UTL_HTTP.WRITE_TEXT(v_HTTP_REQ, v_TEXT);
        v_POS := v_POS + v_LEN;
    END LOOP;
    -- get the response
    v_HTTP_RESP := UTL_HTTP.GET_RESPONSE(v_HTTP_REQ);
    -- read it into CLOB
    DBMS_LOB.CREATETEMPORARY(p_RESPONSE, TRUE);
    DBMS_LOB.OPEN(p_RESPONSE, DBMS_LOB.LOB_READWRITE);
    LOOP
        BEGIN           
            UTL_HTTP.READ_TEXT(v_HTTP_RESP, v_TEXT, 8192);       
        EXCEPTION
            WHEN UTL_HTTP.END_OF_BODY THEN
                ERRS.LOG_AND_CONTINUE('Send_Request: Exeception occurred reading text from the http response.',
                                      p_LOG_LEVEL => LOGS.C_LEVEL_INFO_MORE_DETAIL);
                v_TEXT := '';
        END;
        EXIT WHEN NVL(LENGTH(v_TEXT), 0) = 0;   
        DBMS_LOB.WRITEAPPEND(p_RESPONSE, LENGTH(v_TEXT), v_TEXT);
    END LOOP;
    DBMS_LOB.CLOSE(p_RESPONSE);
    -- gather response headers
    p_HEADERNAMES := STRING_COLLECTION();
    p_HEADERVALUES := STRING_COLLECTION();
    v_COUNT := UTL_HTTP.GET_HEADER_COUNT(v_HTTP_RESP);
    v_POS := 1;
    WHILE v_POS <= v_COUNT LOOP
        p_HEADERNAMES.EXTEND();
        p_HEADERVALUES.EXTEND();   
        UTL_HTTP.GET_HEADER(v_HTTP_RESP, v_POS, p_HEADERNAMES(p_HEADERNAMES.LAST), p_HEADERVALUES(p_HEADERVALUES.LAST));
        v_POS := v_POS + 1;   
    END LOOP;
    UTL_HTTP.END_RESPONSE(v_HTTP_RESP);
    -- success!
    p_ERRORMESSAGE := NULL;
EXCEPTION
    WHEN UTL_HTTP.REQUEST_FAILED THEN
        ERRS.LOG_AND_CONTINUE('Send_Request: Exeception Request Failed caught.', p_LOG_LEVEL => LOGS.C_LEVEL_INFO_MORE_DETAIL);   
    WHEN OTHERS THEN
        ERRS.LOG_AND_CONTINUE('Send_Request: Exeception Others caught.', p_LOG_LEVEL => LOGS.C_LEVEL_INFO_MORE_DETAIL);   
END SEND_REQUEST;It fails specifically at the section that is reading text from the response:
UTL_HTTP.READ_TEXT(v_HTTP_RESP, v_TEXT, 8192);
...Any thoughts?
I have used a packet sniffer, Wireshark, to monitor the HTTP traffic between the website and database during the issue. There is nothing malformed with the Response content. No special chars that I can find. Etc.
The machine in question that is failing is running 10gR2.
I have done some searching and I found this forum post:
utl_http.read_text and multi-byte support
and this Oracle bug:
https://support.oracle.com/CSP/main/article?cmd=show&type=BUG&id=4015165&productFamily=Oracle
Not really much help.
Any help would be appreciated.
Thanks,
GatorPaul
Edited by: 939368 on Jun 7, 2012 2:27 PM

Answer 1

In this case, and most cases, the NLS_LENGTH_SEMANTICS is set to 'BYTE'. Realize that this is an Oracle application that we deploy into an external customer environment and we do not always have the ability to control NLS Settings.
So, based on your explanation, I would expect that an approach like this would fix it:
v_TEXT VARCHAR2(32766);
UTL_HTTP.READ_TEXT(v_HTTP_RESP, v_TEXT, 8192);
Here we are saying, get the next 8192 characters, but put that into a buffer that allows up to 32K bytes. This should allow for the enough room for up to 4 bytes per character. Am I understanding you correctly?
But here is my question:
I put a fix in place today, where I increased both the v_TEXT byte size and the GET_TEXT 'len' parameter to 32766 and it fixed the issue. By doing that, I am telling it: Give me the next 32766 characters and put it into a VARCHAR2(32766). Given your explanation, I would expect this to overflow the v_TEXT variable as well, or at least have the potential to do so.
We were processing 5 different XML responses. They were all failing originally. After the change, they all passed. Their sizes were 47K, 21K, 14K, 48K, and 21K. If the XML file was small, < 32K then maybe is slipped under the radar given the new buffer size of 32766. But what about the 2 files that were over 32K. Very curious on your thoughts. I did not have a loop counter in there to see how many times it was looping to parse the 48K file. With a new buffer size of 32K I would expect it to loop 2x. But, I know in this case, the file was streamed over the network using 14 smaller TCP packets, none of which were more than 9000 bytes. Maybe the PLSQL looped 14 times as well.
When the process was failing for all 5 files, I do know at that time it was always failing on the first loop (first 8192 characters).
Anyway, Thanks for the advice. I will let you guys know if I uncover anymore info.
G8torPaul
Edited by: G8torPaul on Jun 12, 2012 2:04 PM
Edited by: G8torPaul on Jun 12, 2012 2:04 PM
Edited by: G8torPaul on Jun 12, 2012 2:05 PM