Is it possible to generate a report in CSV/text format ?

Question

Hello , I received a request from a client to generate a report in CSV/text format ? Is it possible ?
How should I do it ? Thanks.

Answer 1

Hi!
If i understood right, you want to generate a .csv-file from all item-values and records in your / customers form:
So try this procedure:
procedure write_csv_file( p_csv_file in varchar2,
                          p_block    in varchar2 ) is
l_file      client_text_io.file_type;
l_item      varchar2(61) := p_block || '.' || get_block_property ( p_block, first_item );
l_tmp_str   varchar2(32000);
l_delimeter varchar2(1) := ';';  --> change as you need (',' or char(9) for tab)
l_cnt       pls_integer := 1;
l_too_big   exception;
begin
l_file := client_text_io.fopen ( p_csv_file, 'W' );  --> existing file will be deleted!
if
  NOT client_text_io.is_open ( l_file )
then
  message ( 'File ' || p_csv_file || ' could not be opened for writing. Please check filename and path.' );
  message ( ' ' );
  return;
end if;
for l_rec in ( select :system.cursor_block cur_block from dual ) loop --> this one-count-loop is just for Steve C.
                                                                     --> spare one variable and plenty of ram ;-)
  if
    :system.cursor_block != upper ( p_block )
  then
    go_block ( p_block );
  end if;
  first_record;
  loop
    loop
      if
        get_item_property ( l_item, item_type ) in ( 'TEXT ITEM', 'LIST', 'RADIO GROUP', 'CHECKBOX', 'DISPLAY ITEM' )
      then
        if
          length ( l_tmp_str || name_in ( l_item ) || l_delimeter ) > 32000
        then
          raise l_too_big;
           end if;
        l_tmp_str := l_tmp_str || name_in ( l_item ) || l_delimeter;
      end if;
      exit when     l_item = p_block || '.' || get_block_property ( p_block, last_item );
      l_item := p_block || '.' || get_item_property ( l_item, nextitem );
    end loop;
    client_text_io.put_line ( l_file, l_tmp_str );
    l_tmp_str := null;
    exit when :system.last_record = 'TRUE';
    next_record;
    l_item := p_block || '.' || get_block_property ( p_block, first_item );
    l_cnt := l_cnt + 1;
  end loop;
  go_block ( l_rec.cur_block );
end loop;
client_text_io.fclose ( l_file );
message ( l_cnt || ' record/s written to ' || p_csv_file );
message ( ' ' );
--> if you don't use webutil, comment out or delete the following line
--> in forms 6i use host instead of webutil_host.nonblocking.
--> it starts the csv_file-mimetype attached application
webutil_host.nonblocking ( 'cmd /c start ' || p_csv_file );
exception when
  l_too_big
then
  client_text_io.fclose ( l_file );
  message ( 'Error: The amount of data in record ' || l_cnt || ' exceeds the max. length of 32000 characters. Your file is not complete.' );
  message ( ' ' );
when
  others
then
  client_text_io.fclose ( l_file );
  message ( 'Error ' || sqlerrm || ' in write_csv_file Procedure.' );
  message ( ' ' );
end;You can call this procedure in your when-button-pressed-trigger like:
begin
write_csv_file( 'c:\temp\test.csv', :system.cursor_block );
end;Hope this is what you are looking for.
Regards