Need Help: UTL_FILE Reading and Writing to Text File

Question

Hello I am using version 11gR2 using the UTL_FILE function to read from a text file then write the lines where it begins with word 'foo' and end my writing to the text file where the line with the word 'ZEN' is found. Now, I have several lines that begin with 'foo' and 'ZEN' Which make for one full paragraph, and in this paragraph there's a line that begins with 'DE4.2'. Therefore,
I need to write all paragraphs that include the line 'DE4.2' in their beginning and ending lines 'foo' and 'ZEN'
FOR EXAMPLE:
FOO/234E53LLID
THIS IS MY SECOND LINE
THIS IS MY THIRD LINE
DE4.2 THIS IS MY FOURTH LINE
THIS IS MY FIFTH LINE
ZEN/DING3434343
FOO/234E53LLID
THIS IS MY SECOND LINE
THIS IS MY THIRD LINE
THIS IS MY FIFTH LINE
ZEN/DING3434343
I am only interested in writing the first paragraph tha includes line DE4.2 in one of ther lines Not the Second paragraph that does not include the 'DE4.2'
Here's my code thus far:
CREATE OR REPLACE PROCEDURE my_app2 IS
infile utl_file.file_type;
outfile utl_file.file_type;
buffer VARCHAR2(30000);
b_paragraph_started BOOLEAN := FALSE; -- flag to indicate that required paragraph is started
BEGIN
-- open a file to read
infile := utl_file.fopen('TEST_DIR', 'mytst.txt', 'r');
-- open a file to write
outfile := utl_file.fopen('TEST_DIR', 'out.txt', 'w');
-- check file is opened
IF utl_file.is_open(infile)
THEN
-- loop lines in the file
LOOP
BEGIN
utl_file.get_line(infile, buffer);
     --BEGINPOINT APPLICATION
IF buffer LIKE 'foo%' THEN
          b_paragraph_started := TRUE;          
     END IF;
     --LOOK FOR GRADS APPS
          IF b_paragraph_started AND buffer LIKE '%DE4%' THEN
          utl_file.put_line(outfile,buffer, FALSE);
END IF;
     --ENDPOINT APPLICATION      
          IF buffer LIKE 'ZEN%' THEN
     b_paragraph_started := FALSE;
          END IF;
utl_file.fflush(outfile);
EXCEPTION
WHEN no_data_found THEN
EXIT;
END;
END LOOP;
END IF;
utl_file.fclose(infile);
utl_file.fclose(outfile);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20099, 'Unknown UTL_FILE Error');
END my_app2;
When I run this code I only get one line: DE4.2 I AM MISSING THE ENTIRE PARAGRAPH
PLEASE ADVISE...

Answer 1

Hi,
Look at where you're calling utl_file.put_line. The only time you're writing anything is immediately after you find the the key word 'DE4', and then you're writing just that line.
You need to store the entire paragraph, and when you reach the end of the paragraph, write the whole thing only if you found the key word, like this:
CREATE OR REPLACE PROCEDURE my_app2 IS
    TYPE  line_collection  
    IS       TABLE OF VARCHAR2 (30000)
           INDEX BY BINARY_INTEGER;
    infile               utl_file.file_type;
    outfile                      utl_file.file_type;
    input_paragraph          line_collection;
    input_paragraph_cnt          PLS_INTEGER     := 0;          -- Number of lines stored in input_paragraph
    b_paragraph_started      BOOLEAN      := FALSE;     -- flag to indicate that required paragraph is started
    found_key_word          BOOLEAN          := FALSE;     -- Does this paragraph contain the magic word?
BEGIN
    -- open a file to read
    infile := utl_file.fopen('TEST_DIR', 'mytst.txt', 'r');
    -- open a file to write
    outfile := utl_file.fopen('TEST_DIR', 'out.txt', 'w');
    -- check file is opened
    IF utl_file.is_open(infile)
    THEN
     -- loop lines in the file
     LOOP
         BEGIN
          input_paragraph_cnt := input_paragraph_cnt + 1;
             utl_file.get_line (infile, input_paragraph (input_paragraph_cnt));
          --BEGINPOINT APPLICATION
          IF LOWER (input_paragraph (input_paragraph_cnt)) LIKE 'foo%' THEN
              b_paragraph_started := TRUE;
          END IF;
          --LOOK FOR GRADS APPS
          IF b_paragraph_started
          THEN
              IF  input_paragraph (input_paragraph_cnt) LIKE '%DE4%'
              THEN
               found_key_word := TRUE;
              END IF;
              --ENDPOINT APPLICATION
              IF input_paragraph (input_paragraph_cnt) LIKE 'ZEN%' THEN
                  b_paragraph_started := FALSE;
               IF  found_key_word
               THEN
                   FOR j IN 1 .. input_paragraph_cnt
                   LOOP
                       utl_file.put_line (outfile, input_paragraph (j), FALSE);
                   END LOOP;
               END IF;
               found_key_word := FALSE;
               input_paragraph_cnt := 0;
              END IF;
          ELSE     -- paragraph is not started
              input_paragraph_cnt := 0;
          END IF;
          EXCEPTION
              WHEN no_data_found THEN
               EXIT;
          END;
      END LOOP;
    END IF;
    utl_file.fclose (infile);
    utl_file.fclose (outfile);
--EXCEPTION
--    WHEN OTHERS THEN
--        raise_application_error(-20099, 'Unknown UTL_FILE Error');
END my_app2;
SHOW ERRORSIf you don't have an EXCEPTION section, the default error handling will print an error message, spcifying exactly what the error was, and which line of your code caused the error. By using your own EXCEPTION section, you're hiding all that information. I admit, the error messages aren't always as informative as we'd like, but they're never less informative than "Unknown UTL_FILE Error'. Don't use your own EXCEPTION handling unless you can improve on the default.
Remember that anything inside quotes is case-sensitive. If your file contains upper-case 'FOO', then it won't be "LIKE 'foo%' ".
Edited by: Frank Kulash on Dec 7, 2011 1:35 PM
You may have noticed that this site normally doesn't display multiple spaces in a row.
Whenever you post formatted text (such as your code) on this site, type these 6 characters:
\{code}
(small letters only, inside curly brackets) before and after each section of formatted text, to preserve spacing.