Keep Previous Value of Cell

Question

Hi there,
I have two columns, let's call them Event Date (Column A) and Previous Event Date (Column B).
I would like to implement some <acronym title="visual basic for applications">VBA</acronym> code (or use formulas if necessary) that automatically keeps the previous value of Event Date and retains it in the adjacent cell for Previous
Event Date.
For example, if A3 = Jan-03 and I update A3 to Jan-04, B3 would then show Jan-03 as it is the previous value of the cell.
I would like this code to work for a whole column of cells, not just a single cell.
I'm open to any & all ideas and appreciate the help. If any clarifications are necessary, just let me know.

Answer 1

Right-click the sheet tab.
Select View Code from the context menu.
Copy the following code into the worksheet module:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim newVal As Variant
' Code won't work if multiple cells have been changed
If Target.Count > 1 Then
Exit Sub
End If
' Only act if cell in column A has been changed
If Intersect(Range("A:A"), Target) Is Nothing Then
Exit Sub
End If
' Turn off events and screen updating
Application.EnableEvents = False
Application.ScreenUpdating = False
' Get new value
newVal = Target.Value
' Undo to restore old value
Application.Undo
' Copy old value to adjacent cell
Target.Offset(0, 1).Value = Target.Value
' Redo the change
Target.Value = newVal
' Turn on screen updating and events
Application.ScreenUpdating = True
Application.EnableEvents = True
End Sub
Remarks:
If you change multiple cells at once, the code won't do anything.
When you change a cell in column A, that cell will remain the active cell, i.e. Tab or Enter won't activate another cell.
When you change a cell in column A, Undo will be disabled.
Regards, Hans Vogelaar (http://www.eileenslounge.com)