ODS and Transformations get inactive after i transport it in PD.

Question

i have transported my  ETL model in production , Now Everything what we have transported has come into production system but transformation and ODS in our ETL model get inactivated . Also while i want to display the transformation it give massege that " 'the infosource that we have created  before the transformation in not active and can not be used . ' 
Our ETL model is like
Cube(now Active)  --- tranformation(Now is in not active state) --  ODS(Now is in not active state) -- transformaion(Now is in not active state) -- infosource(Now in active state) -- transformation(Now in active state) -- PSA .
the part    ": tranformation --  ODS -- transformaion " gets inactivated after transportation also DTP which pull data from ODS to cube also get inactive .
Please suggest me to how i can activate these inactive object  or i have to transport these object again to PD
Thanks .

Answer 1

Hi Bryan ,
        Yes data was their inside the ODS  while transporting , Now i have successfully transported the request , nd now activating ODS transformation nd DTP . Actually i got a prog to activate transformation and DTP and want to share with all ...  . i juz activate mt DTP and transformation though these prog .
Program for DTP ACTIVATION
*& Report  ZDTP_ACTIVATE
*Coded by NBS BI team
*Date: 15-JAN-2010
*Function: For DTPs activation
REPORT  ZDTP_ACTIVATE.
TYPES: BEGIN OF t_dtp,
dtp LIKE rsbkdtpstat-dtp,
objstat LIKE rsbkdtpstat-objstat,
src LIKE rsbkdtp-src,
tgt LIKE rsbkdtp-tgt,
END OF t_dtp.
TYPES: i_dtp TYPE STANDARD TABLE OF t_dtp.
DATA: lv_output(255) TYPE c,
lv_subrc TYPE sysubrc,
  tab_dtp TYPE i_dtp,
  r_dtp TYPE REF TO cl_rsbk_dtp.
SELECTION-SCREEN BEGIN OF BLOCK b1.
SELECTION-SCREEN SKIP 1.
PARAMETERS: p_id TYPE char35.
SELECTION-SCREEN END OF BLOCK b1.
START-OF-SELECTION.
  FIELD-SYMBOLS: <fs_dtp> TYPE t_dtp.
  REFRESH tab_dtp.
  SELECT * FROM rsbkdtp AS a JOIN rsbkdtpstat
         AS b ON adtp = bdtp INTO
        CORRESPONDING FIELDS OF TABLE tab_dtp
         WHERE a~dtp = p_id AND
            a~objvers = 'A' AND
              b~objstat = 'INA'.
  IF tab_dtp IS NOT INITIAL.
    LOOP AT tab_dtp ASSIGNING <fs_dtp>.
      CALL METHOD cl_rsbk_dtp=>factory
        EXPORTING
          i_dtp   = <fs_dtp>-dtp
        RECEIVING
          r_r_dtp = r_dtp.
      IF sy-subrc = 0.
        CALL METHOD r_dtp->activate
          EXPORTING
            i_objvers             = rs_c_objvers-modified
            i_force_activation    = rs_c_true
            i_show_check_protocol = rs_c_false
            i_with_cto            = rs_c_true
          IMPORTING
            e_subrc               = lv_subrc.
        IF lv_subrc = 0.
          CONCATENATE 'Activated DTP : ' <fs_dtp>-dtp ' : ' <fs_dtp>-src '->' <fs_dtp>-tgt INTO lv_output.
        ELSE.
          CONCATENATE 'DTP : ' <fs_dtp>-dtp ' : ' <fs_dtp>-src '->' <fs_dtp>-tgt ' Could Not be Activated' INTO lv_output.
        ENDIF.
      ENDIF.
      WRITE:/ lv_output.
    ENDLOOP.
  ELSE.
    WRITE:/ 'DTP is not Inactive'.
  ENDIF.
Program for TRANSFORMATION ACTIVATION
**& Report  ZTRFN_ACTIVATE
*Coded by NBS BI team.
*Date: 15-Jan-2010
*Function: Activates in-active transformation only.
REPORT  ZTRFN_ACTIVATE.
TYPES: t_tran TYPE rstran,
i_tran TYPE STANDARD TABLE OF t_tran.
DATA: r_tran_maintain TYPE REF TO cl_rstran_maintain,
lv_subrc TYPE sy-subrc,
lv_output(255) TYPE c,
tab_tran TYPE i_tran,
i_s_source TYPE rstran_s_tlogo,
i_s_target TYPE rstran_s_tlogo.
SELECTION-SCREEN BEGIN OF BLOCK b1.
SELECTION-SCREEN SKIP 1.
PARAMETERS: p_id TYPE char35.
SELECTION-SCREEN END OF BLOCK b1.
START-OF-SELECTION.
  FIELD-SYMBOLS: <fs_trans> TYPE t_tran.
  REFRESH tab_tran.
  SELECT * FROM rstran
  INTO TABLE tab_tran
  WHERE tranid = p_id AND objvers = 'A' AND objstat = 'INA'.
  SORT tab_tran.
  IF tab_tran IS NOT INITIAL.
    LOOP AT tab_tran ASSIGNING <fs_trans>.
      TRY.
          CREATE OBJECT r_tran_maintain
            EXPORTING
              i_tranid       = <fs_trans>-tranid
              i_s_source     = i_s_source
              i_s_target     = i_s_target
              i_expert       = rs_c_false
              i_mode         = rsawc_c_tfc-display
              i_with_message = rs_c_true.
        CATCH cx_rstran_not_found .
        CATCH cx_rstran_input_invalid .
        CATCH cx_rstran_cancelled .
        CATCH cx_rstran_not_authorized .
        CATCH cx_rstran_display_only .
        CATCH cx_rstran_already_exist .
        CATCH cx_rstran_error_with_message .
      ENDTRY.
      CALL METHOD r_tran_maintain->check
        EXPORTING
          i_with_display = rs_c_true
        IMPORTING
          e_subrc        = lv_subrc.
      IF lv_subrc = 0.
        CONCATENATE 'Activated Transformation : ' <fs_trans>-tranid ' : ' <fs_trans>-sourcename '->' <fs_trans>-targetname INTO lv_output.
      ELSE.
        CONCATENATE 'Transformation : ' <fs_trans>-tranid ' : ' <fs_trans>-sourcename '->' <fs_trans>-targetname 'Could Not be Activated' INTO lv_output.
      ENDIF.
      IF lv_subrc = 0.
        TRY.
            CALL METHOD r_tran_maintain->execute
              EXPORTING
                i_wrkmode = cl_rstran_stat=>wrkmode_activate
              IMPORTING
                e_subrc   = lv_subrc.
          CATCH cx_rstran_cancelled .
          CATCH cx_rstran_error_with_message .
          CATCH cx_rstran_display_only .
        ENDTRY.
      ENDIF.
      WRITE:/ lv_output.
    ENDLOOP.
  ELSE.
    WRITE:/ 'Transformation is not Inactive'.
  ENDIF.