Modes in Sequential files?

Question

hi,
     what are the modes in sequential files and give brief description.

Answer 1

Hi,
There are 2 modes:
1. Text mode
2. Binary mode
Using Text Mode
To open a file in text mode, use the IN TEXT MODE addition to the OPEN DATASET statement.
Syntax
OPEN DATASET <dsn> FOR .... IN TEXT MODE.
If you read from or write to a file that is open in text mode, the data is transferred line by line. The system assumes that the file has a line structure.
In each TRANSFER statement, the system transfers all bytes (apart from spaces at the end) into the file, and places an end of line marker at the end. For information about the TRANSFER statement, refer to Writing Data to Files.
In each READ DATASET statement, the system reads all of the data up to the next end of line marker. For information about the READ DATASET statement, refer to Reading Data from Files. If the target field is too small, the line is truncated. If it is longer than the line in the file, it is filled with trailing spaces.
You should always use text mode if you want to write strings to files or where you know that an existing file has a line construction. You can, for example, use text mode to read files that you have created using any editor on your application server.
The following example works in R/3 Systems that are running on UNIX systems using ASCII.
DATA FNAME(60) VALUE 'myfile'.
DATA: TEXT(4),
      HEX TYPE X.
OPEN DATASET FNAME FOR OUTPUT IN TEXT MODE.
TRANSFER '12        ' TO FNAME.
TRANSFER '123456  9 ' TO FNAME.
TRANSFER '1234      ' TO FNAME.
OPEN DATASET FNAME FOR INPUT IN TEXT MODE.
READ DATASET FNAME INTO TEXT.
WRITE / TEXT.
READ DATASET FNAME INTO TEXT.
WRITE  TEXT.
READ DATASET FNAME INTO TEXT.
WRITE  TEXT.
OPEN DATASET FNAME FOR INPUT IN BINARY MODE.
SKIP.
DO.
  READ DATASET FNAME INTO HEX.
  If SY-SUBRC <> 0.
    EXIT.
  ENDIF.
  WRITE HEX.
ENDDO.
The output appears as follows:
12 1234 1234
31 32 0A 31 32 33 34 35 36 20 20 39 0A 31 32 33 34 0A
This example opens a file "myfile" for writing in text mode. Three literals with length 10 characters are written to it. After the file has been opened for reading in text mode, the lines are read into the field TEXT (length 4). The first line is filled with two trailing spaces. The last five characters of the second line are truncated. The structure of the file is displayed by opening it in binary mode and reading its contents into the hexadecimal field HEX. The numbers 31 - 36 are the ASCII codes for the digits 1 - 6. 20 is the code for the space character. The end of each line is marked by 0A. Note that any spaces at the end of strings are not written to the file.
Using Binary Mode
To open a file in binary mode, use the IN BINARY MODE addition to the OPEN DATASET statement.
Syntax
OPEN DATASET <dsn> IN BINARY MODE [FOR ....].
If you read from or write to a file that is open in binary mode, the data is transferred byte by byte. The system does not interpret the contents of the file while it is being transferred. If you write the contents of a field to a file, the system transfers all of the bytes in the source field. When you transfer data from a file to a field, the number of bytes transferred depends on the length of the target field. If you then use another ABAP statement to address the target field, the system interprets the field contents according to the data type of the field.
DATA FNAME(60) VALUE 'myfile'.
DATA: NUM1     TYPE I,
      NUM2     TYPE I,
      TEXT1(4) TYPE C,
      TEXT2(8) TYPE C,
      HEX      TYPE X.
OPEN DATASET FNAME FOR OUTPUT IN BINARY MODE.
NUM1  = 111.
TEXT1 = 'TEXT'.
TRANSFER NUM1  TO FNAME.
TRANSFER TEXT1 TO FNAME.
OPEN DATASET FNAME FOR INPUT IN BINARY MODE.
READ DATASET FNAME INTO TEXT2.
WRITE / TEXT2.
OPEN DATASET FNAME FOR INPUT IN BINARY MODE.
READ DATASET FNAME INTO NUM2.
WRITE / NUM2.
OPEN DATASET FNAME FOR INPUT IN BINARY MODE.
SKIP.
DO.
  READ DATASET FNAME INTO HEX.
  If SY-SUBRC <> 0.
    EXIT.
  ENDIF.
  WRITE  HEX.
ENDDO.
The output appears as follows:
###oTEXT
111
00 00 00 6F 54 45 58 54
The program opens the file "myfile" in binary mode and writes the contents of the fields NUM1 and TEXT1 into the file. For information about the TRANSFER statement, refer to Writing Data to Files. The file is then opened for reading, and its entire contents are read into the field TEXT2. For information about the READ DATASET statement, refer to Reading Data from Files. The first four characters of the string TEXT2 are nonsense, since the corresponding bytes are the platform-specific representation of the number 111. The system tries to interpret all of the bytes as characters. However, this only works for the last four bytes. After the OPEN statement, the position is reset to the start of the file, and the first four bytes of the file are transferred into NUM2. The value of NUM2 is correct, since it has the same data type as NUM1. Finally, the eight bytes of the file are read into the field HEX. On the screen, you can see the hexadecimal representation of the file contents. The last four bytes are the ASCII representation of the characters in the word "TEXT".
Regards,
Bhaskar