Is there a way to find which process s chain was scheduled?

Question

I am developing a query on 0TCT_C21. Is there a way to find which process chains were scheduled to run? I want to see only those process chains. 
If 0TCT_C21 does not have the information, is it a way to get from somewhere else (i.e., some other tables using virtual characteristic or so  ...).
Thanks a lot,

Answer 1

You need to use a combination of tables and function modules.
Table TBTCO contains list of jobs with job status 'S' for scheduled
Table TBTCP contains the program name and variant scheduled in that job
you need to use a function module to know the chain name using the above program name and variant.
I have written a sample code to do this. feel free to change it as per your needs.
REPORT  ztest4.
TYPES: BEGIN OF l_s_scheduled,
       jobname  TYPE tbtco-jobname,
       jobcount TYPE tbtco-jobcount,
       sdlstrtdt TYPE tbtco-sdlstrtdt,
       sdlstrttm TYPE tbtco-sdlstrttm,
       progname TYPE tbtcp-progname,
       variant TYPE tbtcp-variant,
       chain   TYPE rspc_chain,
  END OF l_s_scheduled.
DATA: l_t_scheduled TYPE STANDARD TABLE OF l_s_scheduled,
      l_t_valtab    TYPE STANDARD TABLE OF rsparams,
      l_w_valtab    TYPE rsparams.
FIELD-SYMBOLS     <l_f_scheduled> TYPE l_s_scheduled.
SELECT a~jobname a~jobcount a~sdlstrtdt a~sdlstrttm b~progname b~variant
INTO CORRESPONDING FIELDS OF TABLE l_t_scheduled
   FROM tbtco AS a JOIN tbtcp AS b
              ON a~jobname = b~jobname AND
                 a~jobcount = b~jobcount
WHERE a~jobname = 'BI_PROCESS_TRIGGER' AND
      a~status = 'S'. "Scheduled
LOOP AT l_t_scheduled ASSIGNING <l_f_scheduled>.
  REFRESH l_t_valtab.
  CALL FUNCTION 'RS_VARIANT_CONTENTS'
    EXPORTING
      report               = <l_f_scheduled>-progname
      variant              = <l_f_scheduled>-variant
    TABLES
      valutab              = l_t_valtab
    EXCEPTIONS
      variant_non_existent = 1
      variant_obsolete     = 2
      OTHERS               = 3.
  IF sy-subrc = 0.
    READ TABLE l_t_valtab INTO l_w_valtab
    WITH KEY selname = 'CHAIN'.
    IF sy-subrc = 0.
      <l_f_scheduled>-chain = l_w_valtab-low.
    ENDIF.
    WRITE :/ <l_f_scheduled>-chain, <l_f_scheduled>-sdlstrtdt, <l_f_scheduled>-sdlstrttm.
  ENDIF.
ENDLOOP.
The structure l_s_scheduled in the above program can be extended with more fields and can be used as extract structure in a generic datasource  of type function module and can be fed into a DSO for reporting.
https://www.sdn.sap.com/irj/servlet/prt/portal/prtroot/com.sap.km.cm.docs/library/business-intelligence/d-f/functional%20module%20based%20generic%20datasource%20part%20i.pdf
Hope it helps!