Newbie: How to manage the number of files in a folder

Question

I have a backup application that runs each day and creates a file in a folder.
I have an iCal scipt which automates this backup to run at a specific time but I would like to modify it so that it deletes the oldest file in the folder. I cannot figure out the best way to do this. Does anyone have any suggestions?

Answer 1

This rather long script finds the oldest file in the complete nested range of a chosen outer folder and deletes it.
property filePathList : {}
property fileDateList : {}
getEveryFileName((choose folder) as alias)
Sort_items(fileDateList, filePathList)
set oldest to item 1 of filePathList
tell application "Finder" to delete oldest
to getEveryFileName(theFolder)
tell application "Finder"
my getNamesDates(get files of theFolder)
set FolderList to folders of theFolder
repeat with everyFolder in FolderList
my getEveryFileName(everyFolder)
end repeat
end tell
end getEveryFileName
to getNamesDates(FileList)
repeat with everyFile in FileList
try
tell application "Finder"
set end of fileDateList to modification date of everyFile
set end of filePathList to everyFile as alias
end tell
on error anError
display dialog anError
end try
end repeat
end getNamesDates
to Sort_items(sortList, SecondList)
-- sorts by the first list (dates), while keeping the second list in the same order.
tell (count sortList) to repeat with i from (it - 1) to 1 by -1
set s to sortList's item i
set r to SecondList's item i
repeat with i from (i + 1) to it
tell sortList's item i to if s > it then
set sortList's item (i - 1) to it
set SecondList's item (i - 1) to SecondList's item i
else
set sortList's item (i - 1) to s
set SecondList's item (i - 1) to r
exit repeat
end if
end repeat
if it is i and s > sortList's end then
set sortList's item it to s
set SecondList's item it to r
end if
end repeat
end Sort_items
dual-core G5/2.3   Mac OS X (10.4.6)   dual screens