List error in Function REUSE_ALV_GRID_DISPLAY /_\ (urgent)

Question

Hi All 
My system is ECC6, unicode.
I had created a filed text(50), and i put 50 word into the field.
text = '１２３４５６７８９Ａ１２３４５６７８９Ｂ１２３４５６７８９Ｃ１２３４５６７８９Ｄ１２３４５６７８９Ｅ'
When I used the function 'REUSE_ALV_GRID_DISPLAY' to list data
It only list 42 word on screen.
text = '１２３４５６７８９Ａ１２３４５６７８９Ｂ１２３４５６７８９Ｃ１２３４５６７８９Ｄ１２'
How to resolve it ???
Please help me..  Thanks in advance...
Regards,DDT

Answer 1

Hi
Where are you displaying text ? is that part of the column of the record or displaying on the header ?
I am able to display by setting like that .
[Check the screen shot.|http://bp1.blogger.com/_O5f8iAlgdNQ/SAD_cVWiN8I/AAAAAAAAA-U/VW2fzLZ1yIA/s1600-h/grid-744999.JPG]
and program for that .
REPORT  zvenkat_alv_grid.
TABLES:t001.
"Types
TYPES:
      BEGIN OF t_1001,
        bukrs TYPE t001-bukrs,
        butxt TYPE t001-butxt,
        ort01 TYPE t001-ort01,
        land1 TYPE t001-land1,
        text  TYPE string,
      END OF t_1001.
"Work area
DATA:
      w_t001 TYPE t_1001.
"Internal table
DATA:
      i_t001 TYPE STANDARD TABLE OF t_1001.
" ALV Declarations
* Types Pools
TYPE-POOLS:
   slis.
* Types
TYPES:
   t_fieldcat         TYPE slis_fieldcat_alv,
   t_events           TYPE slis_alv_event,
   t_layout           TYPE slis_layout_alv.
* Workareas
DATA:
   w_fieldcat         TYPE t_fieldcat,
   w_events           TYPE t_events,
   w_layout           TYPE t_layout.
* Internal Tables
DATA:
   i_fieldcat         TYPE STANDARD TABLE OF t_fieldcat,
   i_events           TYPE STANDARD TABLE OF t_events.
*&    start of selection
START-OF-SELECTION.
  PERFORM get_data.
*&    end-of-selection.
END-OF-SELECTION.
  PERFORM build_fieldcatlog.
  PERFORM build_events.
  PERFORM build_layout.
  PERFORM list_display.
*&      Form  get_data
FORM get_data .
  SELECT bukrs
         butxt
         ort01
         land1
    FROM t001
    INTO TABLE i_t001
    UP TO 30 ROWS.
w_t001-text = 'aaaaaaaaa1aaaaaaaaa2aaaaaaaaa3aaaaaaaaa4aaaaaaaaa5aaaaaaaaa6aaaaaaaaa7aaaaaaaaa8aaaaaaaaa9aaaaaaaa10'.
modify i_t001 FROM w_t001 INDEX 1.
ENDFORM.                    " get_data
*&      Form  build_fieldcatlog
FORM build_fieldcatlog .
  CLEAR:w_fieldcat,i_fieldcat[].
  PERFORM build_fcatalog USING:
           'BUKRS' 'I_T001' 'BUKRS',
           'BUTXT' 'I_T001' 'BUTXT',
           'ORT01' 'I_T001' 'ORT01',
           'LAND1' 'I_T001' 'LAND1',
           'TEXT'  'I_T001' 'TEXT'.
ENDFORM.                    "BUILD_FIELDCATLOG
*&      Form  BUILD_FCATALOG
FORM build_fcatalog USING l_field l_tab l_text.
  w_fieldcat-fieldname      = l_field.
  w_fieldcat-tabname        = l_tab.
  w_fieldcat-seltext_m      = l_text.
  IF l_field = 'TEXT'.
    w_fieldcat-outputlen      = '120'..
  ENDIF.
  APPEND w_fieldcat TO i_fieldcat.
  CLEAR w_fieldcat.
ENDFORM.                    " build_fieldcatlog
*&      Form  build_events
*       text
FORM build_events.
  CLEAR :
        w_events, i_events[].
  w_events-name = 'TOP_OF_PAGE'."Event Name
  w_events-form = 'TOP_OF_PAGE'."Callback event subroutine
  APPEND w_events TO i_events.
  CLEAR  w_events.
ENDFORM.                    "build_events
*&      Form  build_layout
FORM build_layout .
  w_layout-colwidth_optimize = 'X'.
  w_layout-zebra             = 'X'.
ENDFORM.                    " build_layout
*&      Form  list_display
FORM list_display .
  DATA:
        l_program TYPE sy-repid.
  l_program = sy-repid.
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_callback_program = l_program
      is_layout          = w_layout
      it_fieldcat        = i_fieldcat
      it_events          = i_events
    TABLES
      t_outtab           = i_t001
    EXCEPTIONS
      program_error      = 1
      OTHERS             = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    " list_display
*&      Form  top_of_page
FORM top_of_page.
  DATA :
   li_header TYPE slis_t_listheader,
   w_header  LIKE LINE OF li_header.
  DATA:
        l_date TYPE char10.
  WRITE sy-datum TO l_date.
  w_header-typ  = 'H'.
  CONCATENATE sy-repid ':' 'From Date' l_date INTO w_header-info SEPARATED BY space.
  APPEND w_header TO li_header.
  CLEAR w_header.
  w_header-typ  = 'S'.
  w_header-info = sy-title.
  APPEND w_header TO li_header.
  CLEAR w_header.
  w_header-typ  = 'A'.
  w_header-info = sy-uname.
  APPEND w_header TO li_header.
  CLEAR w_header.
  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary = li_header.
*  w_fieldcat-fieldname      = 'TEXT'.
*  w_fieldcat-tabname        = 'ITAB'.
*  w_fieldcat-seltext_m      = 'Text Description'. "Column heading.
*  w_fieldcat-outputlen      = '120'.              "Max length 120
*  APPEND w_fieldcat TO i_fieldcat.
*  CLEAR w_fieldcat.
ENDFORM.                    "
Regards,
Venkat.O