Issue with Mulidimensional Nested Table

Question

Hi All,
I am studing Multidimensional Nested table and have the below code:
DECLARE
  TYPE table_type1 IS TABLE OF INTEGER;
  TYPE table_type2 IS TABLE OF TABLE_TYPE1;
  table_tab1 table_type1 := table_type1();
  table_tab2 table_type2 := table_type2(table_tab1);
BEGIN
  FOR i IN 1 .. 2
  LOOP
    table_tab2.extend;
    table_tab2(i) := table_type1();
    FOR j IN 1 .. 3
    LOOP
      IF i = 1
      THEN
        table_tab1.extend;
        table_tab1(j) := j;
      ELSE
        table_tab1.extend;
        table_tab1(j) := 4 - j;
      END IF;
        table_tab2.extend;
      table_tab2(i)(j) := table_tab1(j);
      DBMS_OUTPUT.PUT_LINE('table_tab2(' || i || ')(' || j || '): ' ||
                           table_tab2(i) (j));
    END LOOP;
  END LOOP;
exception
  when others then
    dbms_output.put_line(sqlerrm);
END;
This code is working fine as of now.But,If i comment below code(table_tab2 is also extended latter):
table_tab2.extend; 
    table_tab2(i) := table_type1();
then it gives me error 'Subscription Beyond count'.
I would like to know why i need to extend table_tab2 twice?
Thanks!

Answer 1

This code is working fine as of now
No, it isn't. Make sure you have serveroutput on. If you do, you get this as script output (I am using SQL Developer):
anonymous block completed
...meaning no exception was raised to client, because you trapped it, but the DBMS Output window gives:
ORA-06533: Subscript beyond count
...with no indication of which line, because you suppressed it (why?). If you drop the worse than useless exception handler, you get:
ORA-06533: Subscript beyond count
ORA-06512: at line 22
06533. 00000 -  "Subscript beyond count"
*Cause:    An in-limit subscript was greater than the count of a varray
           or too large for a nested table.
*Action:   Check the program logic and explicitly extend if necessary.
A bit more helpful, yes? and with less code. Here is a revised block that writes the loop variable product to the nested array, with its output, initialising and extending correctly:
DECLARE
  TYPE table_type1 IS   TABLE OF INTEGER;
  TYPE table_type2 IS   TABLE OF table_type1;
  table_tab1            table_type1;
  table_tab2            table_type2 := table_type2();
BEGIN
  FOR i IN 1..2 LOOP
    table_tab1 := table_type1();
    FOR j IN 1..3 LOOP
      table_tab1.extend;
      table_tab1(j) := i * j;
    END LOOP;
    table_tab2.extend;
    table_tab2(i) := table_tab1;
  END LOOP;
  FOR i IN 1..table_tab2.COUNT LOOP
    FOR j IN 1..table_tab2(i).COUNT LOOP
      DBMS_OUTPUT.PUT_LINE('Row ' || i || ' element ' || j || ' = ' || table_tab2(i)(j));
    END LOOP;
  END LOOP;
END;
Row 1 element 1 = 1
Row 1 element 2 = 2
Row 1 element 3 = 3
Row 2 element 1 = 2
Row 2 element 2 = 4
Row 2 element 3 = 6
You could alternatively dispense with table_tab1 if you prefer, and write directly each element.