Mail script not working since Mavericks (set preview pane is visible)

Question

Anyone have an idea?
Here's a script which worked on Mountain Lion, but fails on Mavericks.  It fails when trying to "set preview pane is visible to false":
FYI - This script mimics a behaviour of Sparrow.
tell application "Mail"
     tell message viewer 0
                    if preview pane is visible then
                                   set mailbox list visible to false
                                   delay 0.1
                                   set preview pane is visible to false
       (* I don't know why this delay is necassary.  It wasn't
                                      when I first wrote this script …cb *)
                                   delay 0.1
                                   tell application "Mail"
                                                  set bounds of window 1 to {0, 0, 400, 1058}
                                   end tell
                    else
                                   tell application "Mail"
                                                set bounds of window 1 to {405, 0, (405 + 1200), 1058}
                                  end tell
                                  set mailbox list visible to true
                                  delay 0.1
                                  set preview pane is visible to true
end if
     end tell
end tell

Answer 1

This post gave me the idea of the following script, which seems to work properly with version 7.1 (1827) of Mail under OS X 10.9.1. The script uses GUI Scripting.
tell application "Mail"
    activate
    tell message viewer 1
        if (preview pane is visible) then
            tell application "System Events" to tell process "Mail"
                tell menu bar item "Mail" of menu bar 1 to ¬
                    click menu item "Preferences…" of menu 1
                tell window 1
                    click button "Viewing" of toolbar 1
                    click checkbox "Use classic layout" of group 1 of group 1
                    click checkbox "Use classic layout" of group 1 of group 1
                    click button 1 -- close window
                end tell
            end tell
        else
            if mailbox list visible then
                set mailbox list visible to false
                delay 0.5
                set mailbox list visible to true
            else
                set mailbox list visible to true
                delay 0.5
                set mailbox list visible to false
            end if
        end if
    end tell
end tell