Manipulating result set in cursor

Question

Hello,
BEGIN
FOR record IN ( SELECT empno, ename FROM emp
WHERE ROWNUM <= 1000 ORDER BY empno )
LOOP
-- How can I retrieve last 10 rows here in more productive way?
-- I have to scroll whole loop, or I can jupm directly to
990th row, or something else ?
END LOOP;
END;
Thank you a lot!

Answer 1

SET SERVEROUTPUT ON
DECLARE
  TYPE cursor_type IS REF CURSOR;
  cursor_name         cursor_type;
  TYPE record_type IS RECORD
    (empno            emp.empno%TYPE,
     ename            emp.ename%TYPE);
  rec                 record_type;
BEGIN
  OPEN cursor_name FOR
    'SELECT empno, ename
     FROM   (SELECT empno, ename,
                    RANK () OVER
                         (ORDER BY empno)
                         AS r
             FROM   emp)
     WHERE  r BETWEEN 991 AND 1000';
  LOOP
    FETCH cursor_name INTO rec;
    EXIT WHEN cursor_name%NOTFOUND;
    DBMS_OUTPUT.PUT_LINE (rec.empno
    || ' '
    || rec.ename);
  END LOOP;
END;
-- or
SET SERVEROUTPUT ON
BEGIN
  FOR rec IN
    (SELECT empno, ename
     FROM   (SELECT empno, ename,
                    ROWNUM AS r
             FROM   (SELECT   empno, ename
                     FROM     emp
                     ORDER BY empno)
             WHERE  ROWNUM <= 1000)
     WHERE  r >= 991)
  LOOP
    DBMS_OUTPUT.PUT_LINE (rec.empno
    || ' '
    || rec.ename);
  END LOOP;
END;