Locking in forms

Question

i have a doubt in that in my application, users can select some sequential numbers from a table, i am using the following statement to lock a record once the user has selected a record and not to allow the other user to see this particular record and to let him select the next sequential record. The statement i am using is as follows:
SELECT STATUS INTO V_TEMP FROM TABL_SERAIL_NO
WHERE ser_no = R_RCS.RC_SC_ID AND STATUS = 'AA' AND EXPIRY_DATE >= TRUNC(SYSDATE) FOR UPDATE OF STATUS NOWAIT;
In the above statement, the clause 'FOR UPDATE OF STATUS NOWAIT' is used to lock the record. Now, the problem is that when the user exits the front-end session without a commit, the locked record remains locked for sometime, i guess 5-10 mins. I think, my query is clear to u. Now, can u please help me in understanding as to exactly what is happening as it is very urgent.

Answer 1

Hi,
You might want to try the following ON-LOCK trigger:
declare
dummy char(1); -- select .. into variable
row_free boolean not null := false; -- if the record is free, exit the loop and lock it
row_locked exception; -- if the record is locked, ask the user what to do
pragma exception_init(row_locked, -54); -- catch "ORA-00054: RESOURCE BUSY AND .." error
no_tries number not null := 0; -- number of tries
begin
loop
begin
select '1' -- try to lock the current record
into dummy
from emp
where rowid = :emp.rowid
for update nowait;
row_free := true;
exit; -- if success, exit the loop
exception
when row_locked then -- handle error ORA-00054, increment no_tries
no_tries := no_tries + 1;
end;
-- change the alert message
set_alert_property('al_lock', alert_message_text,
'Record locked (attempt '| |no_tries| |'). Continue trying?');
exit when show_alert('al_lock') = alert_button2; -- if user clicks no, exit the loop
end loop;
if row_free then -- record is not locked, let's lock it
lock_record;
else -- we're out of the loop, but the record is not ours
message('Error: record was not reserved for update or delete');
raise form_trigger_failure;
end if;
end;Don't forget to create an alert named AL_LOCK, with two buttons ('Yes' and 'No').
Hope this helps,
Pedro.