Not Getting all the icons in the Toolbar while using using ALV with OOPS

Question

Hello,
But I am not able to get all the Keys in the toolbar for which i have called the method from class  cl_salv_functions_list, by using the following logic.
Though i am getting all except Word Processing, ABC Analysis, Save layout, Information, Get Layout.
FORM ALV_DISPLAY .
  data: lr_functions type ref to cl_salv_functions_list,    "toolbar
        lr_columns type ref to cl_salv_columns,
        LI_COLUMNS TYPE REF TO CL_SALV_COLUMNS_TABLE,    "columns instance
        LI_COL TYPE REF TO CL_SALV_COLUMN_TABLE,        "column instance
        LR_EVENTS TYPE REF TO CL_SALV_EVENTS_TABLE,
        GR_EVENTS TYPE REF TO LCL_HANDLE_EVENTS.
  TRY.                                               "method for ALV display
      CALL METHOD CL_SALV_TABLE=>FACTORY
        EXPORTINg
          LIST_DISPLAY = IF_SALV_C_BOOL_SAP=>FALSE
        IMPORTING
          R_SALV_TABLE = li_alv
        CHANGING
          T_TABLE      = it_po_final.
    CATCH CX_SALV_MSG .
      message e001(00) with text-011.
  ENDTRY.
*calling methods for toolbar
  lr_functions = li_alv->get_functions( ).
  lr_functions->set_default( abap_true ).
  lr_functions->set_print_preview( abap_true ).
  lr_functions->set_view_excel( abap_true ).
  lr_functions->SET_EXPORT_WORDPROCESSOR( abap_true ).
  lr_functions->set_export_localfile( abap_true ).
  lr_functions->SET_EXPORT_MAIL( abap_true ).
  lr_functions->SET_EXPORT_SEND( abap_true ).
  lr_functions->SET_ABC_ANALYSIS( abap_true ).
  lr_functions->SET_GRAPHICS( abap_true )
  lr_functions->SET_LAYOUT_SAVE( abap_true ).
  lr_functions->SET_DETAIL( abap_true ).
  lr_functions->SET_LAYOUT_MAINTAIN( abap_true )
*... set the columns technical
  lr_columns = li_alv->get_columns( ).
  lr_columns->set_optimize( abap_true ).
**get ALV columns
  CALL METHOD LI_ALV->GET_COLUMNS  "get all columns
    RECEIVING
      VALUE = LI_COLUMNS.
  IF LI_COLUMNS IS NOT INITIAL.
*Get EBELN column
    TRY.
        LI_COL ?= LI_COLUMNS->GET_COLUMN( 'EBELN' ). "get EBELN columns to insert hotspot
      CATCH CX_SALV_NOT_FOUND.
      MESSAGE i001(00) with text-012.
    ENDTRY.
* Set the HotSpot for ebeln Column
    TRY.
        CALL METHOD LI_COL->SET_CELL_TYPE "set cell type hotspot
          EXPORTING
            VALUE = IF_SALV_C_CELL_TYPE=>HOTSPOT.
      CATCH CX_SALV_DATA_ERROR .
      MESSAGE i001(00) with text-012.
    ENDTRY.
  ENDIF.
*Register events
*Event handler method for ALV
***handle hotspot click
  LR_EVENTS = LI_ALV->GET_EVENT( ). "get event
  CREATE OBJECT GR_EVENTS.
  SET HANDLER GR_EVENTS->ON_LINE_CLICK FOR LR_EVENTS. "register event handler method
  IF li_alv IS BOUND.        "calling display method for ALV
    li_alv->display( ).
  ENDIF.
ENDFORM.                    " ALV_DISPLAY

Answer 1

Hi Neha,
If you didn't get the answer then follow this one. Yeah and sorry, i checked and found that really you were not getting every icons. I am giving here a sample program.
REPORT  zdc_factory_alv_test
TYPES: BEGIN OF ty_vbak,
           vbeln TYPE vbak-vbeln,
           erdat TYPE erdat,
           auart TYPE auart,
           kunnr TYPE kunnr,
        END OF ty_vbak.
DATA: gt_vbak        TYPE STANDARD TABLE OF ty_vbak,
       gs_vbak        LIKE LINE OF gt_vbak,
       gr_salv         TYPE REF TO cl_salv_table,
       gr_container   TYPE REF TO cl_gui_docking_container.
START-OF-SELECTION.
   CALL SCREEN '3000'.
*&      Module  STATUS_3000  OUTPUT
*       text
MODULE status_3000 OUTPUT.
   SET PF-STATUS '3000'.
   SET TITLEBAR 'FACTORY'.
ENDMODULE.                 " STATUS_3000  OUTPUT
*&      Module  ALV_OUTPUT  OUTPUT
*       text
MODULE alv_output OUTPUT.
   PERFORM get_data.
   PERFORM create_container.
   PERFORM display_alv.
ENDMODULE.                 " ALV_OUTPUT  OUTPUT
*&      Form  GET_DATA
*       text
*  -->  p1        text
*  <--  p2        text
FORM get_data .
   SELECT vbeln erdat auart kunnr
      INTO  TABLE gt_vbak
      FROM  vbak
      UP TO 20 ROWS.
ENDFORM.                    " GET_DATA
*&      Form  CREATE_CONTAINER
*       text
*  -->  p1        text
*  <--  p2        text
FORM create_container .
   IF gr_container IS NOT BOUND.
     IF cl_salv_table=>is_offline( ) EQ if_salv_c_bool_sap=>false.
       CREATE OBJECT gr_container
         EXPORTING
           side      = cl_gui_docking_container=>dock_at_top
           extension = 2000
         EXCEPTIONS
           others    = 1.
     ENDIF.
   ENDIF.
ENDFORM.                    " CREATE_CONTAINER
*&      Form  DISPLAY_ALV
*       text
*  -->  p1        text
*  <--  p2        text
FORM display_alv .
   DATA : lr_columns     TYPE REF TO cl_salv_columns_table.
   DATA : lr_functions   TYPE REF TO  cl_salv_functions_list,
          lr_layout      TYPE REF TO cl_salv_layout,
          ls_layout_key  TYPE salv_s_layout_key.
   TRY.
       CALL METHOD cl_salv_table=>factory
         EXPORTING
           r_container  = gr_container
         IMPORTING
           r_salv_table = gr_salv
         CHANGING
           t_table      = gt_vbak.
     CATCH cx_salv_msg .
   ENDTRY.
   lr_functions = gr_salv->get_functions( ).
   lr_functions->set_all( abap_true ).
   lr_columns = gr_salv->get_columns( ).
   lr_columns->set_optimize( 'X' ).
   lr_layout = gr_salv->get_layout( ).
   ls_layout_key-report = sy-repid.
   lr_layout->set_key( ls_layout_key ).
   lr_layout->set_save_restriction( ).
   gr_salv->display( ).
ENDFORM.                    " DISPLAY_ALV
Note:- Double click on screen name '3000' and it will ask you option of creating screen.
There i have created one module..
After clicking 3000 under output module create MODULE alv_output.
That will look like...
PROCESS BEFORE OUTPUT.
   MODULE status_3000.
   MODULE alv_output.
PROCESS AFTER INPUT.
* MODULE USER_COMMAND_3000.
This is the sample result..
Still if you have any problem, then feel free to ask..
Regards
Dhananjay