Parallel processing of mass data : sy-subrc value is not changed

Question

Hi,
I have used the Parallel processing of mass data using the "Start New Task" . In my function module I am handling the exceptions and finally raise the application specific old exception to be handled in my main report program. Somehow the sy-subrc is not getting changed and always returns 0 even if the expection is raised.
Can anyone help me about the same.
Thanks & Regards,
Nitin

Answer 1

Hi Silky,
I've build a block of code to explain this.
  DATA: ls_edgar TYPE zedgar,
        l_task(40).
  DELETE FROM zedgar.
  COMMIT WORK.
  l_task = 'task1'.
  ls_edgar-matnr = '123'.
  ls_edgar-text = 'qwe'.
  CALL FUNCTION 'Z_EDGAR_COMMIT_ROLLBACK' STARTING NEW TASK l_task PERFORMING f_go ON END OF TASK
    EXPORTING
      line = ls_edgar.
  l_task = 'task2'.
  ls_edgar-matnr = 'abc'.
  ls_edgar-text = 'def'.
  CALL FUNCTION 'Z_EDGAR_COMMIT_ROLLBACK' STARTING NEW TASK l_task PERFORMING f_go ON END OF TASK
    EXPORTING
      line = ls_edgar.
  l_task = 'task3'.
  ls_edgar-matnr = '456'.
  ls_edgar-text = 'xyz'.
  CALL FUNCTION 'Z_EDGAR_COMMIT_ROLLBACK' STARTING NEW TASK l_task PERFORMING f_go ON END OF TASK
    EXPORTING
      line = ls_edgar.
*&      Form  f_go
FORM f_go USING p_c TYPE ctype.
  RECEIVE RESULTS FROM FUNCTION 'Z_EDGAR_COMMIT_ROLLBACK' EXCEPTIONS err = 2.
  IF sy-subrc = 2.
*this won't affect the LUW of the received function
    ROLLBACK WORK.
  ELSE.
*this won't affect the LUW of the received function
    COMMIT WORK.
  ENDIF.
ENDFORM.                    "f_go
and the function is:
FUNCTION z_edgar_commit_rollback.
*"*"Interface local:
*"  IMPORTING
*"     VALUE(LINE) TYPE  ZEDGAR
*"  EXCEPTIONS
*"      ERR
  MODIFY zedgar FROM line.
  IF line-matnr CP 'a*'.
*comment raise or rollback/commit to test
*    RAISE err.
    ROLLBACK WORK.
  ELSE.
    COMMIT WORK.
  ENDIF.
ENDFUNCTION.
ok.
In your main program you have a Logical Unit of Work (LUW), witch consists of an application transaction and is associated with a database transaction. Once you start a new task, your creating an independent LUW, with it's own database transaction.
So if you do a commit or rollback in your function the effect is only on the records your processing in the function.
There is a way to capture the event when this LUW concludes in the main LUW. That is the PERFORMING whatever ON END OF TASK. In there you can get the result of the function but you cannot commit or rollback the LUW from the function since it already have implicitly happened at the conclusion of the funtion. You can test it by correctly comment the code I've supplied.
So, if you  want to rollback the LUW of the function you better do it inside it.
I don't think it matches exactly your question, maybe it lead you on the right track. Give me more details if it doesn't.
Hope it helps,
Edgar