Maximum Time out runtime error

Question

Hi All,
The following query is giving the error message:
SELECT mkpfbudat msegbwart msegwerks msegmatnr mseg~shkzg
         msegmenge msegmeins msegdmbtr maraextwg makt~maktx
    INTO TABLE i_src
    FROM mkpf
      JOIN mseg ON mkpfmblnr = msegmblnr
               AND mkpfmjahr = msegmjahr
      JOIN mara ON msegmatnr = maramatnr
      JOIN makt ON msegmatnr = maktmatnr
    WHERE mkpf~budat IN s_budat AND
          mseg~bwart IN s_bwart AND
          mseg~matnr IN s_matnr AND
          mseg~werks IN s_werks AND
          mara~mtart  = c_mtart AND
          makt~spras  = sy-langu.
The error message is :
The program ZMMPR_KEY_MOVEMENT has exceeded the maximum permitted runtime and therefore has been terminated. 
Can you tell me how we can improve the performance?
Thanks,
Sobhan.

Answer 1

Hi Sobhan,
I remember this problem, getting MBELN's for a date range and material range and BWART range, from the early 90's on an R/3 1.2.
Try it this way:
TABLES: mkpf, mseg, mara.
SELECT-OPTIONS:
  s_budat FOR mkpf-budat,
  s_bwart FOR mseg-bwart,
  s_matnr FOR mseg-matnr,
  s_werks FOR mseg-werks.
PARAMETERS:
  c_mtart TYPE mtart.
TYPES:
  BEGIN OF i_scr_t,
    mblnr LIKE mkpf-mblnr,
    mjahr LIKE mkpf-mjahr,
    budat LIKE mkpf-budat,
    bwart LIKE mseg-bwart,
    werks LIKE mseg-werks,
    matnr LIKE mseg-matnr,
    shkzg LIKE mseg-shkzg,
    menge LIKE mseg-menge,
    meins LIKE mseg-meins,
    dmbtr LIKE mseg-dmbtr,
    extwg LIKE mara-extwg,
    maktx LIKE makt-maktx,
  END OF i_scr_t,
  BEGIN OF mblnr_t,
    mblnr LIKE mkpf-mblnr,
    mjahr LIKE mkpf-mjahr,
    budat LIKE mkpf-budat,
  END OF mblnr_t,
  BEGIN OF mat_t,
    matnr LIKE mara-matnr,
    extwg LIKE mara-extwg,
    mtart LIKE mara-mtart,
    maktx LIKE makt-maktx,
  END OF mat_t.
DATA:
  lt_mblnr TYPE TABLE OF mblnr_t WITH HEADER LINE,
  lt_mat   TYPE HASHED TABLE OF mat_t WITH UNIQUE KEY matnr,
  ls_mat   LIKE LINE OF lt_mat,
  i_scr    TYPE TABLE OF i_scr_t WITH HEADER LINE.
SELECT budat mjahr mblnr FROM mkpf
  INTO CORRESPONDING FIELDS OF TABLE lt_mblnr
  WHERE mkpf~budat IN s_budat.
LOOP AT lt_mblnr.
  SELECT bwart werks matnr shkzg menge meins dmbtr
    FROM mseg
    INTO CORRESPONDING FIELDS OF i_scr
    WHERE mblnr = lt_mblnr-mblnr
      AND mjahr = lt_mblnr-mjahr
      AND bwart IN s_bwart
      AND matnr IN s_matnr
      AND werks IN s_werks.
    READ TABLE lt_mat INTO ls_mat
      WITH TABLE KEY matnr = i_scr-matnr.
    IF sy-subrc <> 0.
      ls_mat-matnr = i_scr-matnr.
      SELECT SINGLE extwg mtart FROM mara
        INTO (ls_mat-extwg, ls_mat-mtart)
        WHERE matnr = ls_mat-matnr.
      SELECT SINGLE maktx FROM makt INTO ls_mat-maktx
        WHERE matnr = ls_mat-matnr
          AND spras = sy-langu.
      INSERT ls_mat INTO TABLE lt_mat.
    ENDIF.
    IF ls_mat-mtart = c_mtart.
      i_scr-extwg = ls_mat-extwg.
      i_scr-maktx = ls_mat-maktx.
      APPEND i_scr.
    ENDIF.
  ENDSELECT.
ENDLOOP.
It does not look very high performing, but in fact, it used only 1/2 an hour instead of 3 days of the version, that corresponds to yours. Yes, I know, a lot changed since 1.2 in the database interface, but just try it and you will see. And forget joining MKPF and MSEG. No database will handle this in a real system.
If you find my answer useful, please don't forget the reward.
Regards,
Juergen
Message was edited by: Juergen Wurth