Is there a way to accomplish a dynamic image insertion linkage?

Question

I have a cell in my spreadsheet where I have inserted a graphic, let's say .../GRAPHICS/PICTURE-1.JPG for reference.
I would like the image displayed in Numbers to change dynamically by virtue of my changing the contents of .../GRAPHICS/PICTURE-1.JPG (through renaming, of course).
What I really want is a dynamic link, rather than having to manually reinsert the image. (No problem for PICTURE-1.JPG, but more than a minor annoyance when it gets to, say, PICTURE-23.JPG, right?)
Thanks for any suggestions.
-- Ranebo

Answer 1

Hello
I hope that the given script will fit your needs.
I took care to comment many instructions.
--(SCRIPT exchangePictures.app]
Save the script as a Bundle Application
In the bundle, create a folder whose name is the one of the iWork's document to change (stripped of its name extension)
In this folder, store the "new" pictures in a subfolder named "New".
CAUTION: as you wrote, YOU MUST check that new files dimensions are the same that the old ones.
Drag and drop the icon of an iWork document on the script's icon.
The "old" embedded files having a "replacement" in the folder "New" are duplicated in the folder "Old"
and the replacement file is copied in the document's package.
Yvan KOENIG (28 mars 2008)
property permitted : {"com.apple.iwork.keynote.keynote", "com.apple.iwork.numbers.numbers", "com.apple.iwork.pages.pages"}
property nouveau : "New"
property ancien : "Old"
-- ==================
(* lignes exécutées si on double clique l'icône du script
• lines executed if on double click the script's icon *)
on run
tell application "System Events" to set _ to choose file of type permitted
my traiteFichier(_)
end run
-- ==================
(* lignes exécutées si on glisse-dépose l'icône d'un document iWork sur l'icône du script
• lines executed if we drag&drop the icon of an iWork document on the script's icon *)
on open (sel)
local theFile, ti
set theFile to first item of sel
tell application "System Events" to set ti to type identifier of theFile
if ti is in permitted then my traiteFichier(theFile) (*
if the dropped document is not a Pages or a Numbers one, exit. *)
end open
-- ==================
on traiteFichier(theDoc) (*
theDoc is an iWork's document *)
set theDoc to theDoc as Unicode text
tell application "System Events" to tell disk item theDoc
set leNom to name (* document's name *)
set nomExt to name extension (* document's name extension *)
set liste to files (* the files stored in the document's package *)
end tell
set nomDossierDoc to (text 1 thru -(2 + (length of nomExt)) of leNom) & ":" (*
the document's name minus the name extension *)
tell application "System Events" to set myPath to (path to me) as Unicode text (*
grab the script's pathname *)
if myPath ends with "Script Editor.app:" then return (* The script can't be used from the Script Editor *)
set DossierDoc to myPath & nomDossierDoc
set DossierDocNew to DossierDoc & nouveau & ":"
tell application "System Events"
set dossierExiste to exists folder DossierDoc
set newExiste to exists folder DossierDocNew
end tell
if (dossierExiste is true) and (newExiste is true) then (*
the required folders are available *)
set DossierDocOld to DossierDoc & ancien & ":"
tell application "System Events"
if not (exists folder DossierDocOld) then make new folder at end of folder DossierDoc with properties {name:ancien}
end tell (*
now we are sure that the folder DossierDocOld exists *)
repeat with f in liste (*
with every files stored in the documents's package *)
set f to f as alias
tell application "Finder" (*
We must use Finder because at this time, System Events is unable to duplicate *)
set nf to name of f
if exists file (DossierDocNew & nf) then (*
here we are sure that we have a replacement file *)
try
duplicate f to folder DossierDocOld with replacing (*
stores a duplicate of the original file *)
end try
try
duplicate file (DossierDocNew & nf) to (theDoc as alias) with replacing (*
put the new file in the document's package *)
end try
end if -- exists file…
end tell -- to Finder
end repeat
end if -- dossierExiste and newExiste
end traiteFichier
--[/SCRIPT]
Yvan KOENIG (from FRANCE vendredi 28 mars 2008 19:51:15)