Mark different numbers on a list

Question

I need help with a project on Numbers...
I have a list with several numbers (first column), i want to when i write a number on a specific cell (second column), automaticaly the first column with this list numbers mark me the maximum numbers possible to create this result, for example...
Header 1
Header 2
12
42
12
8
4
3
3
2
2
1
I want to with the 42 number (wroten manually) Numbers mark me (i don't know, with a color or something) the 12 12 8 4 3 3. and not marks me the 2 2 1
It's possible or it's a little bit crazy idea?

Answer 1

I believe the script below will give you the full answer to your question. It is a simple script with nothing fancy. The table it works with is also not fancy. A very similar question was asked nearly two years ago and this was the solution.
The script works on Table 1 of Sheet 1 unless you modify the script.
The target number you want to reach must be in cell B1
The number of elements (the number of values in your list) must be in B2. You can have up to 26 elements
The list of numbers must start at cell B3. Sort them ascending as in the table below.
When you run the script it will put a 1 next to the numbers to use
Cell C1 =SUMPRODUCT(B3:B19,C3:C19) verifies the result
To create and use the script:
Start the Automator application
Create a Service using no input for application Numbers
Use the Run Applescript action from the Utilities folder
Copy the script from below and paste it into the action, overwriting the default text
Save it with a descriptive name such as Numbers Recursion
You can now run it from the Numbers/Services menu
global target
global nbr_elem
property stat : {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
property statb : {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
property elems : {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
global best
on run
          local i, r
          set best to 0
          tell application "Numbers" to tell document 1 to tell sheet 1 to tell table 1
                    set target to value of cell 1 of column 2
                    set nbr_elem to value of cell 2 of column 2
                    repeat with i from 1 to nbr_elem
                              set r to i + 2
                              set item i of elems to value of cell r of column 2
                    end repeat
          end tell
          eval(0, 1)
  store_sol()
end run
on copy_stat()
          local i
          repeat with i from 1 to nbr_elem
                    set (item i of statb) to item i of stat
          end repeat
end copy_stat
on store_sol()
          local i, r
          tell application "Numbers" to tell document 1 to tell sheet 1 to tell table 1
                    repeat with i from 1 to nbr_elem
                              set r to i + 2
                              set value of cell r of column 3 to item i of statb
                    end repeat
          end tell
end store_sol
on eval(total, pos)
          local tt, tb
          if pos ≤ nbr_elem then
                    set item pos of stat to 0
  eval(total, pos + 1)
                    set item pos of stat to 1
                    eval(total + (item pos of elems), pos + 1)
          else
                    set tt to total - target
                    if tt < 0 then set tt to -tt
                    set tb to target - best
                    if tb < 0 then set tb to -tb
                    if tt < tb then
                              set best to total
  copy_stat()
                    end if
          end if
end eval