Passing UNIX command in SQL Script

Question

Hi,
I am writing a sql-script in unix.
The logic is as below:
SELECT flag FROM dummy_table;
If flag = Y Then
cp ./abc.txt $HOME/abc.txt
Else
SELECT id, roll FROM employees;
Please help me out.
Thanks and Regards,
Tony

Answer 1

I did that way:
Under SYS create the following procedure:
CREATE OR REPLACE PROCEDURE SYS.LINUX_RUN (PATH     IN     VARCHAR2,
                                           result      OUT VARCHAR2)
IS
   script_file   VARCHAR2 (40) := 'my-temp-script.sh';
   script_data   VARCHAR2 (4000);
   MyFile        UTL_FILE.file_type;
   d             VARCHAR2 (4000);
   dump_file     VARCHAR2 (40) := '/tmp/my-temp-file.dat';
   dump_type     UTL_FILE.file_type;
BEGIN
   pms.post_calls;
   -- Open file
   MyFile := UTL_FILE.fopen ('TMP', script_file, 'w');
   -- Write data to file
   script_data := PATH || ' > ' || dump_file;
   UTL_FILE.put_line (MyFile, script_data, FALSE);
   -- Close file
   UTL_FILE.fflush (MyFile);
   UTL_FILE.fclose (MyFile);
   -- Purge old logs, no fun anyway
   DBMS_SCHEDULER.purge_log (JOB_NAME => 'TEST');
   -- Execute script
   -- The job is created as disabled as
   -- we execute it manually and will
   -- drop itself once executed.
   DBMS_SCHEDULER.create_job (job_name              => 'TEST',
                              job_type              => 'EXECUTABLE',
                              job_action            => '/bin/sh',
                              number_of_arguments   => 1,
                              start_date            => SYSTIMESTAMP,
                              enabled               => FALSE);
   DBMS_SCHEDULER.set_job_argument_value ('TEST', 1, '/tmp/' || script_file);
   DBMS_SCHEDULER.enable ('TEST');
   -- Wait for the job to be executed
   -- usually done within 1 second but
   -- I set it to 2 just in case.
   DBMS_LOCK.sleep (2);
   -- Open the output file and
   -- print the result.
   dump_type := UTL_FILE.fopen ('TMP', dump_file, 'r');
   UTL_FILE.get_line (dump_type, d);
   result := d;
   LOOP
      BEGIN
         UTL_FILE.get_line (dump_type, d);
         DBMS_OUTPUT.put_line (d);
      EXCEPTION
         WHEN OTHERS
         THEN
            EXIT;
      END;
   END LOOP;
   UTL_FILE.fclose (dump_type);
   -- Clean up our temp files
   UTL_FILE.fremove ('TMP', script_file);
   UTL_FILE.fremove ('TMP', dump_file);
END;
/And grant execute on this procedure to end user.
Then under granted user you can use this procedure in your PL/SQL code.
It works just fine for me :)
Good luck.