Office 2007 XLSX Support

Question

hi,
I am looking for a solution that can help me in some standard way to support xlsx support to my ECC6 EHP 4 System.
I want if alv is exported ( any alv report program) in excel it should generate xlsx file Office 2007 standard xlsx file to save.
I am also looking of any class / object / functions that I can use to generate xlsx file from my custom program and send as email or do a GUI_Download.
I know I cannot ask too many questions on single thread, but my requirement is to have a standard solution that supports 2007 office excel file format in download/ upload by default.
I found an OSS not also that refer to same requirement but I want you advice that does it solve my purpose fully.
OSS note: 1286768
Thanks
Anand

Answer 1

Hi,
ALV export to XLSX format can be achieved using CL_SALV_TABLE and CL_BCS, This works with   ECC6  EHP5, not sure about EHP 4.
See the following code snippet to send email as XLSX attachement.
types:
     begin of lty_alv,
     end of lty_alv.
data: lt_alv type standard table of  lty_alv.
data: lo_salv_table type ref to cl_salv_table.
select ... into table lt_alv .....................
cl_salv_table=>factory(
           IMPORTING r_salv_table = lo_salv_table
           CHANGING t_table = lt_alv ).
* Generate XLSX format & send email
     DATA: lo_bcs TYPE REF TO cl_bcs,
           lo_document TYPE REF TO cl_document_bcs,
           lo_distrlist_bcs TYPE REF TO cl_distributionlist_bcs.
     DATA: lv_xml TYPE xstring,
           lt_stream TYPE solix_tab.
     DATA lv_msg TYPE string.
     "Get XML output in Excel xml format
      lv_xml = lo_salv_table->to_xml(
                    xml_type    = if_salv_bs_xml=>c_type_excel_xml
                    xml_flavour = if_salv_bs_c_tt=>c_tt_xml_flavour_full  ).
     lt_stream = cl_bcs_convert=>xstring_to_solix( iv_xstring = lv_xml ).
      lv_msg = 'Mail body text goes here'.
     lo_document = cl_document_bcs=>create_document(
                           i_type = 'RAW'
                           i_text = cl_bcs_convert=>string_to_soli( iv_string = lv_msg )
                           i_subject = 'Mail Subject goes here' ).
      lo_document->add_attachment( i_attachment_type = 'RAW'  "XLS also can be used
                         i_attachment_subject = 'file_name.xlsx'
                         i_att_content_hex = lt_stream ).
      lo_bcs = cl_bcs=>create_persistent( ).
      lo_bcs->set_document( lo_document ).
      lo_bcs->set_sender( i_sender = cl_cam_address_bcs=>create_internet_address( 'sender email id' ) ). "cl_sapuser_bcs=>create( sy-uname )
      lo_distrlist_bcs = cl_distributionlist_bcs=>getu_persistent( i_dliname = 'Distribution list name'           i_private = abap_false ). "Or use create internet address as above
      lo_bcs->add_recipient( i_recipient = lo_distrlist_bcs ).
      lo_bcs->set_send_immediately( abap_true ).
      lo_bcs->send_request->set_link_to_outbox( abap_true ).
      lo_bcs->send( ).
      commit work.
Disadvantage of this method: if mail is opened within SAP Business workplace, it does not identify the file type as it support only 3 character identity as of now. External email clients can open the attachement properly. If you want to open the attachement within SAP, change attachement type to 'XLS' and remove the file extension from file name.
Thanks,
Shajahan