Name of file in the header

Question

Hi,
I would like to set automaticaly the name of the file in the header (or the foot) of a document without to write it but after i have save the document. Is it possible ?
Thanks for your response.
PB G4   Mac OS X (10.4.6)   Pages 2

Answer 1

You can use AppleScript to target the header specifically, so you don't have to rely on the active insertion location. But, because Pages can have complicated documents, some care must be taken to get every header in every section.
<pre>
tell application "Pages"
tell front document
set docName to name
set firstSection to section 1
repeat with aSection in every section
tell aSection
-- If reusing headers/footers from the previous section, there's
-- no need to set the value again, unless it's the first section,
-- where there is no previous section.
if not reuse headers and footers or contents of aSection is firstSection then
-- Every section has an odd header
set odd header to docName
-- Some may also have an even header
if different left and right pages then
set even header to docName
end if
-- This may not be desirable, but it's here for completeness
-- In practice different first page is used
-- for a title page, where you might not want the header.
if different first page then
set first page header to docName
end if
end if
end tell
end repeat
end tell
end tell
</pre>
Titanium PowerBook   Mac OS X (10.4.6)