ORA-00604: error occurred at recursive SQL when calling proc via db_link

Question

Hi,
I'm on 9.2.0.8 and got strange issue with simple test case
on source db:
CREATE OR REPLACE PROCEDURE ADMIN.gg_ref(out_tokens OUT SYS_REFCURSOR) is
  BEGIN
  OPEN out_tokens for select dummy from dual;
END ;
Now testing code localy:
SQL> var r refcursor
SQL> declare
  2   output sys_refcursor;
  3  begin
  4   adminx.gg_ref(output);
  5  :r:=output;
  6  end;
  7  /
PL/SQL procedure successfully completed.
SQL> print r
D
X
So its working.
I've got db_link to that db , and now call that proc via dblink from other 9.2.0.8 DB:
var r refcursor
  1  declare
  2   output sys_refcursor;
  3  begin
  4   admin.gg_ref@LINK_NAME(output);
  5  :r:=output;
  6* end;
SQL> /
declare
ERROR at line 1:
ORA-00604: error occurred at recursive SQL level 1
ORA-00900: invalid SQL statementWhats wrong with my code ?
Are there any restriction I'm not aware of ?
Regards
GregG

Answer 1

GregG wrote:
What should my code look like now ?
Should I rewrite this as function returning index by collection or something ?You can use DBMS_SQL - but use the remote package and not the local one. This is a little bit more complex ito call interface than using a ref cursor, but is the very same thing on the server side. DBMS_SQL also provides a more comprehensive set of features than using the ref cursor interface.
The main issue though is additional coding - as DBMS_SQL is a lower level interface (a lot closer to the real Oracle Call Interface/OCI):
--// on remote database the procedure returns a DBMS_SQL cursor instead of a ref cursor
SQL> create or replace procedure FooProc( cur in out number, deptID number ) is
  2          rc      number;
  3  begin
  4          cur := DBMS_SQL.open_cursor;
  5 
  6          DBMS_SQL.parse(
  7                  cur,
  8                  'select ename from emp where deptno = :deptID',
  9                  DBMS_SQL.native
10          );
11 
12          DBMS_SQL.Bind_Variable( cur, 'deptID', deptID );
13 
14          rc := DBMS_SQL.Execute( cur );
15  end;
16  /
Procedure created.
--// from the local database side we call this remote proc
SQL> declare
  2          c               number;  --// instead of using sys_refcursor
  3          empName         varchar2(10); --// buffer to fetch column into
  4  begin
  5          FooProc@testdb( c, 10 );  --/ call the proc that creates the cursor
  6 
  7          --// we need to define our fetch buffer for the 1st column in the
  8          --// SQL projection of that cursor (10 byte fetch buffer for 1st column)
  9          DBMS_SQL.define_column@testdb( c, 1, empName, 10 );
10 
11          --// we now fetch from this cursor, but via the DBMS_SQL
12          --// interface
13          loop
14                  --// fetch the row (exit when 0 rows are fetched)
15                  exit when DBMS_SQL.Fetch_Rows@testdb( c ) = 0;
16 
17                  --// copy value of 1st column in row into the local PL/SQL buffer
18                  DBMS_SQL.column_value@testdb( c, 1, empName );
19 
20                  --// record value it via dbms output
21                  DBMS_OUTPUT.put_line( 'name='||empName||' deptID=10' );
22          end loop;
23 
24          --// close it explicitly as you would a ref cursor
25          DBMS_SQL.Close_Cursor@testdb( c );
26  end;
27  /
name=CLARK deptID=10
name=KING deptID=10
name=MILLER deptID=10
PL/SQL procedure successfully completed.
SQL>