Oracle 9i Trigger not updating first time through

Question

Hi,
I have read a lot of postings but this one seems to be unique. I am trying to update using from Access to Oracle backend database with a Trigger. When I put the code from the update in a test window in the PL/SQL, I step through the code and it doesn't update the first time through. The values from my :old and :new fields are null the first time through. When I change either proj_part_ppv_adj, incorp_date or end_date in the test window and step through the code again, it updates my table.
update statement:
-- Created on 10/17/2005
declare
-- Local variables here
i integer;
begin
-- Test statements here
update pcrit.tpcrit_proj_part
set proj_no = 'TestChris',
mat = '1080373',
plant = 'COR1',
vndr_code = '0000000564',
it_cat = '0',
incorp_date = '15-OCT-2005',
end_date = '31-DEC-2005',
unit_prce_chg = null,
proj_part_ppv_adj = 32500,
edit_id = 'XXXXXX',
edit_dt = to_date('17-OCT-2005 08:10:32 AM',
'DD-MON-YYYY HH:MI:SS AM')
where proj_no = 'TestChris'
and mat = '1080373'
and plant = 'COR1'
and vndr_code = '0000000564'
and it_cat = '0';
commit;
end;
Trigger:
create or replace trigger tpcrit_proj_part_trg_ubr
before update on tpcrit_proj_part
for each row
/* This trigger stores the key values of TPCRIT_PROJ_PART records for
later use by the after-update trigger.
The trigger must be disabled when running the loader or it will
interfere with loading documents from SAP/ODM.
declare
rowParts pcrit_mod_proj_part.typProjPartRowKey;
begin
if :new.proj_no <> :old.proj_no or :new.mat <> :old.mat or
:new.plant <> :old.plant or :new.vndr_code <> :old.vndr_code or
:new.it_cat <> :old.it_cat or :new.incorp_date <> :old.incorp_date or
:new.end_date <> :old.end_date or
:new.proj_part_ppv_adj <> :old.proj_part_ppv_adj then
-- Only perform the task if something other than the comment has changed.
-- Initialize the rowParts record to be added to the list.
rowParts.proj_no := :new.proj_no;
rowParts.mat := :new.mat;
rowParts.plant := :new.plant;
rowParts.vndr_code := :new.vndr_code;
rowParts.it_cat := :new.it_cat;
rowParts.incorp_date := :new.incorp_date;
rowParts.end_date := :new.end_date;
rowParts.proj_part_ppv_adj := :new.proj_part_ppv_adj;
-- Get the project type for this project.
begin
select proj_type
into rowParts.proj_type
from tpcrit_proj
where proj_no = :new.proj_no;
exception
when no_data_found then
rowParts.proj_type := null;
end;
-- Add this part row to the list for after-statement processing.
pcrit_mod_proj_part.add_to_list(rowParts);
end if;
end tpcrit_proj_part_trg_ubr;

Answer 1

Are you lookng at tpcrit_proj_part to see if the update happend, or are you looking for the results of the after update trigger?
I believe that this is exactly what you are doing, except I have left out the after update trigger.
SQL> CREATE TABLE t (id number, id_dt DATE,
  2                  descr varchar2(10), desc2 varchar2(10));
Table created.
SQL> CREATE TRIGGER t_bu
  2     BEFORE UPDATE ON t
  3     FOR EACH ROW
  4  BEGIN
  5     IF :new.id <> :old.id or
  6        :new.id_dt <> :old.id_dt or
  7        :new.descr <> :old.descr or
  8        :new.desc2 <> :old.desc2 THEN
  9        DBMS_OUTPUT.Put_Line('This is all your proceesing');
10     END IF;
11  END;
12  /
Trigger created.
SQL> INSERT INTO t (id, id_dt) VALUES(1, TRUNC(sysdate));
1 row created.
SQL> COMMIT;
Commit complete.
SQL> SELECT * FROM t;
        ID ID_DT       DESCR      DESC2
         1 09-NOV-2005
SQL> UPDATE t
  2  SET descr = 'Descr',
  3      desc2 = 'Desc2'
  4  WHERE id = 1 and
  5        id_dt = TRUNC(sysdate);
1 row updated.So your processing never happened but the update certainly did:
SQL> SELECT * FROM t;
        ID ID_DT       DESCR      DESC2
         1 09-NOV-2005 Descr      Desc2Now, even without a commit:
SQL> UPDATE t
  2  SET descr = 'CHANGED'
  3  WHERE id = 1 and
  4        id_dt = TRUNC(sysdate);
This is all your proceesing
1 row updated.Now, fix the trigger to take NULL into account:
SQL> ROLLBACK;
Rollback complete.
SQL> SELECT * FROM t;
        ID ID_DT       DESCR      DESC2
         1 09-NOV-2005
SQL> CREATE OR REPLACE TRIGGER t_bu
  2     BEFORE UPDATE ON t
  3     FOR EACH ROW
  4  BEGIN
  5     IF (:new.id <> :old.id or
  6         (:new.id IS NULL and :old.id IS NOT NULL) or
  7         (:new.id IS NOT NULL and :old.id IS NULL)) or
  8        (:new.id_dt <> :old.id_dt or
  9         (:new.id_dt IS NULL and :old.id_dt IS NOT NULL) or
10         (:new.id_dt IS NOT NULL and :old.id_dt IS NULL)) or
11        (:new.descr <> :old.descr or
12         (:new.descr IS NULL and :old.descr IS NOT NULL) or
13         (:new.descr IS NOT NULL and :old.descr IS NULL)) or
14        (:new.desc2 <> :old.desc2 or
15         (:new.desc2 IS NULL and :old.desc2 IS NOT NULL) or
16         (:new.desc2 IS NOT NULL and :old.desc2 IS NULL)) THEN
17        DBMS_OUTPUT.Put_Line('This is all your proceesing');
18     END IF;
19  END;
20  /
Trigger created.
SQL> UPDATE t
  2  SET descr = 'Descr',
  3      desc2 = 'Desc2'
  4  WHERE id = 1 and
  5        id_dt = TRUNC(sysdate);
This is all your proceesing
1 row updated.Now, all your processing happens on the first update, and all others:
SQL> SELECT * FROM t;
        ID ID_DT       DESCR      DESC2
         1 09-NOV-2005 Descr      Desc2
SQL> UPDATE t
  2  SET descr = 'CHANGED'
  3  WHERE id = 1 and
  4        id_dt = TRUNC(sysdate);
This is all your proceesing
1 row updated.But only when something changes:
SQL> UPDATE t
  2  SET descr = 'CHANGED'
  3  WHERE id = 1 and
  4        id_dt = TRUNC(sysdate);
1 row updated.If you really see something different, then post a cut and paste of a sqlplus session as I did showing the behaviour you are getting.
TTFN
John