Oracle XE htp-package limitations?

Question

Hello,
I'm developing a web application on my laptop Windows XP pro, Oracle XE 10 + apache + mod_owa. I had some serious issues with htp.p -calls, I'd keep getting this error message, no matter how small I made the htp.p -arguments
Error 6502 calling procedure:
ORA-06502: PL/SQL: numeric or value error: character string buffer too small
ORA-06512: at "SYS.HTP", line 1536
....I then started to wonder about this, and so I copied my packages to another machine (Windows server 2003, Oracle 10g, apache + mod_owa), compiled them and my error disappeared !
Now is this some sort of limitation in Oracle XE, or what?

Answer 1

Funny.. I'm sure that I submitted my response to this yesterday - but it does not show.
Anyway, here it is again. No, there is no limitation I'm aware of - having tested the code below in XE. I have a procedure called WebCall that simulates a mod_plsql call. I've used this to test:
SQL> create or replace type TStrings is table of varchar2(4000);
  2  /                                                         
Type created.
SQL>
SQL> /
Type created.
SQL> create or replace procedure WebTest is
  2          cookie  OWA_COOKIE.cookie;   
  3  begin                                
  4          OWA_UTIL.mime_header('text/html', TRUE );
  5          cookie := OWA_COOKIE.get( 'SOME_CUSTOM_COOKIE' );
  6                                                          
  7          HTP.prn( 'What do you want, universe? (Klingon for "hello world")' );
  8          HTP.prn( '<hr>' );                                                  
  9          HTP.prn( rpad('0',3000,'1') );                                      
10          HTP.prn( '<hr>' );                                                  
11                                                                              
12          if cookie.vals.First is NULL then                                   
13                  HTP.prn( 'Cookie [SOME_CUSTOM_COOKIE] is not set' );        
14          else                                                                
15                  HTP.prn( 'Cookie [SOME_CUSTOM_COOKIE] is set to "'|| cookie.vals( cookie.vals.First )||'"' );
16          end if;                                                                                             
17                                                                                                              
18          HTP.prn( '<hr>' );                                                                                  
19                                                                                                              
20          HTP.prn( 'You are connection from web browser: '|| OWA_UTIL.get_cgi_env( 'HTTP_USER_AGENT' ) );     
21  end;                                                                                                        
22  /                                                                                                           
Procedure created.
SQL>
SQL> create or replace function WebCall( procName varchar2, queryString varchar2 default null ) return TStrings pipelined is
  2          nameList        OWA.vc_arr;                                                                                   
  3          valueList       OWA.vc_arr;                                                                                   
  4          htpBuffer       HTP.htbuf_arr;                                                                                
  5          bufRows         integer         := 99999999;                                                                  
  6          rc              integer;                                                                                      
  7  begin                                                                                                                 
  8          -- name-value list (typical CGI variables)                                                                    
  9          nameList(1) := 'HTTP_COOKIE';                                                                                 
10          nameList(2) := 'HTTP_HOST';                                                                                   
11          nameList(3) := 'HTTP_USER_AGENT';                                                                             
12          nameList(4) := 'QUERY_STRING';                                                                                
13          nameList(5) := 'REMOTE_ADDR';                                                                                 
14          nameList(6) := 'REQUEST_METHOD';                                                                              
15          nameList(7) := 'QUEST_URI';                                                                                   
16                                                                                                                        
17          valueList(1) := 'SOME_CUSTOM_COOKIE=123; SOME_OTHER_COOKIE=foo';                                              
18          valueList(2) := 'localhost';                                                                                  
19          valueList(3) := 'Mozilla/5.0; PL/SQL Interface';                                                              
20          valueList(4) := nvl( queryString, 'param1=value1&pama2=value3' );                                             
21          valueList(5) := 'localhost';                                                                                  
22          valueList(6) := 'GET';                                                                                        
23          valueList(7) := '/custom-web-service';                                                                        
24                                                                                                                        
25          -- initiliase OWA and configure a basic CGI environment                                                       
26          DBMS_SESSION.reset_package;                     -- reset PL/SQL PGA maintaining package state                 
27          rc := OWA.Initialize;                                                                                         
28          OWA.init_cgi_env( 7, nameList, valueList );                                                                   
29          htp.HTBUF_LEN := 255;                                                                                         
30                                                                                                                        
31          -- now call the web enabled PL/SQL procedure                                                                  
32          execute immediate 'begin '||procName||'; end;';                                                               
33                                                                                                                        
34          -- return the output as rows                                                                                  
35          OWA.get_page( htpBuffer, bufRows );                                                                           
36          for i in 1..htpBuffer.Count                                                                                   
37          loop                                                                                                          
38                  PIPE ROW( htpBuffer(i) );                                                                             
39          end loop;                                                                                                     
40                                                                                                                        
41          return;                                                                                                       
42  end;                                                                                                                  
43  /                                                                                                                     
Function created.
SQL> show errors
No errors.     
SQL>           
SQL> col HTML_LINE format a80
SQL>                        
SQL> select                 
  2          rownum          as LINE_NO,
  3          b.column_value  as HTML_LINE
  4  from       TABLE( WebCall('WebTest') ) b
  5  /                                      
   LINE_NO HTML_LINE
         1 Content-type: text/html                                                        
         2 Content-length: 3176                                                           
         3                                                                                
         4 What do you want, universe? (Klingon for "hello world")                        
         5 <hr>                                                                           
         6 01111111111111111111111111111111111111111111111111111111111111111111111111111111
           11111111111111111111111111111111111111111111111111111111111111111111111111111111
           11111111111111111111111111111111111111111111111111111111111111111111111111111111
           111111111111111                                                                
..snipped..
        17 11111111111111111111111111111111111111111111111111111111111111111111111111111111
           11111111111111111111111111111111111111111111111111111111111111111111111111111111
           11111111111111111111111111111111111
        18 <hr>
        19 Cookie [SOME_CUSTOM_COOKIE] is set to "123"
        20 <hr>
        21 You are connection from web browser: Mozilla/5.0; PL/SQL Interface
21 rows selected.
SQL>The WebTest procedure writes a 3000 character string via HTP.PRN. It works fine.
As it accepts a varchar2 parameter, it should be capable of accepting 32KB strings. Note that the size is byte size and not char size. When using a db with a multibyte char set, a single char consumes more than 1 byte of space and then obviously less chars can be send in a 32KB block.
Also note that the limit for the SQL engine for varchar2 is 4000 bytes and not 32KB like the PL engine.
Playing around with the WebCall code, the only time I ran into string size errors, was when changing the HTBUF_LEN parameter to greater than 255. My guess this is a limitation of how the call interface between OWA and mod_plsql has been designed. But this does not limit the actual size of the HTP.PRN to 255 - only the way the data is exchanged (note that the pipeline function returns the data from the HTP buffer in 255 char chunks.