Multiple SDO_GEOMETRY Objects of type CIRCLE with the same LOCATION

Question

Can i have a single MERCHANT LOCATION hold multiple SDO_GEOMETRY Objects of type CIRCLE ?
For example the use case , i need to have a SDO_GEOMETRY TYPE CIRCLE circle defined for a single MERCHANT LOCATION with a 2 Mile radius as well as a 5 Mile Radius.
is that even possible with Spatial? I know i can add a single geometry for a merchant at once, but i want to give the user the flexibility of choosing the type of geometry for the merchant based on set of rules. hence want to check if this can be done or not?
Thanks in Advance

Answer 1

Person with no name,
Not clear exactly what you need to do here.
You can store two circles with the same centre in a single sdo_geometry but only if you use a polygon with the circle with the greatest radius being the outer ring and the smaller radius the inner ring.
I have a utility in my free COGO plsql package that allows me to create circles for PLANAR data pretty easily as follows:
-- Function...
Create
    function CreateCircle(dCentreX in Number,
                          dCentreY in Number,
                          dRadius in Number)
    return mDSYS.sdo_geometry
    IS
      dPnt1X NUMBER;
      dPnt1Y NUMBER;
      dPnt2X NUMBER;
      dPnt2Y NUMBER;
      dPnt3X NUMBER;
      dPnt3Y NUMBER;
    BEGIN
      -- Compute three points on the circle's circumference
      dPnt1X := dCentreX - dRadius;
      dPnt1Y := dCentreY;
      dPnt2X := dCentreX + dRadius;
      dPnt2Y := dCentreY;
      dPnt3X := dCentreX;
      dPnt3Y := dCentreY + dRadius;
      RETURN MDSYS.SDO_GEOMETRY(2003,NULL,NULL,MDSYS.SDO_ELEM_INFO_ARRAY(1,1003,4),MDSYS.SDO_ORDINATE_ARRAY(dPnt1X, dPnt1Y, dPnt2X, dPnt2Y, dPnt3X, dPnt3Y));
    End;
select sdo_geometry(f.geom.sdo_gtype,
                    f.geom.sdo_srid,
                    sdo_point_type(f.centreX,f.centreY,null),
                    f.geom.sdo_elem_info,
                    f.geom.sdo_ordinates) as mcircle
  from (select 10 as centreX,
               10 as centreY,
               sdo_geom.sdo_xor(cogo.CreateCircle(10,10,2),
                                cogo.CreateCircle(10,10,5),
                                0.005) as geom
          from dual ) f;
-- Results
MCIRCLE
SDO_GEOMETRY(2003,NULL,SDO_POINT_TYPE(10.0,10.0,NULL),SDO_ELEM_INFO_ARRAY(1,1003,2, 11,2003,2),SDO_ORDINATE_ARRAY(10.0,15.0, 5.0,10.0, 10.0,5.0, 15.0,10.0, 10.0,15.0, 10.0,8.0, 8.0,10.0, 10.0,12.0, 12.0,10.0, 10.0,8.0))(This geometry looks like a donut.)
Note that I have included the centre coordinates in the sdo_point of the result sdo_geometry.
To extract each ring:
-- We need a function to return number of rings in a polygon as sdo_util.getNumElems() does not
Create
  Function GetNumRings( p_geometry  in mdsys.sdo_geometry,
                        p_ring_type in integer /* 0 = ALL; 1 = OUTER; 2 = INNER */ )
    Return Number
  Is
    v_elements   pls_integer := 0;
    v_ring_count pls_integer := 0;
    v_etype      pls_integer;
    v_ring_type  pls_integer := case when ( p_ring_type is null OR
                                            p_ring_type not in (0,1,2) )
                                     Then 0
                                     Else p_ring_type
                                 End;
  Begin
    If ( p_geometry is not null ) Then
      v_elements := ( ( p_geometry.sdo_elem_info.COUNT / 3 ) - 1 );
      <<element_extraction>>
      FOR v_i IN 0 .. v_elements LOOP
        v_etype := p_geometry.sdo_elem_info(v_i * 3 + 2);
        If ( ( v_etype in (1003,1005,2003,2005) and 0 = v_ring_type )
          OR ( v_etype in (1003,1005)           and 1 = v_ring_type )
          OR ( v_etype in (2003,2005)           and 2 = v_ring_type ) ) Then
           v_ring_count := v_ring_count + 1;
        End If;
      END LOOP element_extraction;
    End If;
    Return v_ring_count;
  End GetNumRings;
-- Query
with circles as (
  SELECT SDO_GEOMETRY(2003,NULL,SDO_POINT_TYPE(10.0,10.0,NULL),SDO_ELEM_INFO_ARRAY(1,1003,2, 11,2003,2),SDO_ORDINATE_ARRAY(10.0,15.0, 5.0,10.0, 10.0,5.0, 15.0,10.0, 10.0,15.0, 10.0,8.0, 8.0,10.0, 10.0,12.0, 12.0,10.0, 10.0,8.0))
         as geom
    FROM dual
select sdo_util.extract(a.geom,1,e.ringNo) as circle
  from circles a,
       (select level as ringNo from circles a connect by level <= GETNUMRINGS(a.geom)) e;
-- Result
CIRCLE
SDO_GEOMETRY(2003,NULL,SDO_POINT_TYPE(10.0,10.0,NULL),SDO_ELEM_INFO_ARRAY(1,1003,2),SDO_ORDINATE_ARRAY(10.0,15.0, 5.0,10.0, 10.0,5.0, 15.0,10.0, 10.0,15.0))
SDO_GEOMETRY(2003,NULL,SDO_POINT_TYPE(10.0,10.0,NULL),SDO_ELEM_INFO_ARRAY(1,1003,2),SDO_ORDINATE_ARRAY(10.0,8.0, 12.0,10.0, 10.0,12.0, 8.0,10.0, 10.0,8.0))Not sure if this helps you at all....
regards
Simon