Making a textframe centre within margins but be left justified

Question

I'd like a textframe to size its width automatically and centre itself within page margins, but for the text to remain left justified. Is this possible? e.g. Three pages of poetry with very different line lengths. If possible this would be some sort of general layout that I could then drop different pages of text into

Answer 1

I like the double-click-the-right-handle idea. And if you need to add a poem earlier, add a page using the page palette and all of the custom frames will stay with their poems.
I happen to have an Applescript for shrinking a frame to its longest line and centering it. It's designed to work both for left or centered justified text (I had some poems where the text was centered but the author attribution was right justified, we wanted the right end of that to line up with the right end of whatever the longest line of text is, so shrinking those text frames was important too). You can select all of the frames on a spread and it will adjust each of them to its longest line, or if you've got text selected it will work on whatever frame the cursor is in. I've adapted it below to an 8.5 x 11 page document, but it's pretty straightforward to change. You'll want to define LeftColumnCenter to the horizontal offset, in picas, of the centerline of the left page; and likewise RightColumnCenter to the centerline of the right page.
Assign this a keystroke shortcut, and your job should zip along.
tell application "Adobe InDesign CS3"
tell view preferences of active document
set horizontal measurement units to picas
end tell
-- Change the following numbers to the horizontal offset, in picas, of
-- the vertical line you want the frame to align to on the left and right pages.
set LeftColumnCenter to 25.5
set RightColumnCenter to 76.5
repeat with SelectionCounter from 1 to count of items in selection
set mySelection to item SelectionCounter of selection
if class of mySelection is not text frame then
set myFrames to parent text frames of item SelectionCounter of selection
set myFrame to item SelectionCounter of myFrames
else
set myFrame to mySelection
end if
-- get the boundaries of the selected frame
set OriginalBounds to geometric bounds of myFrame
set OriginalTop to item 1 of OriginalBounds
set OriginalLeft to item 2 of OriginalBounds
set OriginalBottom to item 3 of OriginalBounds
set OriginalRight to item 4 of OriginalBounds
-- figure out if the selected frame is on the right or left page
set ColumnCenter to LeftColumnCenter
if OriginalLeft is greater than 56 then
set ColumnCenter to RightColumnCenter
end if
-- find the length of each line in the frame and remember the longest one
set NumberOfLines to number of lines in myFrame
set LongestLine to 2
tell view preferences
set horizontal measurement units to points
end tell
repeat with myCounter from 1 to NumberOfLines
if justification of line myCounter of myFrame is in {left align, left justified} then
set StartOfLine to horizontal offset of line myCounter of myFrame
set EndOfLine to end horizontal offset of line myCounter of myFrame
set StartofCharacter to horizontal offset of last character of line myCounter of myFrame
set EndofCharacter to end horizontal offset of last character of line myCounter of myFrame
set ThicknessofCharacter to EndofCharacter - StartofCharacter
set LineLength to (EndOfLine - StartOfLine) - ThicknessofCharacter
if LongestLine is less than (LineLength) then
set LongestLine to (LineLength)
end if
end if
if justification of line myCounter of myFrame is in {center align, center justified, fully justified} then
set StartOfLine to horizontal offset of line myCounter of myFrame
set EndOfLine to end horizontal offset of line myCounter of myFrame
set LineLength to EndOfLine - StartOfLine
--+ (point size of last character of line myCounter of myFrame) * 0.05
if LongestLine is less than (LineLength) then
set LongestLine to (LineLength)
end if
end if
end repeat
--figure out the new width of the frame and assign the new bounds to the frame
set HalfLine to LongestLine / 2
set NewLeft to ColumnCenter - (HalfLine)
set NewRight to ColumnCenter + (HalfLine)
set geometric bounds of object reference of myFrame to {OriginalTop, NewLeft, OriginalBottom, NewRight}
end repeat
end tell